=LEFT(A2,3) מחזירה את 3 התווים הראשונים של הטקסט שב-A2, =RIGHT(A2,1) את התו האחרון, ו-=MID(A2,5,4) מחזירה ארבעה תווים החל מהתו החמישי. בקוד NYC-2041-B אלה NYC, B ו-2041.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Code | City | Number | Size |
| 2 | NYC-2041-B | NYC | 2041 | B |
| 3 | LAX-1187-A | LAX | 1187 | A |
| 4 | SFO-3302-C | SFO | 3302 | C |
| 5 | BOS-0915-B | BOS | 0915 | B |
לחצו על C2 ושנו את ה-5 ל-4: עכשיו התוצאה מתחילה במקף. רווחים וסימני פיסוק נספרים כתווים, והתו הראשון הוא מיקום 1.
תחביר
=LEFT(text, [num_chars])
=RIGHT(text, [num_chars])
=MID(text, start_num, num_chars)
num_charsאופציונלי ב-LEFT וב-RIGHT, וברירת המחדל שלו היא 1.- אם מבקשים יותר תווים ממה שיש, מקבלים את הטקסט כולו, לא שגיאה.
=LEFT("Ann",10)היאAnn. - מספר שלילי נותן #VALUE!, למשל
=LEFT(A2,LEN(A2)-3)על טקסט שקצר מ-3 תווים.
כשהאורך משתנה: LEFT, RIGHT ו-MID עם FIND
לקודים יש לעתים רחוקות אותו אורך. השתמשו ב-FIND כדי למצוא את המפריד, ותנו לנוסחה לחשב את מספר התווים:
| A | B | C | |
|---|---|---|---|
| 1 | Code | Before the dash | After the dash |
| 2 | NY-2041 | NY | 2041 |
| 3 | BOSTON-15 | BOSTON | 15 |
| 4 | LA-30087 | LA | 30087 |
FIND("-",A2)מחזירה את המיקום של המקף, 3 ב-NY-2041.LEFT(A2,3-1)לוקחת את 2 התווים שלפניו.MID(A2,3+1,50)מתחילה אחרי המקף ולוקחת עד 50 תווים, יותר ממה שיש בכל קוד, ולכן היא מגיעה עד הסוף.
ב-Microsoft 365 וב-Excel 2024, TEXTBEFORE(A2,"-") ו-TEXTAFTER(A2,"-") נותנות את אותן תוצאות בנוסחה קצרה יותר; ראו פיצול טקסט.
הסרת התווים הראשונים או האחרונים
כדי להוריד תווים, שמרו את השאר. LEN נותנת את האורך הכולל, ומחסירים ממנו את מה שרוצים להסיר:
| A | B | C | |
|---|---|---|---|
| 1 | Text | Without first 3 | Without last 2 |
| 2 | ID-58210 | 58210 | ID-582 |
| 3 | ID-7734 | 7734 | ID-77 |
| 4 | ID-120 | 120 | ID-1 |
| A | B | |
|---|---|---|
| 1 | Card | Last four |
| 2 | 4111 2222 3333 9876 |
תורכם: ב-B2, החזירו את 4 התווים האחרונים של מספר הכרטיס שב-A2.
חילוץ מספר מתוך קוד
LEFT, RIGHT ו-MID מחזירות תמיד טקסט, גם כשהתווים הם ספרות. ספרות כטקסט נראות כמו מספרים אבל SUM מדלגת עליהן, ולכן סכום של מספרים שחולצו יכול לצאת 0:
| A | B | C | |
|---|---|---|---|
| 1 | Order | MID (text) | VALUE(MID) |
| 2 | SO-0120-X | 0120 | 120 |
| 3 | SO-0345-Y | 0345 | 345 |
| 4 | SO-1000-Z | 1000 | 1000 |
| 5 | Total | 0 | 1465 |
עמודה B מציגה 0120 עם האפס המוביל כי זה עדיין טקסט, והסכום ב-B5 הוא 0. עמודה C ממירה כל חלק עם VALUE והסכום נכון. =--MID(A2,4,4) ו-=MID(A2,4,4)*1 ממירות באותה דרך; עוד על זה בהמרת טקסט למספר.
| A | B | |
|---|---|---|
| 1 | Item | Quantity |
| 2 | PK-045-BAG |
תורכם: הכמות נמצאת בין שני המקפים ותמיד יש בה 3 ספרות. ב-B2, חלצו אותה כמספר שאפשר לסכם.
טעות נפוצה: LEFT על תאריך
תאריך נשמר כמספר, ולכן =LEFT(B2,4) על התאריך 2026-03-15 לא מחזירה 2026: היא מחזירה 4609, 4 הספרות הראשונות של 46096, המספר הסידורי שמאחורי התאריך.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Event | Date | LEFT(date,4) | Year |
| 2 | Launch | 2026-03-15 | 4609 | 2026 |
| 3 | 2026 |
השתמשו ב-YEAR(B2) בשביל השנה כמספר, או ב-TEXT(B2,"yyyy") בשביל השנה כטקסט. MONTH, DAY ו-TEXT עם "mmm" או "dd" מכסות את שאר החלקים.
שאלות נפוצות
איך מחלצים את N התווים הראשונים באקסל?
השתמשו ב-LEFT עם המספר: =LEFT(A2,3) מחזירה את 3 התווים הראשונים. בלי הארגומנט השני, =LEFT(A2) מחזירה רק את התו הראשון.
איך מסירים את התווים הראשונים או האחרונים באקסל?
שמרו את השאר עם LEN: =RIGHT(A2,LEN(A2)-3) מסירה את 3 התווים הראשונים ו-=LEFT(A2,LEN(A2)-2) מסירה את 2 האחרונים.
למה אי אפשר לסכם את המספרים ש-MID מחזירה?
LEFT, RIGHT ו-MID מחזירות תמיד טקסט, ו-SUM מדלגת על טקסט. הפכו את התוצאה למספר עם VALUE או עם שני סימני מינוס: =VALUE(MID(A2,5,4)) או =--MID(A2,5,4).
איך מקבלים את הטקסט שלפני תו מסוים באקסל?
מצאו את המיקום של התו וקחו אחד פחות: =LEFT(A2,FIND("-",A2)-1) מחזירה את כל מה שלפני המקף הראשון. ב-Microsoft 365, =TEXTBEFORE(A2,"-") עושה את אותו הדבר.
