=SUMIFS(C2:C7,A2:A7,"North",B2:B7,"Apple") מחברת את המכירות ב-C2:C7 בשורות שבהן עמודה A היא North ועמודה B היא Apple. הטווח שמחברים בא ראשון, ואחריו זוג של טווח ותנאי לכל תנאי.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Condition | Total | |
| 2 | North | Apple | 120 | North, Apple | 150 | |
| 3 | South | Pear | 45 | North, over 50 | 200 | |
| 4 | North | Pear | 80 | North | 230 | |
| 5 | East | Apple | 55 | |||
| 6 | South | Apple | 200 | |||
| 7 | North | Apple | 30 |
שתי שורות הן North וגם Apple, 120 ו-30, ולכן F2 מציג 150. F3 משתמש בעמודת המכירות גם כטווח הסכום וגם כטווח קריטריון: שורות של North מעל 50. ב-F4 יש תנאי אחד והוא עובד כמו SUMIF. שנו את B4 ל-Apple ו-F2 גדל ב-80.
התחביר של SUMIFS
=SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)
sum_rangeהוא התאים שמחברים, והוא בא ראשון. ב-SUMIF הוא בא אחרון:=SUMIF(A2:A7,"North",C2:C7). בלבול בין שני הסדרים הוא טעות נפוצה ב-SUMIFS. אם אתם מעתיקים SUMIF ומוסיפים תנאי, העבירו את טווח הסכום להתחלה.- כל תנאי הוא זוג: טווח וקריטריון, עד 127 זוגות. הקריטריונים עובדים כמו של SUMIF:
"North",">50","*apple*","<>", או תא שמחובר לאופרטור,">="&G2. - שורה מתווספת רק כשכל התנאים מתקיימים.
- כל הטווחים חייבים להיות באותו גודל, אחרת SUMIFS מחזירה
#VALUE!.
SUMIFS עובדת גם עם תנאי אחד, ואם כותבים אותה כך אפשר להוסיף תנאי שני מאוחר יותר בלי לסדר מחדש את הארגומנטים.
SUMIFS עם טווח תאריכים
כדי לסכם חודש אחד, או כל תקופה, השתמשו בעמודת התאריכים פעמיים: פעם עם תאריך ההתחלה ופעם עם תאריך הסיום. שמרו את התאריכים בתאים.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Date | Setting | Value | |
| 2 | North | Apple | 120 | 2026-01-05 | Start | 2026-02-01 | |
| 3 | South | Pear | 45 | 2026-01-12 | End | 2026-02-28 | |
| 4 | North | Pear | 80 | 2026-02-03 | Total | 135 | |
| 5 | East | Apple | 55 | 2026-02-18 | North only | 80 | |
| 6 | South | Apple | 200 | 2026-03-02 | |||
| 7 | North | Apple | 30 | 2026-03-20 |
בפברואר יש שתי הזמנות, 80 ו-55, ולכן G4 מציג 135, ו-G5 משאיר רק את זו של North. שנו את G3 ל-2026-03-31 כדי לכלול את מרץ. אם בתאריכים יש גם שעות, "<="&G3 נעצר ב-0:00 ביום האחרון: השתמשו ב-"<"&G3+1 כתנאי הסיום כדי שהזמנות מאוחר יותר באותו יום ייספרו.
כדי לסכם חודש שלם מתאריך אחד שבתא, תנו ל-EOMONTH למצוא את היום האחרון: =SUMIFS(C2:C7,D2:D7,">="&G2,D2:D7,"<="&EOMONTH(G2,0)).
SUMIFS עם OR
התנאים ב-SUMIFS תמיד מחוברים עם AND. ל-North או South, תנו לתנאי של האזור רשימה בסוגריים מסולסלים: SUMIFS מחזירה סכום אחד לכל פריט ו-SUM מחברת אותם.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Condition | Total | |
| 2 | North | Apple | 120 | North or South | 475 | |
| 3 | South | Pear | 45 | North or South, Apple | 350 | |
| 4 | North | Pear | 80 | Two SUMIFS | 475 | |
| 5 | East | Apple | 55 | |||
| 6 | South | Apple | 200 | |||
| 7 | North | Apple | 30 |
F2 ו-F4 נותנים שניהם 475, הכול חוץ משורת ה-East. F3 משלב את ה-OR על האזורים עם AND על המוצר. שימו את הרשימה בקריטריון אחד בלבד: שתי רשימות באותה SUMIFS מצמדות את הפריטים שלהן לפי מיקום במקום לנסות כל צירוף.
SUMIFS עם קריטריון ריק: מסנן אופציונלי
בדוח יש לעתים קרובות תאי מסנן שהקורא יכול להשאיר ריקים כדי לומר "הכול". תא ריק שמשמש כקריטריון לא אומר "כל דבר": אקסל קורא אותו כ-0, שלא מתאים לשום דבר בעמודת טקסט. החליפו אותו בתו הכללי "*", שמתאים לכל טקסט. בחרו אזור ומוצר מהרשימות, או נקו אותם.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Filter | Value | ||
| 2 | North | Apple | 120 | Region | North | ||
| 3 | South | Pear | 45 | Product | |||
| 4 | North | Pear | 80 | Total | 230 | ||
| 5 | East | Apple | 55 | ||||
| 6 | South | Apple | 200 | ||||
| 7 | North | Apple | 30 |
כש-North נבחר ואין מוצר, G4 מחבר כל שורה של North: 230. בחרו Apple ב-G3 והוא יורד ל-150; נקו את G2 והוא מחבר את Apple מכל האזורים. "*" מתאים רק לטקסט, ולכן זה עובד בעמודות טקסט; עמודה של מספרים צריכה במקום זאת טווח, ">="&min ו-"<="&max.
כדי לחבר את השורות שבהן עמודה ריקה או מלאה, השתמשו ב-"" וב-"<>" כקריטריונים. כשבעמודה D יש תאריך תשלום, =SUMIFS(C2:C7,A2:A7,"North",D2:D7,"") מחברת את המכירות של North שעוד לא שולמו.
תרגול: SUMIFS
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Condition | Total | |
| 2 | North | Apple | 120 | South, Apple | ||
| 3 | South | Pear | 45 | |||
| 4 | North | Pear | 80 | |||
| 5 | East | Apple | 55 | |||
| 6 | South | Apple | 200 | |||
| 7 | North | Apple | 30 | |||
| 8 | South | Apple | 75 |
תורכם: חברו את המכירות שבהן האזור הוא South והמוצר הוא Apple. כתבו את הנוסחה ב-F2.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Date | Setting | Value | |
| 2 | North | Apple | 120 | 2026-01-05 | Start | 2026-01-10 | |
| 3 | South | Pear | 45 | 2026-01-12 | End | 2026-03-05 | |
| 4 | North | Pear | 80 | 2026-02-03 | Total | ||
| 5 | East | Apple | 55 | 2026-02-18 | |||
| 6 | South | Apple | 200 | 2026-03-02 | |||
| 7 | North | Apple | 30 | 2026-03-20 | |||
| 8 | North | Plum | 65 | 2026-03-01 |
תורכם: חברו את המכירות של North שתאריכן מ-G2 עד G3, כולל שני הימים. כתבו את הנוסחה ב-G4.
SUMIFS מול SUMIF מול SUMPRODUCT
| מה צריך | במה להשתמש |
|---|---|
| תנאי אחד | SUMIF(range,criteria,sum_range) או SUMIFS עם זוג אחד |
| כמה תנאים, שכולם מתקיימים | SUMIFS(sum_range,range1,criteria1,range2,criteria2) |
| אחד מכמה ערכים בעמודה אחת | SUM(SUMIFS(sum_range,range,{"a","b"})) |
| תנאי על חישוב (החודש של תאריך, עמודה אחת מול אחרת, מחיר כפול כמות) | SUMPRODUCT |
| אותם תנאים, אבל ספירה | COUNTIFS |
אם SUMIFS מחזירה 0, בדקו כל תנאי לבד עם COUNTIFS על אותם טווחים: התנאי שהספירה שלו 0 הוא זה שאף פעם לא מתאים, בדרך כלל בגלל רווח בסוף, מספר שמאוחסן כטקסט, או תא שנכתב בתוך המירכאות (">=G2" במקום ">="&G2).
שאלות נפוצות
מה ההבדל בין SUMIF ל-SUMIFS?
SUMIF מקבלת תנאי אחד ושמה את טווח הסכום בסוף: =SUMIF(A2:A7,"North",C2:C7). SUMIFS מקבלת כל מספר של תנאים ושמה את טווח הסכום בהתחלה: =SUMIFS(C2:C7,A2:A7,"North",B2:B7,"Apple"). עם תנאי אחד שתיהן נותנות את אותו סכום.
איך משתמשים ב-SUMIFS עם טווח תאריכים?
השתמשו בעמודת התאריכים פעמיים, עם התחלה ועם סוף: =SUMIFS(C2:C7,D2:D7,">="&G2,D2:D7,"<="&G3) מחברת את המכירות שתאריכן מ-G2 עד G3, כולל שניהם.
האם SUMIFS יכולה להשתמש בלוגיקת OR?
לא ישירות: התנאים שלה מחוברים עם AND. תנו לקריטריון אחד רשימה וסכמו את התוצאות: =SUM(SUMIFS(C2:C7,A2:A7,{"North","South"})) מסכמת את North ואת South.
למה SUMIFS מחזירה #VALUE!?
טווח הסכום וטווחי הקריטריונים אינם באותו גודל, למשל C2:C7 עם A2:A8. בניגוד ל-SUMIF, SUMIFS לא משנה את הגודל שלהם; לכל טווח חייב להיות אותו מספר של שורות ועמודות.
איך הופכים קריטריון של SUMIFS לאופציונלי?
החליפו תא מסנן ריק בתו הכללי "*", שמתאים לכל טקסט: =SUMIFS(C2:C7,A2:A7,IF(G2="","*",G2)). כש-G2 ריק, כל האזורים נכללים.
