=SUMIF(A2:A7,"North",C2:C7) מחברת את המכירות ב-C2:C7 בכל שורה שבה בעמודה A כתוב North. SUMIF בודקת טווח אחד מול תנאי ומחברת את השורות המתאימות של טווח אחר.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Region | Total | |
| 2 | North | Apple | 120 | North | 230 | |
| 3 | South | Pear | 45 | South | 245 | |
| 4 | North | Pear | 80 | |||
| 5 | East | Apple | 55 | |||
| 6 | South | Apple | 200 | |||
| 7 | North | Apple | 30 |
F2 מחבר את 120, 80 ו-30, שלוש השורות של North, ומציג 230. F3 לוקח את האזור שלו מ-E3: שנו את E3 ל-East והוא יציג 55. שנו מספר כלשהו בעמודה C ושני הסכומים מתעדכנים.
התחביר של SUMIF
=SUMIF(range, criteria, [sum_range])
rangeהוא התאים שהתנאי נבדק מולם.criteriaהוא התנאי: טקסט במירכאות ("North"), השוואה (">100"), תבנית עם תווים כלליים ("*apple*"), או תא (E3, או">"&F2עם אופרטור).sum_rangeהוא התאים שמחברים. הוא אופציונלי: בלעדיו, SUMIF מחברת את התאים המתאימים שלrangeעצמו.
range ו-sum_range מותאמים שורה מול שורה, ולכן הם צריכים להתחיל באותה שורה ולהיות באותו גודל. באקסל שמוגדר לשפה שמשתמשת בפסיק עשרוני, הארגומנטים מופרדים בנקודה פסיק: =SUMIF(A2:A7;"North";C2:C7).
SUMIF גדול מ או קטן מ
כדי לחבר את המספרים שמעל ערך מסוים או מתחתיו, התנאי והסכום נמצאים באותה עמודה, ולכן אפשר להשמיט את sum_range.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Condition | Total | |
| 2 | North | Apple | 120 | Over 100 | 320 | |
| 3 | South | Pear | 45 | 100 or less | 210 | |
| 4 | North | Pear | 80 | Not North | 300 | |
| 5 | East | Apple | 55 | Limit | 50 | |
| 6 | South | Apple | 200 | Over the limit | 455 | |
| 7 | North | Apple | 30 |
F2 מחבר את 120 ו-200, F3 מחבר את ארבעת האחרים, ושניהם יחד תמיד נותנים את הסכום הכולל. F4 מראה "שונה מ": הכול חוץ מ-North. F6 קורא את הסף שלו מ-F5. כתבו את האופרטור במירכאות וחברו את התא עם &: ">"&F5, אף פעם לא ">F5".
SUMIF אם תא מכיל טקסט
* בקריטריון מייצג כל מספר של תווים ו-? מייצג תו אחד בדיוק. "*apple*" מתאים לכל מוצר שיש בשם שלו apple במקום כלשהו, בכל גודל אותיות.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Product | Sales | Condition | Total | |
| 2 | Apple | 120 | contains apple | 250 | |
| 3 | Pineapple | 45 | exactly Apple | 120 | |
| 4 | Pear | 80 | starts with P | 325 | |
| 5 | Green apple | 55 | word in D6 | 80 | |
| 6 | Plum | 200 | pear | ||
| 7 | Apple cider | 30 |
E2 מחבר את Apple, Pineapple, Green apple ו-Apple cider. E3, בלי תווים כלליים, מחבר רק את התא שהוא בדיוק Apple. E5 בונה את התבנית מהמילה שב-D6: שנו את D6 ל-cider ו-E5 יציג רק את המכירות של cider. עוד תבניות, ו-~ לכוכבית אמיתית, נמצאים בעמוד על תווים כלליים.
כדי לחבר את הערכים שליד כל תא מלא, השתמשו ב-"<>" (לא ריק): =SUMIF(A2:A7,"<>",B2:B7). "" מחבר את השורות שבהן התא ריק.
SUMIF לפי תאריך
תאריכים הם מספרים, ולכן ">=", "<" וכל השאר עובדים עליהם. בנו את התאריך עם DATE או שמרו אותו בתא, וחברו אותו לאופרטור עם &.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Sales | Date | Condition | Total | |
| 2 | North | 120 | 2026-01-05 | From Feb 1 | 365 | |
| 3 | South | 45 | 2026-01-12 | Cutoff | 2026-03-01 | |
| 4 | North | 80 | 2026-02-03 | Before the cutoff | 300 | |
| 5 | East | 55 | 2026-02-18 | On Jan 12 | 45 | |
| 6 | South | 200 | 2026-03-02 | |||
| 7 | North | 30 | 2026-03-20 |
F2 מחבר את ארבע ההזמנות מ-1 בפברואר והלאה: 80, 55, 200 ו-30, שהם 365. F4 מחבר את ההזמנות שלפני התאריך שב-F3. סכום של חודש אחד דורש תאריך התחלה ותאריך סיום, שני תנאים על אותה עמודה, וזו עבודה ל-SUMIFS: =SUMIFS(B2:B7,C2:C7,">="&DATE(2026,2,1),C2:C7,"<"&DATE(2026,3,1)).
SUMIF מגיליון אחר
הטווחים יכולים להיות בגיליון אחר: כתבו את שם הגיליון ואת ! לפניהם. למטה, הנתונים נמצאים בלשונית Sales והסיכום בלשונית משלו. לחצו על הלשונית Sales כדי לראות את השורות שמתחברות.
| A | B | |
|---|---|---|
| 1 | Region | Total |
| 2 | North | 230 |
| 3 | South | 245 |
| 4 | East | 55 |
B2 מועתק למטה עד B4: הקריטריון A2 עובר ל-A3 ול-A4, וה-$ משאיר את שני הטווחים באותן שורות של הגיליון Sales. בלי ה-$, העותק השלישי היה קורא את Sales!A4:A9 ומפספס את השורות הראשונות. התבנית הזו, רשימת תוויות עם SUMIF אחת ליד כל אחת, היא הדרך לבנות סיכום לפי קטגוריה בלי טבלת ציר. שם גיליון עם רווח צריך גרשיים: 'Sales 2026'!$A$2:$A$7.
תרגול: SUMIF
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Product | Total | |
| 2 | North | Apple | 120 | Apple | ||
| 3 | South | Pear | 45 | |||
| 4 | North | Pear | 80 | |||
| 5 | East | Apple | 55 | |||
| 6 | South | Apple | 200 | |||
| 7 | North | Plum | 30 | |||
| 8 | West | Apple | 65 |
תורכם: חברו את המכירות של השורות של Apple. כתבו את הנוסחה ב-F2.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Order | Amount | Condition | Total | |
| 2 | A-101 | 120 | 100 or more | ||
| 3 | A-102 | 45 | |||
| 4 | A-103 | 310 | |||
| 5 | A-104 | 100 | |||
| 6 | A-105 | 85 | |||
| 7 | A-106 | 140 | |||
| 8 | A-107 | 99 |
תורכם: חברו את ההזמנות של 100 או יותר ב-B2:B8. כתבו את הנוסחה ב-E2.
SUMIF עם כמה קריטריונים
SUMIF מקבלת תנאי אחד. שני מקרים חוזרים הרבה.
שני התנאים חייבים להתקיים (North וגם Apple): השתמשו ב-SUMIFS. טווח הסכום שלה בא ראשון, ואחריו זוגות התנאים.
=SUMIFS(C2:C7,A2:A7,"North",B2:B7,"Apple")
אחד משני ערכים באותה עמודה (North או South): תנו ל-SUMIF רשימה בסוגריים מסולסלים וסכמו את שתי התוצאות עם SUM, או חברו שתי פונקציות SUMIF.
=SUM(SUMIF(A2:A7,{"North","South"},C2:C7))
=SUMIF(A2:A7,"North",C2:C7)+SUMIF(A2:A7,"South",C2:C7)
לתנאי על חישוב (החודש של תאריך, מכירות כפול מחיר), SUMIF לא יכולה לעזור; SUMPRODUCT יכולה.
למה SUMIF מחזירה 0 או סכום שגוי
- הקריטריון אף פעם לא מתאים. "North " עם רווח בסוף אינו שווה ל-"North". בדקו את התנאי עם
=COUNTIF(A2:A7,"North"): אם התוצאה 0, הבעיה היא בהתאמה, לא בסכום. - מספרים שמאוחסנים כטקסט בטווח הסכום. SUMIF מדלגת עליהם בשקט. בדרך כלל הם מיושרים לשמאל התא ויש להם משולש ירוק; המירו אותם קודם למספרים.
- תא בתוך המירכאות.
">F5"משווה לטקסט F5. כתבו">"&F5. - טווחים בגדלים שונים.
=SUMIF(A2:A7,"North",C2)לא מחזירה שגיאה: אקסל משנה את הגודל שלsum_rangeכך שיתאים ל-range, החל מהתא הראשון שלו. זה עובד, אבל טווח סכום שמתחיל בשורה הלא נכונה מחבר בשקט את התאים הלא נכונים, ולכן תמיד תנו לשני הטווחים את אותן שורות. - הטווחים נמצאים בחוברת עבודה אחרת שסגורה. SUMIF מציגה
#VALUE!עד שהקובץ נפתח.
שאלות נפוצות
איך SUMIF עובדת באקסל?
=SUMIF(range, criteria, sum_range) בודקת כל תא של range מול הקריטריון, וכשיש התאמה היא מוסיפה את התא שבאותה שורה של sum_range. =SUMIF(A2:A7,"North",C2:C7) מסכמת את עמודה C עבור השורות של North.
איך מסכמים ערכים שגדולים ממספר?
השמיטו את טווח הסכום ושימו את ההשוואה במירכאות: =SUMIF(C2:C7,">100") מחברת כל ערך ב-C2:C7 שגדול מ-100. כשהסף נמצא בתא, כתבו =SUMIF(C2:C7,">"&F2).
איך מסכמים אם תא מכיל טקסט?
שימו כוכביות סביב הטקסט: =SUMIF(B2:B7,"*apple*",C2:C7) מחברת את עמודה C בכל מקום שבו עמודה B מכילה apple, כמו Apple, Pineapple או Green apple. ההתאמה מתעלמת מגודל האותיות.
איך משתמשים ב-SUMIF עם כמה קריטריונים?
כשכל התנאים חייבים להתקיים, השתמשו ב-SUMIFS: =SUMIFS(C2:C7,A2:A7,"North",B2:B7,"Apple"). לאחד משני ערכים באותה עמודה, סכמו את התוצאות של רשימה: =SUM(SUMIF(A2:A7,{"North","South"},C2:C7)).
למה ה-SUMIF שלי מחזירה 0?
בדרך כלל הקריטריון אף פעם לא מתאים (רווח בסוף הנתונים, או ">F2" שנכתב במקום ">"&F2), או שהמספרים בטווח הסכום מאוחסנים כטקסט, ו-SUMIF מדלגת עליהם. בדקו את ההתאמה עם COUNTIF עם אותו טווח ואותו קריטריון.
