Buat Laporan

Termasuk bagian Logika dan Alur dalam perjalanan GDScript di Coddy. Pelajaran 75 dari 78.

Tantangan

Sulit

Terakhir, tambahkan perintah sell, yang menjual beberapa barang sekaligus dan melaporkan pendapatannya. Pertahankan semua yang kamu tulis pada langkah-langkah sebelumnya.

Baris seperti sell Apple:30 Banana:20 menjual 30 apel dan 20 pisang. Setiap bagian setelah sell terdiri dari nama barang, titik dua, dan jumlah, dan sebuah barang muncul paling banyak satu kali per baris.

Tulis fungsi sales_report(inventory, sales) di atas _ready(). sales adalah dictionary yang memetakan setiap nama barang ke jumlah yang terjual. Untuk setiap barang, lakukan langkah-langkah berikut secara berurutan:

Jika barang tidak ada di inventory, cetak Error: Item 'Orange' not found. lalu lanjutkan ke barang berikutnya
Jika stoknya lebih sedikit daripada jumlah yang diminta, cetak Error: Insufficient stock for 'Apple'. lalu lanjutkan ke barang berikutnya
Jika tidak, kurangi stok sebanyak jumlah tersebut dan tambahkan hasil perkalian jumlah dengan harga ke pendapatan

Fungsi ini mengembalikan teks Total revenue: $ diikuti pendapatan dengan dua angka desimal.

Di dalam perulangan, bagian sell membangun dictionary sales dari bagian-bagian setelah perintah. Bagian yang tidak tepat berupa nama dan bilangan bulat yang dipisahkan oleh : akan mencetak Error: Invalid sale 'Apple-3'. (dengan bagian tersebut) dan dilewati. Lalu, cetak hasil yang dikembalikan oleh sales_report().

Untuk perintah add Apple 0.5 50, add Banana 0.2 60, sell Apple:30 Banana:20 Orange:10, show, dan exit, output-nya adalah:

Inventory Management System
Item 'Apple' added successfully.
Item 'Banana' added successfully.
Error: Item 'Orange' not found.
Total revenue: $19.00
{ "Apple": { "price": 0.5, "stock": 20 }, "Banana": { "price": 0.2, "stock": 40 } }
Goodbye!

Coba sendiri

extends Node

func add_item(inventory: Dictionary, item: String, price: float, stock: int) -> void:
	if inventory.has(item):
		print("Error: Item '%s' already exists." % item)
		return
	inventory[item] = {"price": price, "stock": stock}
	print("Item '%s' added successfully." % item)

func update_stock(inventory: Dictionary, item: String, quantity: int) -> void:
	if not inventory.has(item):
		print("Error: Item '%s' not found." % item)
		return
	var new_stock: int = inventory[item]["stock"] + quantity
	if new_stock < 0:
		print("Error: Insufficient stock for '%s'." % item)
		return
	inventory[item]["stock"] = new_stock
	print("Stock for '%s' updated successfully." % item)

func check_availability(inventory: Dictionary, item: String) -> int:
	if not inventory.has(item):
		return -1
	return inventory[item]["stock"]

func _ready():
	# Inventaris: nama item -> {"price": float, "stock": int}
	var inventory := {}
	print("Inventory Management System")

	while true:
		var line := OS.read_string_from_stdin()
		var parts := line.split(" ")
		var command := parts[0]

		if command == "exit":
			print("Goodbye!")
			break
		elif command == "show":
			print(inventory)
		elif command == "add":
			if parts.size() != 4:
				print("Error: Use add ITEM PRICE STOCK")
			elif not parts[2].is_valid_float() or not parts[3].is_valid_int():
				print("Error: Price and stock must be numeric.")
			else:
				add_item(inventory, parts[1], float(parts[2]), int(parts[3]))
		elif command == "update":
			if parts.size() != 3:
				print("Error: Use update ITEM QUANTITY")
			elif not parts[2].is_valid_int():
				print("Error: Quantity must be an integer.")
			else:
				update_stock(inventory, parts[1], int(parts[2]))
		elif command == "check":
			if parts.size() != 2:
				print("Error: Use check ITEM")
			else:
				var stock := check_availability(inventory, parts[1])
				if stock == -1:
					print("Item not found")
				else:
					print(parts[1], ": ", stock, " in stock")
		else:
			print("Unknown command")