يغيّر التنسيق الشرطي مظهر الخلية (التعبئة، ولون الخط، والحدود) عندما يتحقق شرط. حدد الخلايا، واذهب إلى الصفحة الرئيسية > التنسيق الشرطي، واختر قاعدة جاهزة، أو اختر قاعدة جديدة > استخدام صيغة لتحديد الخلايا التي سيتم تنسيقها واكتب صيغة مثل =$C2>100، التي تلوّن كل صف مبلغه في العمود C أكبر من 100.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Order | Region | Amount | Due | Status |
| 2 | 1001 | North | 120 | 2026-03-02 | Paid |
| 3 | 1002 | South | 85 | 2026-03-10 | Open |
| 4 | 1003 | North | 240 | 2026-03-12 | Open |
| 5 | 1004 | East | 60 | 2026-03-20 | Paid |
| 6 | 1005 | South | 150 | 2026-03-25 | Open |
| 7 | 1006 | East | 95 | 2026-03-08 | Open |
تُميَّز الصفوف 2 و4 و6. غيّر C3 إلى 100 فلا يحدث شيء، لأن القاعدة تقول أكبر من 100؛ وغيّرها إلى 101 فيضيء الصف 3. والقاعدة معروضة تحت الشبكة، ويمكنك نقرها وتعديلها.
كيف تضيف قاعدة تنسيق شرطي
في القائمة قواعد جاهزة للحالات الشائعة:
- قواعد تمييز الخلايا: أكبر من، وأصغر من، وبين، ويساوي، والنص الذي يحتوي على، وتاريخ حدوث، والقيم المتكررة.
- قواعد أعلى/أسفل: أعلى 10 عناصر، وأعلى 10%، وأسفل 10 عناصر، وأسفل 10%، وأعلى من المتوسط، وأقل من المتوسط (ويمكن تغيير الرقم 10).
- أشرطة البيانات ومقاييس الألوان ومجموعات الأيقونات: تظلّل كل خلية حسب حجمها بدلًا من اختبار شرط.
ولأي شيء آخر، اكتب قاعدة صيغة:
- حدد الخلايا المراد تنسيقها، بدءًا من الخلية العلوية اليسرى، لتكون الخلية النشطة. وفي الورقة السابقة هي A2:E7.
- اذهب إلى الصفحة الرئيسية > التنسيق الشرطي > قاعدة جديدة.
- اختر استخدام صيغة لتحديد الخلايا التي سيتم تنسيقها.
- اكتب الصيغة للخلية النشطة. يجب أن تعيد TRUE أو FALSE:
=$C2>100. - انقر تنسيق، واختر لون تعبئة أو خط، واضغط موافق مرتين.
ينقل الاكسل الصيغة إلى كل خلية في النطاق كصيغة منسوخة إلى الأسفل وإلى الجانب، فتقرر علامات الدولار ما تنظر إليه كل خلية. يعني $C2 "العمود C، هذا الصف": العمود ثابت، والصف يتحرك. والقواعد في هذه الصفحة تعرض الصيغ نفسها تمامًا التي ستكتبها في ذلك المربع.
تمييز الخلايا الأكبر من قيمة في خلية أخرى
توجيه القاعدة إلى خلية بدلًا من كتابة الرقم يجعل تغيير الحد سهلًا. تلوّن القاعدة أدناه خلايا Amount فقط، وتقارن كلًا منها بالخلية F2؛ وتُبقي علامات $ في $F$2 كل خلية تنظر إلى F2.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Order | Region | Amount | Limit | ||
| 2 | 1001 | North | 120 | 100 | ||
| 3 | 1002 | South | 85 | |||
| 4 | 1003 | North | 240 | |||
| 5 | 1004 | East | 60 | |||
| 6 | 1005 | South | 150 | |||
| 7 | 1006 | East | 95 |
تُلوَّن C2 وC4 وC6. اكتب 90 في F2 فتنضم إليها C7؛ واكتب 200 فلا يبقى إلا C4. والقاعدة الجاهزة قواعد تمييز الخلايا > أكبر من تقبل مرجع خلية في مربعها أيضًا (=$F$2).
تمييز صف بناءً على نص
يوضع شرط النص بين علامتي اقتباس. تلوّن =$B2="North" كل صف منطقته North. وتتجاهل المقارنات بالرمز = الأحرف الكبيرة والصغيرة، فتطابق north أيضًا. ولمطابقة نص يحتوي على كلمة فقط، استخدم SEARCH داخل ISNUMBER: تعيد SEARCH موضع الكلمة، أو خطأً عندما تكون مفقودة، وتحوّل ISNUMBER ذلك إلى TRUE أو FALSE.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Order | Region | Amount | Note |
| 2 | 1001 | North | 120 | Paid on time |
| 3 | 1002 | South | 85 | Late, called twice |
| 4 | 1003 | North | 240 | |
| 5 | 1004 | East | 60 | Paid late |
| 6 | 1005 | South | 150 | Waiting for invoice |
| 7 | 1006 | East | 95 |
يُلوَّن الصفان 2 و4 للمنطقة North، وتحتوي D3 وD5 على "late" (إحداهما بالشكل Late). غيّر B7 إلى North فينضم الصف 7. والقاعدة الجاهزة قواعد تمييز الخلايا > النص الذي يحتوي على تفعل ما تفعله قاعدة SEARCH للخلايا المحددة.
تمييز التواريخ المتأخرة
يكون الطلب المفتوح متأخرًا عندما يسبق تاريخ استحقاقه اليوم. في الاكسل تكون القاعدة =AND($E2="Open",$D2<TODAY())، وتتحدث الألوان كل يوم. وتستخدم الورقة أدناه تاريخًا ثابتًا في G2 بدلًا من TODAY()، ليبدو المثال كما هو متى قرأته: =AND($E2="Open",$D2<$G$2).
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Order | Region | Amount | Due | Status | Today | |
| 2 | 1001 | North | 120 | 2026-03-02 | Paid | 2026-03-15 | |
| 3 | 1002 | South | 85 | 2026-03-10 | Open | ||
| 4 | 1003 | North | 240 | 2026-03-12 | Open | ||
| 5 | 1004 | East | 60 | 2026-03-20 | Paid | ||
| 6 | 1005 | South | 150 | 2026-03-25 | Open | ||
| 7 | 1006 | East | 95 | 2026-03-08 | Open |
مع 2026-03-15 في G2، تكون الصفوف 3 و4 و7 متأخرة. وللصف 2 تاريخ أقدم لكنه مدفوع، فتُبقيه AND عاديًا. وتلوّن القاعدة الثانية خلايا D المستحقة خلال الأيام السبعة القادمة: لا شيء بعد. غيّر G2 إلى 2026-03-20 فتلوّن D6 (المستحقة في 2026-03-25). وغيّر E3 إلى Paid فيخرج الصف 3.
ولعبارات مثل "مستحق هذا الأسبوع" أو "الشهر الماضي" دون صيغة، تحتوي القاعدة الجاهزة قواعد تمييز الخلايا > تاريخ حدوث على هذه الخيارات.
تمييز الخلايا الفارغة، أو الصفوف التي تنقصها قيمة
تكون =B2="" بالقيمة TRUE لخلية فارغة (ولصيغة تعيد نصًا فارغًا). ضع $ قبل العمود لتلوين الصف كله عندما تكون خلية واحدة فيه فارغة: =$C2="". والقاعدة الجاهزة هي قاعدة جديدة > تنسيق الخلايا التي تحتوي على فقط > فراغات.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Order | Region | Amount | Status |
| 2 | 1001 | North | 120 | Paid |
| 3 | 1002 | South | Open | |
| 4 | 1003 | North | 240 | Open |
| 5 | 1004 | East | Paid | |
| 6 | 1005 | South | 150 | Open |
| 7 | 1006 | East | 95 | Open |
يُلوَّن الصفان 3 و5. اكتب مبلغًا في C3 فيعود صفها عاديًا. وتعمل =ISBLANK($C2) هنا أيضًا، لكن ISBLANK تكون FALSE لخلية فيها صيغة تعيد ""، بينما تكون =$C2="" بالقيمة TRUE للحالتين.
عدّ ما تلوّنه القاعدة
لا تعطي القاعدة رقمًا أبدًا، لكن الشرط نفسه داخل COUNTIFS أو SUMPRODUCT يعطيه. يحتاج عدّ الطلبات المفتوحة المتأخرة من القسم السابق، مع التاريخ في G2، إلى شرطين: Status يساوي Open، وDue قبل G2.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Order | Region | Amount | Due | Status | Today | |
| 2 | 1001 | North | 120 | 2026-03-02 | Paid | 2026-03-15 | |
| 3 | 1002 | South | 85 | 2026-03-10 | Open | ||
| 4 | 1003 | North | 240 | 2026-03-12 | Open | Overdue | |
| 5 | 1004 | East | 60 | 2026-03-20 | Paid | ||
| 6 | 1005 | South | 150 | 2026-03-25 | Open | ||
| 7 | 1006 | East | 95 | 2026-03-08 | Open |
دورك: في G4، عدّ الطلبات المفتوحة التي يسبق تاريخ استحقاقها التاريخ الموجود في G2.
الإجابة 3، عدد الصفوف الملونة. ويربط الشرط "<"&G2 علامة أصغر من بالتاريخ في G2؛ أما كتابة "<G2" فستقارن بالنص G2. والمزيد عن شروط كهذه في صفحة COUNTIFS.
مقاييس الألوان وأشرطة البيانات ومجموعات الأيقونات
تظلّل هذه الثلاثة كل خلية حسب قيمتها بدلًا من التبديل بناءً على شرط. حدد الأرقام واختر واحدة من الصفحة الرئيسية > التنسيق الشرطي:
- مقاييس الألوان تمتد من لون لأدنى قيمة إلى آخر لأعلى قيمة (أول مقياس في المعرض يلوّن أعلى القيم بالأخضر، والوسط بالأصفر، وأدناها بالأحمر). وهي مناسبة لخريطة حرارية لجدول أرقام.
- أشرطة البيانات ترسم شريطًا داخل كل خلية، بطول يتناسب مع قيمتها مقارنة بالأخرى. وتحت قواعد إضافية يمكنك تحديد إظهار الشريط فقط لإخفاء الرقم.
- مجموعات الأيقونات تضع سهمًا أو علمًا أو إشارة مرور قبل القيمة، افتراضيًا حسب أثلاث النطاق.
لتغيير حدود أي منها، اذهب إلى الصفحة الرئيسية > التنسيق الشرطي > إدارة القواعد > تحرير القاعدة، حيث يمكن ربط كل لون أو أيقونة برقم أو نسبة مئوية أو مئين أو صيغة.
خطأ شائع: علامات الدولار الخاطئة
ثلاث نسخ من القاعدة نفسها، مطبقة على A2:E7، تفعل ثلاثة أشياء مختلفة:
| القاعدة | ما تفحصه كل خلية | النتيجة |
|---|---|---|
=$C2>100 | العمود C في صفها | صفوف كاملة ملونة حسب المبلغ |
=C2>100 | الخلية التي تبعد عمودين إلى يمينها: تفحص A2 الخلية C2، وتفحص B2 الخلية D2 | لا يتبع المبلغ إلا العمود A؛ ويُلوَّن B وC دائمًا (التاريخ والنص يُعدّان أكبر من 100)، ولا يُلوَّن D وE أبدًا |
=$C$2>100 | دائمًا C2 | كل الصفوف ملونة، أو لا شيء |
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Order | Region | Amount | Due | Status |
| 2 | 1001 | North | 120 | 2026-03-02 | Paid |
| 3 | 1002 | South | 85 | 2026-03-10 | Open |
| 4 | 1003 | North | 240 | 2026-03-12 | Open |
| 5 | 1004 | East | 60 | 2026-03-20 | Paid |
| 6 | 1005 | South | 150 | 2026-03-25 | Open |
| 7 | 1006 | East | 95 | 2026-03-08 | Open |
كل خلية ملونة لأن C2 تساوي 120. غيّر C2 إلى 50 فتختفي كل الألوان دفعة واحدة. انقر القاعدة واحذف $ قبل 2 لتحصل على =$C2>100، فتتبع الألوان كل صف من جديد. وقاعدة اختيار الجزء الذي يُثبَّت هي نفسها في الصيغ التي تنسخها إلى الأسفل، وتشرحها صفحة المرجع المطلق.
الأسئلة الشائعة
كيف أطبق التنسيق الشرطي بناءً على خلية أخرى؟
حدد الخلايا المراد تلوينها، واذهب إلى الصفحة الرئيسية > التنسيق الشرطي > قاعدة جديدة > استخدام صيغة لتحديد الخلايا التي سيتم تنسيقها، واكتب الصيغة لأول خلية محددة مشيرًا إلى الخلية الأخرى: تلوّن =$C2>100 الصف عندما تكون قيمة C في ذلك الصف أكبر من 100.
كيف ألوّن صفًا كاملًا بالتنسيق الشرطي؟
حدد الجدول كله، لا عمودًا واحدًا، وضع $ قبل حرف عمود الخلية التي تختبرها: =$E2="Open". يبقى العمود ثابتًا بينما يتحرك رقم الصف، فتفحص كل خلية في الصف الخلية نفسها.
كيف أستخدم التنسيق الشرطي بعدة شروط؟
اجمعها بالدالة AND أو OR داخل قاعدة صيغة واحدة: تلوّن =AND($E2="Open",$D2<TODAY()) الطلبات غير المدفوعة التي تجاوزت تاريخ استحقاقها. وتنطبق كل القواعد المنفصلة على النطاق نفسه؛ وعندما تضبط قاعدتان التنسيق نفسه، مثل التعبئة، تفوز القاعدة الأعلى في الصفحة الرئيسية > التنسيق الشرطي > إدارة القواعد.
كيف أميّز الخلايا التي تحتوي على نص معين؟
استخدم الصفحة الرئيسية > التنسيق الشرطي > قواعد تمييز الخلايا > النص الذي يحتوي على، أو قاعدة صيغة =ISNUMBER(SEARCH("late",A2))، التي تكون TRUE عندما تحتوي A2 على late بأي حالة أحرف.
لماذا لا تعمل صيغة التنسيق الشرطي لدي؟
غالبًا بسبب علامات الدولار: تفحص =$C$2>100 الخلية C2 فقط لكل خلية، وتفحص =C2>100 على صف كامل عمودًا مختلفًا في كل خلية. وتحقق أيضًا من أن الصيغة كُتبت لأول خلية في النطاق المذكور تحت ينطبق على في إدارة القواعد.
