دالة COUNTIF في الاكسل: عدّ الخلايا التي تحقق شرطًا

تعدّ =COUNTIF(B2:B7,"North") الخلايا في B2:B7 التي تحتوي على North. تأخذ COUNTIF وسيطين: النطاق المراد فحصه، والشرط الذي يجب أن تحققه الخلية لتُعدّ.

الصيغإعادة الضبط

F2fx

=COUNTIF(B2:B7,"North")

	A	B	C	D	E	F
1	Rep	Region	Sales		Region	Count
2	Ana	North	120		North	3
3	Ben	South	45		South	2
4	Cara	North	80
5	Dan	East	55
6	Eva	South	200
7	Finn	North	30

انقر على خلية لترى صيغتها. غيّر رقمًا أو صيغة وستعيد الورقة الحساب.

تعدّ F2 صفوف North. وتفعل F3 الشيء نفسه لكن الشرط في خلية: غيّر E3 إلى East، أو غيّر إحدى المناطق في العمود B، فيتبعها العدد. مرجع الخلية هو طريقة بناء جدول ملخص: دالة COUNTIF واحدة لكل صف، تشير كل منها إلى تسميتها.

صيغة دالة COUNTIF

=COUNTIF(range, criteria)

• range هي الخلايا المراد فحصها. يجب أن تكون نطاقًا في ورقة، مثل B2:B7 أو B:B.
• criteria هو الشرط، ويُكتب نصًا بين علامتي اقتباس مزدوجتين، أو رقمًا، أو مرجع خلية. كل صيغة أدناه شرط صالح:

COUNTIF أكبر من، أصغر من، أو يساوي

ضع عامل المقارنة داخل علامتي الاقتباس مع الرقم: ">50" و"<=50" و"<>55". والرقم وحده دون عامل يعني "يساوي".

الصيغإعادة الضبط

F2fx

=COUNTIF(C2:C7,">50")

	A	B	C	D	E	F
1	Rep	Region	Sales		Condition	Count
2	Ana	North	120		Over 50	4
3	Ben	South	45		50 or less	2
4	Cara	North	80		Exactly 55	1
5	Dan	East	55		Not 55	5
6	Eva	South	200		Limit	100
7	Finn	North	30		Over the limit	2

انقر على خلية لترى صيغتها. غيّر رقمًا أو صيغة وستعيد الورقة الحساب.

أربع من المبيعات الست أكبر من 50 واثنتان 50 أو أقل، لذا يساوي مجموع F2 وF3 دائمًا عدد الصفوف. تقرأ F7 حدها من F6: غيّر F6 إلى 50 فتعرض F7 العدد نفسه الذي في F2.

COUNTIF مع مرجع خلية

عندما تكون القيمة التي تقارن بها في خلية، يبقى عامل المقارنة بين علامتي الاقتباس وتُربط الخلية به بالرمز &: ">"&F6 و"<="&F6 و"<>"&E3. ومن الأخطاء الشائعة في COUNTIF كتابة ">F6". داخل علامتي الاقتباس، F6 مجرد حرفين من النص، فيقارن الاكسل كل رقم بالنص "F6" ويكون العدد 0 في أغلب الأحيان.

ولشرط "يساوي خلية" لا حاجة إلى عامل: ما دامت E3 تحتوي على قيمة، فإن =COUNTIF(B2:B7,E3) مثل =COUNTIF(B2:B7,"="&E3).

COUNTIF يحتوي على نص: أحرف البدل

يعمل حرفا بدل في شرط COUNTIF: * تمثل أي عدد من الأحرف، و? حرفًا واحدًا بالضبط. تطابق "*apple*" أي خلية فيها apple في أي موضع، و"P*" أي خلية تبدأ بالحرف P، و"????" أي نص من أربعة أحرف بالضبط.

الصيغإعادة الضبط

D2fx

=COUNTIF(A2:A8,"*apple*")

	A	B	C	D
1	Product		Condition	Count
2	Apple		contains apple	4
3	Pineapple		starts with P	3
4	Pear		4 letters	2
5	apple juice		equal to APPLE	1
6			not Pear	6
7	Plum		empty	1
8	Green apple		not empty	6

انقر على خلية لترى صيغتها. غيّر رقمًا أو صيغة وستعيد الورقة الحساب.

اقرأ D2 وD5 معًا. تجد "*apple*" أربع خلايا، لكن "APPLE" دون أحرف بدل تجد خلية واحدة فقط، وهي الخلية التي تساوي Apple تمامًا. فدون أحرف البدل يجب أن تتطابق الخلية كلها، والمطابقة تتجاهل حالة الأحرف، لذا تعدّ "APPLE" و"Apple" و"apple" الخلية نفسها.

وتُظهر D6 فخًا: تعدّ "<>Pear" ست خلايا، لأن الخلية الفارغة A6 هي أيضًا "ليست Pear". لعدّ الخلايا الممتلئة التي ليست Pear فقط، استخدم COUNTIFS بشرطين: =COUNTIFS(A2:A8,"<>Pear",A2:A8,"<>").

ولاستخدام النص الموجود في خلية، اربط أحرف البدل به: =COUNTIF(A2:A8,"*"&E2&"*"). ولعدّ علامة نجمة أو علامة استفهام حقيقية، ضع قبلها علامة التلدة: "~*". تجد أنماطًا أخرى في صفحة أحرف البدل، وعدّ كل خلية تحتوي على أي نص في عدّ الخلايا التي تحتوي على نص.

COUNTIF للخلايا الفارغة وغير الفارغة

تعدّ D7 وD8 في الورقة أعلاه الخلايا الفارغة والممتلئة. "" تعني فارغة و"<>" تعني غير فارغة. الصيغة التي تعيد نصًا فارغًا (=IF(B2>0,B2,"")) تبدو فارغة وتعدّها "" فارغة، لكن "<>" تعدّها ممتلئة أيضًا، لأن الخلية تحتوي على صيغة. تشرح صفحة COUNTIF للخلايا غير الفارغة طرق تجاوز ذلك.

COUNTIF مع التواريخ

التواريخ أرقام في الاكسل، لذا تعمل عليها عوامل المقارنة. ابنِ التاريخ بالدالة DATE، أو خذه من خلية، واربطه بعامل المقارنة بالرمز &. لا تكتب تاريخًا داخل علامتي الاقتباس بتنسيقك الإقليمي أبدًا: تعني ">3/1/2026" الأول من مارس في الولايات المتحدة والثالث من يناير في معظم أوروبا.

الصيغإعادة الضبط

E2fx

=COUNTIF(B2:B7,">="&DATE(2026,2,1))

	A	B	C	D	E
1	Rep	Date		Condition	Count
2	Ana	2026-01-05		From Feb 1	4
3	Ben	2026-01-12		Cutoff	2026-03-01
4	Cara	2026-02-03		Before the cutoff	4
5	Dan	2026-02-18		On Jan 12	1
6	Eva	2026-03-02
7	Finn	2026-03-20

انقر على خلية لترى صيغتها. غيّر رقمًا أو صيغة وستعيد الورقة الحساب.

تعدّ E2 التواريخ الأربعة الواقعة في الأول من فبراير أو بعده. وتعدّ E4 التواريخ السابقة للتاريخ الفاصل في E3: غيّر E3 إلى 2026-02-01 فينخفض العدد إلى 2. والعد بين تاريخين يحتاج إلى شرطين، وهذا عمل COUNTIFS: =COUNTIFS(B2:B7,">="&DATE(2026,2,1),B2:B7,"<"&DATE(2026,3,1)).

عدّ التكرارات بالدالة COUNTIF

تخبرك COUNTIF على القائمة كلها مقابل إحدى خلاياها بعدد مرات ظهور تلك القيمة. وأي عدد أكبر من 1 يعني قيمة مكررة. ثبّت القائمة بالرمز $ حتى تبقى في مكانها عند سحب الصيغة إلى الأسفل.

الصيغإعادة الضبط

B2fx

=COUNTIF($A$2:$A$8,A2)

	A	B	C
1	Name	Times	Duplicate?
2	Ana	2	TRUE
3	Ben	2	TRUE
4	Cara	1	FALSE
5	Ana	2	TRUE
6	Dan	1	FALSE
7	Ben	2	TRUE
8	Eva	1	FALSE

تمييز A2:A8 عندما

انقر على خلية لترى صيغتها. غيّر رقمًا أو صيغة وستعيد الورقة الحساب.

يظهر Ana وBen مرتين، لذا تعرض صفوفهما 2 وTRUE، وتميّزهما قاعدة التنسيق الشرطي =COUNTIF($A$2:$A$8,A2)>1 المطبقة على A2:A8. غيّر الاسم الأخير إلى Cara فيُميَّز Cara أيضًا.

أما =COUNTIF($A$2:A2,A2)>1 (مع تثبيت بداية النطاق فقط) فتعدّ كل اسم من الأعلى حتى صفه، لذا تميّز Ana الثانية دون الأولى. هذه الصيغة تميّز النسخ التي ستحذفها وتُبقي الأولى من كل اسم. الطريقة الكاملة في صفحة إزالة التكرارات.

تمرين: COUNTIF مع خلية

الصيغإعادة الضبط

E3fx

	A	B	C	D	E
1	Order	Amount		Setting	Value
2	A-101	120		Limit	100
3	A-102	45		Orders over limit
4	A-103	310
5	A-104	100
6	A-105	85
7	A-106	140
8	A-107	99

انقر على خلية لترى صيغتها. غيّر رقمًا أو صيغة وستعيد الورقة الحساب.

دورك: عدّ الطلبات في B2:B8 التي تزيد على الحد الموجود في E2. اكتب الصيغة في E3.

تحققعرض الإجابة

غيّر E2 بعد أن تنجح: يجب أن يتغير العدد معها. الطلب الذي قيمته 100 بالضبط ليس "أكبر من" 100.

الصيغإعادة الضبط

D3fx

	A	B	C	D
1	Product		Setting	Value
2	Apple		Word	apple
3	Pear juice		Matches
4	Pineapple
5	Banana
6	Green apple
7	Pear
8	Apple cider

انقر على خلية لترى صيغتها. غيّر رقمًا أو صيغة وستعيد الورقة الحساب.

دورك: عدّ المنتجات في A2:A8 التي يحتوي اسمها على الكلمة الموجودة في D2 في أي موضع. اكتب الصيغة في D3.

تحققعرض الإجابة

COUNTIF بعدة شروط

تأخذ COUNTIF شرطًا واحدًا. ولشرطين أو أكثر هناك حالتان.

يجب أن تتحقق الشروط كلها (North وأكبر من 50): استخدم COUNTIFS، التي تأخذ أزواجًا من النطاقات والشروط.

=COUNTIFS(B2:B7,"North",C2:C7,">50")

يكفي أن يتحقق أحد الشرطين (North أو South): اجمع دالتي COUNTIF، أو أعطِ دالة COUNTIF واحدة قائمة بين قوسين معقوفين واجمع النتائج بالدالة SUM.

=COUNTIF(B2:B7,"North")+COUNTIF(B2:B7,"South")
=SUM(COUNTIF(B2:B7,{"North","South"}))

لا تستخدم صيغة "أو" هذه على خلية يمكن أن تطابق الشرطين معًا ("*apple*" أو "*green*"): ستُعدّ Green apple مرتين. وللشروط المتداخلة، تعدّ =SUMPRODUCT(--((ISNUMBER(SEARCH("apple",A2:A8))+ISNUMBER(SEARCH("green",A2:A8)))>0)) كل خلية مرة واحدة.

العد مع مراعاة حالة الأحرف

لا تفرّق COUNTIF أبدًا بين Apple وapple. وعندما تهم حالة الأحرف، قارن بالدالة EXACT، التي تفرّق بين الحالتين، واجمع نتائج TRUE:

=SUMPRODUCT(--EXACT(A2:A8,"Apple"))

يحوّل -- القيمتين TRUE وFALSE إلى 1 و0. والدالة SUMPRODUCT هي الأداة العامة للشروط التي لا تستطيع COUNTIF التعبير عنها.

لماذا تعيد COUNTIF صفرًا أو عددًا خاطئًا

• عامل المقارنة والخلية كلاهما داخل علامتي الاقتباس. تقارن ">F6" بالنص F6. اكتب ">"&F6.
• مسافات زائدة في البيانات. "North " مع مسافة في آخرها لا تساوي "North". عدّ بالشرط "North*" للتحقق، ثم نظّف العمود بالدالة TRIM.
• أرقام مخزنة كنص. شرط مثل ">50" يقارن الأرقام الحقيقية فقط، لذا تُتخطى الأرقام المكتوبة كنص (المحاذاة لليسار، وغالبًا مع مثلث أخضر). حوّلها أولًا؛ راجع الأرقام المخزنة كنص.
• النطاق يشير إلى مصنف آخر مغلق. تعيد COUNTIF الخطأ #VALUE! حتى يُفتح ذلك المصنف. ولا تعاني SUMPRODUCT من هذا القيد.
• نص أطول من 255 حرفًا. لا تستطيع COUNTIF مطابقة نصوص أطول من 255 حرفًا. قارن مباشرة بدلًا من ذلك: =SUMPRODUCT(--(A2:A8=E2)).