تعيد =TEXT(A2,"dddd") اسم يوم التاريخ الموجود في A2، مثل Monday. وللحصول على اليوم رقمًا، تعيد =WEEKDAY(A2) القيمة 1 للأحد حتى 7 للسبت.
| A | B | C | |
|---|---|---|---|
| 1 | Date | Day | WEEKDAY |
| 2 | 2026-03-02 | Monday | 2 |
| 3 | 2026-03-06 | Friday | 6 |
| 4 | 2026-03-07 | Saturday | 7 |
| 5 | 2026-03-08 | Sunday | 1 |
| 6 | 2026-12-25 | Friday | 6 |
يوافق 2026-03-02 يوم اثنين، لذا تعطي WEEKDAY القيمة 2 (الأحد يُعدّ 1). ويقع عيد الميلاد في 2026 يوم جمعة. غيّر أي تاريخ في العمود A فيتبعه اسم اليوم. تعيد TEXT نصًا، وهذا مناسب للتسميات والتقارير؛ واستخدم WEEKDAY عندما يدخل اليوم في عملية حسابية، مثل التحقق من عطلة نهاية الأسبوع.
أسماء الأيام المختصرة وتنسيقات أخرى
يحدد رمز التنسيق مقدار ما تحصل عليه من الاسم: "dddd" الاسم الكامل، و"ddd" الأحرف الثلاثة الأولى، و"dd" أو "d" يوم الشهر بدلًا من ذلك. اجمع الرموز لكتابة تاريخ كامل بالكلمات.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Date | dddd | ddd | dddd, mmmm d |
| 2 | 2026-03-02 | Monday | Mon | Monday, March 2 |
| 3 | 2026-07-04 | Saturday | Sat | Saturday, July 4 |
| 4 | 2026-10-31 | Saturday | Sat | Saturday, October 31 |
تتبع أسماء الأيام لغة الاكسل لديك: يكتب الاكسل الألماني Montag ويستخدم "TTTT" رمزًا. والاكسل الياباني هو الاستثناء: ما زالت "dddd" تعيد Monday، وللأسماء اليابانية رموزها الخاصة. تعرض =TEXT(A2,"aaa") الرمز 月 وتعرض =TEXT(A2,"aaaa") الكلمة 月曜日، وتعطي =TEXT(A2,"m/d(aaa)") التسمية اليابانية المعتادة، 3/2(月). وتعمل الرموز نفسها في تنسيق الأرقام المخصص.
للإبقاء على التاريخ في الخلية وعرض اليوم فقط، استخدم تنسيق أرقام بدلًا من صيغة: الصفحة الرئيسية > تنسيق الأرقام > تنسيقات أرقام إضافية > مخصص، واكتب dddd أو ddd yyyy-mm-dd. ما زالت الخلية تحتوي على التاريخ، لذا يستمر عمل الجمع والبحث والفرز.
دالة WEEKDAY وأنواع الإرجاع
تعيد WEEKDAY(serial_number, [return_type]) موضع اليوم في الأسبوع. ويحدد الوسيط الثاني اليوم الذي يبدأ به الأسبوع.
| return_type | الأرقام |
|---|---|
| 1 أو محذوف | الأحد 1 إلى السبت 7 |
| 2 | الاثنين 1 إلى الأحد 7 |
| 3 | الاثنين 0 إلى الأحد 6 |
| 11 | الاثنين 1 إلى الأحد 7 (مثل 2) |
| من 12 إلى 17 | الثلاثاء 1 إلى الاثنين 7، وهكذا، حتى 17: الأحد 1 إلى السبت 7 |
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Date | Type 1 | Type 2 | Type 3 |
| 2 | 2026-03-02 | 2 | 1 | 0 |
| 3 | 2026-03-06 | 6 | 5 | 4 |
| 4 | 2026-03-07 | 7 | 6 | 5 |
| 5 | 2026-03-08 | 1 | 7 | 6 |
ليوم الاثنين، 2 مارس، تعطي الأنواع الثلاثة 2 و1 و0. وليوم الأحد، 8 مارس، تعطي 1 و7 و6. والنوع 2 هو ما يريده معظم الناس خارج الولايات المتحدة: الاثنين 1، والسبت والأحد هما اليومان الوحيدان فوق 5.
التحقق مما إذا كان التاريخ في عطلة نهاية الأسبوع
مع النوع 2، السبت 6 والأحد 7، لذا تكون WEEKDAY(A2,2)>5 قيمتها TRUE في عطلة نهاية الأسبوع. ضعها داخل IF للحصول على تسمية، أو استخدمها قاعدة تنسيق شرطي (الصفحة الرئيسية > التنسيق الشرطي > قاعدة جديدة > استخدام صيغة) لتظليل صفوف العطلة.
| A | B | C | |
|---|---|---|---|
| 1 | Date | Weekend? | Label |
| 2 | 2026-03-05 | FALSE | Weekday |
| 3 | 2026-03-06 | FALSE | Weekday |
| 4 | 2026-03-07 | TRUE | Weekend |
| 5 | 2026-03-08 | TRUE | Weekend |
| 6 | 2026-03-09 | FALSE | Weekday |
| 7 | 2026-03-10 | FALSE | Weekday |
يُميَّز صفا السبت 7 مارس والأحد 8 مارس. ويجعل الرمز $ قبل A في القاعدة كل أعمدة الصف تقرأ التاريخ من العمود A. ولعدّ أيام العمل بين تاريخين بدلًا من فحصها واحدًا واحدًا، استخدم NETWORKDAYS: راجع NETWORKDAYS وWORKDAY.
تحويل رقم اليوم إلى تسمياتك الخاصة
عندما تريد تسميات لا تستطيع TEXT إنتاجها، مثل Mo وTu أو أسماء نوبات العمل، أعطِ رقم WEEKDAY للدالة CHOOSE، التي تختار العنصر في ذلك الموضع: =CHOOSE(WEEKDAY(A2,2),"Mo","Tu","We","Th","Fr","Sa","Su"). مع النوع 2 تبدأ القائمة بالاثنين، لذا يعيد الأربعاء We.
تمرين: أسماء الأيام والعطلات
| A | B | |
|---|---|---|
| 1 | Date | Day |
| 2 | 2026-04-16 |
دورك: في B2، اعرض الاسم الكامل ليوم التاريخ الموجود في A2، مثل Monday.
| A | B | |
|---|---|---|
| 1 | Date | Weekend? |
| 2 | 2026-04-16 | |
| 3 | 2026-04-17 | |
| 4 | 2026-04-18 | |
| 5 | 2026-04-19 |
دورك: في B2، أعد TRUE إذا وقع التاريخ الموجود في A2 يوم سبت أو أحد، وFALSE في غير ذلك، ثم اسحبها إلى B5.
لماذا تعيد TEXT يومًا خاطئًا
إذا كان العمود A يحتوي على يوم الشهر (1، 2، 15) بدلًا من تاريخ كامل، تقرأ TEXT كل رقم على أنه تاريخ في يناير 1900، بداية تقويم الاكسل، وتعيد أسماء أيام لا علاقة لها بشهرك.
| A | B | C | |
|---|---|---|---|
| 1 | Typed | TEXT | Built with DATE |
| 2 | 15 | Sunday | Wednesday |
يُقرأ 15 على أنه 15 يناير 1900، الذي يسميه الاكسل يوم أحد. ابنِ التاريخ الحقيقي بالصيغة DATE(2026,4,A2) فيتبين أن 15 أبريل 2026 يوم أربعاء. ويحدث الشيء نفسه مع التواريخ المخزنة كنص: تحقق بالصيغة =ISNUMBER(A2)، التي تكون TRUE للتاريخ الحقيقي.
الأسئلة الشائعة
كيف أستخرج يوم الأسبوع من التاريخ في الاكسل؟
تعيد =TEXT(A2,"dddd") الاسم الكامل (Monday)، وتعيد =TEXT(A2,"ddd") الاسم المختصر (Mon). وللحصول على رقم، استخدم =WEEKDAY(A2,2)، التي تعدّ الاثنين 1 والأحد 7.
ماذا تعيد WEEKDAY في الاكسل؟
رقمًا من 1 إلى 7. دون وسيط ثانٍ، الأحد 1 والسبت 7. وتجعل WEEKDAY(A2,2) الاثنين 1 والأحد 7، وتجعل WEEKDAY(A2,3) الاثنين 0 والأحد 6.
كيف أتحقق مما إذا كان التاريخ في عطلة نهاية الأسبوع في الاكسل؟
تعيد =WEEKDAY(A2,2)>5 القيمة TRUE للسبت والأحد. ضعها داخل IF للحصول على تسمية: =IF(WEEKDAY(A2,2)>5,"Weekend","Weekday").
كيف أعرض التاريخ واسم اليوم في الخلية نفسها؟
أعطِ الخلية تنسيق أرقام مخصصًا: الصفحة الرئيسية > تنسيق الأرقام > تنسيقات أرقام إضافية > مخصص، واكتب ddd yyyy-mm-dd. ما زالت الخلية تحتوي على التاريخ، لذا تستمر الصيغ التي تقرؤها في العمل.
لماذا تعيد TEXT اسم يوم خاطئًا؟
لأن الخلايا تحتوي على أرقام أيام (من 1 إلى 31) أو نصوص، لا تواريخ. تقرأ TEXT الرقم 15 على أنه اليوم الخامس عشر في تقويم الاكسل، أي 15 يناير 1900، الذي يعرضه الاكسل يوم أحد. استخدم تواريخ حقيقية، أو ابنها بالدالة DATE.
