Catene di ereditarietà

Una classe figlia può essere a sua volta una classe genitore. Ogni extends aggiunge un livello alla catena di ereditarietà:

# vehicle.gd
class_name Vehicle
extends RefCounted

var wheels: int

func _init(w: int) -> void:
	wheels = w

func describe() -> String:
	return "%d wheels" % wheels

# car.gd
class_name Car
extends Vehicle

func _init() -> void:
	super(4)

func describe() -> String:
	return "Car with " + super()

# race_car.gd
class_name RaceCar
extends Car

var top_speed: int

func _init(speed: int) -> void:
	super()
	top_speed = speed

func describe() -> String:
	return super() + ", top speed %d" % top_speed

RaceCar ha tutto ciò che proviene da Car e da Vehicle. Ogni super() sale di un livello, quindi una chiamata esegue tutte e tre le versioni di describe():

print(RaceCar.new(300).describe())

Car with 4 wheels, top speed 300

Quando chiami un metodo o leggi una variabile, Godot cerca prima nella classe dell'oggetto stesso, poi nella classe genitore, poi nella classe genitore della classe genitore e usa la prima che trova. RaceCar.new(300).wheels si trova in Vehicle, due livelli più in alto.

Ogni classe ha esattamente una classe genitore. extends accetta una sola classe e indicarne due genera un errore di analisi:

class_name FlyingCar
extends Car, Plane

Parse Error: Expected end of statement after superclass, found "," instead.

GDScript non supporta l’ereditarietà multipla. Quando una classe ha bisogno delle funzionalità di due classi, inseriscile in un’unica catena oppure assegnale un oggetto dell’altra classe con cui lavorare (un capitolo successivo approfondisce questo argomento).