Daftar Berdasarkan Kursus

Termasuk bagian Logika dan Alur dalam perjalanan GDScript di Coddy. Pelajaran 47 dari 78.

Tantangan

Mudah

Daftarkan pelajar yang mengambil suatu kursus. Pertahankan semua yang kamu tulis pada langkah-langkah sebelumnya.

1. Fungsinya. Di bawah fungsi-fungsi lainnya, tulis list_students_by_course(course: String) -> Array. Fungsi ini melakukan perulangan pada student_records dan mengembalikan array berisi nama-nama pelajar yang set "courses"-nya memiliki kursus tersebut, sesuai urutan pelajar ditambahkan. Jika tidak ada yang mengambil kursus tersebut, fungsi ini mengembalikan array kosong.

2. Perintahnya. Tambahkan cabang untuk course <course>, seperti course Math, di atas ["show"]. Cabang ini mencetak array yang dikembalikan oleh list_students_by_course(). Untuk perintah-perintah

add Alice 20 Math Physics
add Bob 22 Math Biology
add Diana 23 Chemistry Physics
course Math
course Physics
course Biology
course History
exit

output-nya adalah:

Student 'Alice' added successfully.
Student 'Bob' added successfully.
Student 'Diana' added successfully.
["Alice", "Bob"]
["Alice", "Diana"]
["Bob"]
[]
Goodbye!

Coba sendiri

extends Node

# Setiap siswa: name -> {"age": int, "grades": Array, "courses": set nama kursus}
var student_records := {}

func _ready():
	while true:
		var parts := Array(OS.read_string_from_stdin().split(" ", false))
		match parts:
			["add", var student, var age, ..]:
				add_student(student, int(age), parts.slice(3))
			["grade", var student, var grade]:
				add_grade(student, int(grade))
			["enrolled", var student, var course]:
				print(is_enrolled(student, course))
			["average", var student]:
				var average := calculate_average_grade(student)
				if average >= 0:
					print("Average grade of '%s': %.2f" % [student, average])
			["show"]:
				print(student_records)
			["exit"]:
				print("Goodbye!")
				break

func add_student(student_name: String, age: int, courses: Array) -> void:
	if student_records.has(student_name):
		print("Student '%s' already exists." % student_name)
		return
	var course_set := {}
	for course in courses:
		course_set[course] = true
	student_records[student_name] = {"age": age, "grades": [], "courses": course_set}
	print("Student '%s' added successfully." % student_name)

func add_grade(student_name: String, grade: int) -> void:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return
	student_records[student_name]["grades"].append(grade)
	print("Grade %d added for student '%s'." % [grade, student_name])

func is_enrolled(student_name: String, course: String) -> bool:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return false
	return student_records[student_name]["courses"].has(course)

func calculate_average_grade(student_name: String) -> float:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return -1.0
	var grades: Array = student_records[student_name]["grades"]
	if grades.is_empty():
		return 0.0
	var total := 0
	for grade in grades:
		total += grade
	return float(total) / grades.size()