Bersihkan Dinding

Termasuk bagian Proyek dalam perjalanan Godot di Coddy. Pelajaran 9 dari 33.

Langkah terakhir adalah cara untuk menang: hancurkan setiap batu bata.

Hitung jumlah batu bata yang tersisa. Mulai dari 40 dan kurangi satu setiap kali brick_broken muncul. Saat jumlahnya nol, dinding sudah bersih:

bricks_left -= 1
if bricks_left == 0:
	$HUD/Message.text = "You Win!"
	get_tree().paused = true

Kurangi satu sebelum memeriksa apakah jumlahnya nol. Jika kamu memeriksanya lebih dahulu, pemeriksaan akan melihat angka 1 pada batu bata terakhir dan tidak pernah melihat angka 0.

Tombol Enter dari Game Over juga memulai permainan baru di sini. Breakout-mu selesai.

Tantangan

Sedang

Di main.gd:

Tambahkan var bricks_left = 40.
Setiap bata yang hancur mengurangi jumlahnya satu.
Jika tidak ada bata yang tersisa, tampilkan You Win! di $HUD/Message dan jeda permainan.

Coba sendiri

extends Node2D

const BRICK = preload("res://brick.tscn")
const COLORS = [Color(1, 0.42, 0.42), Color(1, 0.78, 0.34), Color(0.49, 0.95, 0.75), Color(0.369, 0.635, 1), Color(0.75, 0.82, 0.95)]

var score = 0
var lives = 3

func _ready():
	for row in 5:
		for column in 8:
			var brick = BRICK.instantiate()
			brick.position = Vector2(68 + column * 72, 60 + row * 26)
			brick.color = COLORS[row]
			add_child(brick)
	$Ball.brick_broken.connect(_on_brick_broken)
	$HUD/Score.text = "Score: 0"
	$Ball.missed.connect(_on_missed)
	$HUD/Lives.text = "Lives: 3"

func _process(delta):
	if get_tree().paused and Input.is_action_just_pressed("action"):
		get_tree().paused = false
		get_tree().reload_current_scene()

func _on_brick_broken():
	score += 10
	$HUD/Score.text = "Score: %d" % score

func _on_missed():
	lives -= 1
	$HUD/Lives.text = "Lives: %d" % lives
	if lives == 0:
		$HUD/Message.text = "Game Over"
		get_tree().paused = true