تعيد =LEFT(A2,3) أول 3 أحرف من النص في A2، وتعيد =RIGHT(A2,1) الحرف الأخير، وتعيد =MID(A2,5,4) أربعة أحرف بدءًا من الحرف الخامس. ومع الرمز NYC-2041-B تكون النتائج NYC وB و2041.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Code | City | Number | Size |
| 2 | NYC-2041-B | NYC | 2041 | B |
| 3 | LAX-1187-A | LAX | 1187 | A |
| 4 | SFO-3302-C | SFO | 3302 | C |
| 5 | BOS-0915-B | BOS | 0915 | B |
انقر C2 وغيّر 5 إلى 4: تبدأ النتيجة الآن من الشرطة. المسافات وعلامات الترقيم تُعدّ أحرفًا، والحرف الأول هو الموضع 1.
الصيغة
=LEFT(text, [num_chars])
=RIGHT(text, [num_chars])
=MID(text, start_num, num_chars)
num_charsاختياري في LEFT وRIGHT وقيمته الافتراضية 1.- إذا طلبت أحرفًا أكثر من الموجودة، تحصل على النص كله لا على خطأ. فالصيغة
=LEFT("Ann",10)تعطيAnn. - العدد السالب يعطي #VALUE!، مثل
=LEFT(A2,LEN(A2)-3)على نص أقصر من 3 أحرف.
عندما يختلف الطول: LEFT وRIGHT وMID مع FIND
نادرًا ما تكون الرموز كلها بالطول نفسه. استخدم FIND لتحديد موضع الفاصل ودع الصيغة تحسب العدد:
| A | B | C | |
|---|---|---|---|
| 1 | Code | Before the dash | After the dash |
| 2 | NY-2041 | NY | 2041 |
| 3 | BOSTON-15 | BOSTON | 15 |
| 4 | LA-30087 | LA | 30087 |
- تعيد
FIND("-",A2)موضع الشرطة، 3 فيNY-2041. - تأخذ
LEFT(A2,3-1)الحرفين اللذين قبلها. - تبدأ
MID(A2,3+1,50)بعد الشرطة وتأخذ حتى 50 حرفًا، أكثر من طول أي رمز، فتصل إلى النهاية.
في Microsoft 365 وExcel 2024، تعطي TEXTBEFORE(A2,"-") وTEXTAFTER(A2,"-") النتائج نفسها بصيغة أقصر؛ راجع تقسيم النص.
حذف الأحرف الأولى أو الأخيرة
لإسقاط أحرف، احتفظ بالباقي. تعطي LEN الطول الكلي، وتطرح منه ما تريد حذفه:
| A | B | C | |
|---|---|---|---|
| 1 | Text | Without first 3 | Without last 2 |
| 2 | ID-58210 | 58210 | ID-582 |
| 3 | ID-7734 | 7734 | ID-77 |
| 4 | ID-120 | 120 | ID-1 |
| A | B | |
|---|---|---|
| 1 | Card | Last four |
| 2 | 4111 2222 3333 9876 |
دورك: في B2، أعد آخر 4 أحرف من رقم البطاقة الموجود في A2.
استخراج رقم من رمز
تعيد LEFT وRIGHT وMID نصًا دائمًا، حتى عندما تكون الأحرف أرقامًا. الأرقام النصية تبدو أرقامًا لكن SUM تتخطاها، ولهذا قد يخرج مجموع الأرقام المستخرجة 0:
| A | B | C | |
|---|---|---|---|
| 1 | Order | MID (text) | VALUE(MID) |
| 2 | SO-0120-X | 0120 | 120 |
| 3 | SO-0345-Y | 0345 | 345 |
| 4 | SO-1000-Z | 1000 | 1000 |
| 5 | Total | 0 | 1465 |
يعرض العمود B القيمة 0120 بصفرها البادئ لأنها ما زالت نصًا، ومجموع B5 هو 0. ويحوّل العمود C كل جزء بالدالة VALUE فيكون المجموع صحيحًا. وتحوّل =--MID(A2,4,4) و=MID(A2,4,4)*1 بالطريقة نفسها؛ راجع تحويل النص إلى رقم للمزيد.
| A | B | |
|---|---|---|
| 1 | Item | Quantity |
| 2 | PK-045-BAG |
دورك: تقع الكمية بين الشرطتين وتتكون دائمًا من 3 أرقام. في B2، استخرجها كرقم يمكنك جمعه.
خطأ شائع: LEFT على تاريخ
يُخزن التاريخ كرقم، لذا لا تعيد =LEFT(B2,4) على التاريخ 2026-03-15 القيمة 2026: بل تعيد 4609، أول 4 أرقام من 46096، الرقم التسلسلي الذي يقف خلف التاريخ.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Event | Date | LEFT(date,4) | Year |
| 2 | Launch | 2026-03-15 | 4609 | 2026 |
| 3 | 2026 |
استخدم YEAR(B2) للسنة كرقم، أو TEXT(B2,"yyyy") للسنة كنص. وتغطي MONTH وDAY وTEXT مع "mmm" أو "dd" الأجزاء الأخرى.
الأسئلة الشائعة
كيف أستخرج أول N حرف في الاكسل؟
استخدم LEFT مع العدد: تعيد =LEFT(A2,3) أول 3 أحرف. وبدون الوسيط الثاني، تعيد =LEFT(A2) الحرف الأول فقط.
كيف أحذف الأحرف الأولى أو الأخيرة في الاكسل؟
احتفظ بالباقي بمساعدة LEN: تحذف =RIGHT(A2,LEN(A2)-3) أول 3 أحرف، وتحذف =LEFT(A2,LEN(A2)-2) آخر حرفين.
لماذا لا أستطيع جمع الأرقام التي تعيدها MID؟
لأن LEFT وRIGHT وMID تعيد نصًا دائمًا، وSUM تتخطى النص. حوّل النتيجة إلى رقم بالدالة VALUE أو بعلامتي طرح: =VALUE(MID(A2,5,4)) أو =--MID(A2,5,4).
كيف أحصل على النص الذي يسبق حرفًا معينًا في الاكسل؟
أوجد موضع الحرف وخذ أقل منه بواحد: تعيد =LEFT(A2,FIND("-",A2)-1) كل ما قبل الشرطة الأولى. وفي Microsoft 365 تفعل =TEXTBEFORE(A2,"-") الشيء نفسه.
