تجمع =SUMIF(A2:A7,"North",C2:C7) المبيعات في C2:C7 في كل صف يكون فيه العمود A يساوي North. تفحص SUMIF نطاقًا واحدًا مقابل شرط وتجمع الصفوف المطابقة من نطاق آخر.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Region | Total | |
| 2 | North | Apple | 120 | North | 230 | |
| 3 | South | Pear | 45 | South | 245 | |
| 4 | North | Pear | 80 | |||
| 5 | East | Apple | 55 | |||
| 6 | South | Apple | 200 | |||
| 7 | North | Apple | 30 |
تجمع F2 القيم 120 و80 و30، وهي صفوف North الثلاثة، وتعرض 230. وتأخذ F3 منطقتها من E3: غيّر E3 إلى East فتعرض 55. غيّر أي رقم في العمود C فيتحدث الإجماليان.
صيغة دالة SUMIF
=SUMIF(range, criteria, [sum_range])
rangeهي الخلايا التي يُفحص الشرط مقابلها.criteriaهو الشرط: نص بين علامتي اقتباس ("North")، أو مقارنة (">100")، أو نمط بأحرف البدل ("*apple*")، أو خلية (E3، أو">"&F2مع عامل مقارنة).sum_rangeهي الخلايا المراد جمعها. وهي اختيارية: دونها تجمع SUMIF الخلايا المطابقة منrangeنفسه.
يُطابَق range وsum_range صفًا بصف، لذا يجب أن يبدآ في الصف نفسه وأن يكونا بالحجم نفسه. وفي الاكسل المضبوط على لغة تستخدم الفاصلة العشرية، تُفصل الوسائط بفواصل منقوطة: =SUMIF(A2:A7;"North";C2:C7).
SUMIF أكبر من أو أصغر من
لجمع الأرقام الأكبر أو الأصغر من قيمة ما، يكون الشرط والجمع على العمود نفسه، لذا يمكنك حذف sum_range.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Condition | Total | |
| 2 | North | Apple | 120 | Over 100 | 320 | |
| 3 | South | Pear | 45 | 100 or less | 210 | |
| 4 | North | Pear | 80 | Not North | 300 | |
| 5 | East | Apple | 55 | Limit | 50 | |
| 6 | South | Apple | 200 | Over the limit | 455 | |
| 7 | North | Apple | 30 |
تجمع F2 القيمتين 120 و200، وتجمع F3 القيم الأربع الأخرى، ومجموعهما معًا يساوي الإجمالي الكلي دائمًا. وتعرض F4 شرط "لا يساوي": كل شيء عدا North. وتقرأ F6 حدها من F5. اكتب عامل المقارنة بين علامتي اقتباس واربط الخلية بالرمز &: ">"&F5، لا ">F5" أبدًا.
SUMIF إذا احتوت الخلية على نص
تمثل * في الشرط أي عدد من الأحرف، و? حرفًا واحدًا بالضبط. تطابق "*apple*" أي منتج فيه apple في أي موضع من اسمه، وبأي حالة أحرف.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Product | Sales | Condition | Total | |
| 2 | Apple | 120 | contains apple | 250 | |
| 3 | Pineapple | 45 | exactly Apple | 120 | |
| 4 | Pear | 80 | starts with P | 325 | |
| 5 | Green apple | 55 | word in D6 | 80 | |
| 6 | Plum | 200 | pear | ||
| 7 | Apple cider | 30 |
تجمع E2 كلًا من Apple وPineapple وGreen apple وApple cider. أما E3، دون أحرف بدل، فتجمع الخلية التي تساوي Apple تمامًا فقط. وتبني E5 النمط من الكلمة الموجودة في D6: غيّر D6 إلى cider فتعرض E5 مبيعات cider وحدها. تجد أنماطًا أخرى، والرمز ~ لعلامة نجمة حرفية، في صفحة أحرف البدل.
لجمع القيم المجاورة لأي خلية ممتلئة، استخدم "<>" (غير فارغة): =SUMIF(A2:A7,"<>",B2:B7). أما "" فتجمع الصفوف التي تكون فيها الخلية فارغة.
SUMIF حسب التاريخ
التواريخ أرقام، لذا تعمل عليها ">=" و"<" وبقية العوامل. ابنِ التاريخ بالدالة DATE أو احتفظ به في خلية، واربطه بعامل المقارنة بالرمز &.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Sales | Date | Condition | Total | |
| 2 | North | 120 | 2026-01-05 | From Feb 1 | 365 | |
| 3 | South | 45 | 2026-01-12 | Cutoff | 2026-03-01 | |
| 4 | North | 80 | 2026-02-03 | Before the cutoff | 300 | |
| 5 | East | 55 | 2026-02-18 | On Jan 12 | 45 | |
| 6 | South | 200 | 2026-03-02 | |||
| 7 | North | 30 | 2026-03-20 |
تجمع F2 الطلبات الأربعة من الأول من فبراير فصاعدًا: 80 و55 و200 و30، أي 365. وتجمع F4 الطلبات السابقة للتاريخ الموجود في F3. أما إجمالي شهر واحد فيحتاج إلى تاريخ بداية وتاريخ نهاية، أي شرطين على العمود نفسه، وهذا عمل SUMIFS: =SUMIFS(B2:B7,C2:C7,">="&DATE(2026,2,1),C2:C7,"<"&DATE(2026,3,1)).
SUMIF من ورقة أخرى
يمكن أن تكون النطاقات في ورقة أخرى: ضع اسم الورقة و! قبلها. أدناه، البيانات في علامة التبويب Sales والملخص في علامة تبويب خاصة به. انقر علامة التبويب Sales لترى الصفوف التي تُجمع.
| A | B | |
|---|---|---|
| 1 | Region | Total |
| 2 | North | 230 |
| 3 | South | 245 |
| 4 | East | 55 |
سُحبت B2 إلى الأسفل حتى B4: ينتقل الشرط A2 إلى A3 وA4، ويُبقي الرمز $ النطاقين على صفوف ورقة Sales نفسها. ودون $، كانت النسخة الثالثة ستقرأ Sales!A4:A9 وتفوّت الصفوف الأولى. هذا النمط، قائمة تسميات بجانب كل منها دالة SUMIF واحدة، هو طريقة بناء ملخص حسب الفئة دون جدول محوري. واسم الورقة الذي فيه مسافة يحتاج إلى علامتي اقتباس: 'Sales 2026'!$A$2:$A$7.
تمرين: SUMIF
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Product | Total | |
| 2 | North | Apple | 120 | Apple | ||
| 3 | South | Pear | 45 | |||
| 4 | North | Pear | 80 | |||
| 5 | East | Apple | 55 | |||
| 6 | South | Apple | 200 | |||
| 7 | North | Plum | 30 | |||
| 8 | West | Apple | 65 |
دورك: اجمع مبيعات صفوف Apple. اكتب الصيغة في F2.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Order | Amount | Condition | Total | |
| 2 | A-101 | 120 | 100 or more | ||
| 3 | A-102 | 45 | |||
| 4 | A-103 | 310 | |||
| 5 | A-104 | 100 | |||
| 6 | A-105 | 85 | |||
| 7 | A-106 | 140 | |||
| 8 | A-107 | 99 |
دورك: اجمع الطلبات التي قيمتها 100 أو أكثر في B2:B8. اكتب الصيغة في E2.
SUMIF بعدة شروط
تأخذ SUMIF شرطًا واحدًا. وتتكرر حالتان كثيرًا.
يجب أن يتحقق الشرطان معًا (North وApple): استخدم SUMIFS. يأتي نطاق الجمع فيها أولًا، ثم أزواج الشروط.
=SUMIFS(C2:C7,A2:A7,"North",B2:B7,"Apple")
إحدى قيمتين في عمود واحد (North أو South): أعطِ SUMIF قائمة بين قوسين معقوفين واجمع النتيجتين بالدالة SUM، أو اجمع دالتي SUMIF.
=SUM(SUMIF(A2:A7,{"North","South"},C2:C7))
=SUMIF(A2:A7,"North",C2:C7)+SUMIF(A2:A7,"South",C2:C7)
أما الشرط على عملية حسابية (شهر التاريخ، أو المبيعات مضروبة في السعر)، فلا تنفع فيه SUMIF؛ وتنفع فيه SUMPRODUCT.
لماذا تعيد SUMIF صفرًا أو إجماليًا خاطئًا
- الشرط لا يتطابق أبدًا. "North " مع مسافة في آخرها لا تساوي "North". اختبر الشرط بالصيغة
=COUNTIF(A2:A7,"North"): إذا كانت النتيجة 0، فالمشكلة في المطابقة لا في الجمع. - أرقام مخزنة كنص في نطاق الجمع. تتخطاها SUMIF بصمت. وعادة ما تكون في يسار الخلية مع مثلث أخضر؛ حوّلها إلى أرقام أولًا.
- خلية داخل علامتي الاقتباس. تقارن
">F5"بالنص F5. اكتب">"&F5. - نطاقات بأحجام مختلفة. لا تعيد
=SUMIF(A2:A7,"North",C2)خطأ: يغيّر الاكسل حجمsum_rangeليطابقrange، بدءًا من خليته الأولى. هذا يعمل، لكن نطاق الجمع الذي يبدأ في صف خاطئ يجمع خلايا خاطئة بصمت، لذا أعطِ النطاقين الصفوف نفسها دائمًا. - النطاقات في مصنف آخر مغلق. تعرض SUMIF الخطأ
#VALUE!حتى يُفتح الملف.
الأسئلة الشائعة
كيف تعمل SUMIF في الاكسل؟
تفحص =SUMIF(range, criteria, sum_range) كل خلية في range مقابل الشرط، وتضيف الخلية الموجودة في الصف نفسه من sum_range عندما تتطابق. تجمع =SUMIF(A2:A7,"North",C2:C7) العمود C لصفوف North.
كيف أجمع القيم الأكبر من رقم معين؟
احذف نطاق الجمع وضع المقارنة بين علامتي اقتباس: تجمع =SUMIF(C2:C7,">100") كل قيمة في C2:C7 أكبر من 100. وعندما يكون الحد في خلية، اكتب =SUMIF(C2:C7,">"&F2).
كيف أجمع إذا كانت الخلية تحتوي على نص؟
ضع علامات نجمة حول النص: تجمع =SUMIF(B2:B7,"*apple*",C2:C7) العمود C حيثما احتوى العمود B على apple، مثل Apple أو Pineapple أو Green apple. والمطابقة تتجاهل حالة الأحرف.
كيف أستخدم SUMIF بعدة شروط؟
للشروط التي يجب أن تتحقق كلها، استخدم SUMIFS: =SUMIFS(C2:C7,A2:A7,"North",B2:B7,"Apple"). ولإحدى قيمتين في عمود واحد، اجمع نتائج قائمة: =SUM(SUMIF(A2:A7,{"North","South"},C2:C7)).
لماذا تعيد SUMIF صفرًا؟
غالبًا لأن الشرط لا يتطابق أبدًا (مسافة في آخر البيانات، أو كتابة ">F2" بدلًا من ">"&F2)، أو لأن الأرقام في نطاق الجمع مخزنة كنص، فتتخطاها SUMIF. تحقق من المطابقة بالدالة COUNTIF مع النطاق والشرط نفسيهما.
