Guard pada Match

Guard menambahkan kondisi pada sebuah pola. Tulis when dan sebuah kondisi setelah pola: pola hanya cocok jika nilainya sesuai dengan pola dan kondisinya true. Guard tersedia sejak Godot 4.4.

var hp := 15
match hp:
	0:
		print("Defeated")
	var h when h < 20:
		print("Low health: ", h)
	_:
		print("Healthy")

Low health: 15

GDScript tidak memiliki pola rentang seperti 1..10. Pola pengikatan dengan guard dapat digunakan untuk itu: var h when h < 20: cocok dengan setiap nilai di bawah 20 dan menamainya h.

Jika guard bernilai false, match akan melanjutkan ke pola berikutnya. Pola dicoba dari atas ke bawah, jadi urutannya menentukan blok mana yang dijalankan:

var temp := 32
match temp:
	var t when t <= 0:
		print("Freezing")
	var t when t < 15:
		print("Cold")
	var t when t < 30:
		print("Warm")
	_:
		print("Hot")

Hot

Pola kedua tidak memerlukan t > 0: suhu 0 atau di bawahnya sudah cocok dengan pola pertama. Guard dapat menggunakan kondisi apa pun, dengan variabel lain dan and atau or, serta dapat digunakan dengan pola apa pun: 5 when hard_mode: hanya cocok dengan 5 saat hard_mode bernilai true.