Che cos'è un segnale?

Fa parte della sezione Programmazione orientata agli oggetti del percorso GDScript di Coddy. Lezione 35 di 65.

Agli oggetti accadono delle cose mentre il gioco è in esecuzione: una moneta viene raccolta, una porta si apre, gli hp dell’eroe scendono a 0. Altre parti del programma reagiscono a questi eventi: il punteggio aumenta, viene riprodotto un suono, appare la schermata di fine partita.

Un segnale è un messaggio che un oggetto invia quando gli accade qualcosa. L’oggetto emette il segnale e ogni funzione collegata a quel segnale viene eseguita:

# coin.gd
class_name Coin
extends RefCounted

signal collected

func collect() -> void:
	print("Coin picked up")
	collected.emit()

signal collected dichiara il segnale e collected.emit() lo invia. La moneta non sa chi è in ascolto. Il codice interessato alle monete collega una delle proprie funzioni al segnale:

# main.gd
func _ready():
	var coin := Coin.new()
	coin.collected.connect(_on_coin_collected)
	coin.collect()
	print("Done")

func _on_coin_collected() -> void:
	print("Score +1")

L'output è Coin picked up, Score +1, Done. L'emissione esegue subito le funzioni collegate, prima della riga successiva a emit(). Un segnale senza funzioni collegate non fa nulla quando viene emesso.

Senza un segnale, collect() dovrebbe chiamare direttamente il codice del punteggio, quindi ogni moneta dovrebbe avere un riferimento al tabellone dei punteggi. Con un segnale, la moneta si limita ad annunciare l'evento e un numero qualsiasi di listener, oppure nessuno, può reagire.

Anche i nodi di Godot funzionano allo stesso modo: un Button emette pressed quando viene cliccato e un Timer emette timeout quando il tempo scade.

Sfida

Facile

Una casella postale annuncia la nuova posta con un segnale. Mailbox dichiara già signal mail_arrived e ha un contatore letters. Scrivi deliver(kind):

Quando kind è "letter", aggiungi 1 a letters ed emetti mail_arrived.
Qualsiasi altro tipo (una pubblicità, un volantino) viene buttato via: non cambia nulla e non viene emesso nulla.

Il codice fornito collega una funzione che stampa You've got mail!, poi legge quante righe seguono e consegna ciascuna di esse. La riga away scollega quella funzione e home la collega di nuovo, quindi una lettera che arriva mentre sei via viene conteggiata, ma non annunciata. Per le righe letter, ad, away, letter stampa:

Delivering: letter
You've got mail!
Delivering: ad
Delivering: letter
Letters: 2

Inserisci il tuo codice in mailbox.gd. main.gd contiene il codice fornito per l'input/output e non può essere modificato.

Provalo tu

extends Node

func _ready():
	# Codice di input/output fornito: lascialo così com'è
	var mailbox := Mailbox.new()
	mailbox.mail_arrived.connect(_on_mail_arrived)
	var count := int(OS.read_string_from_stdin())
	for i in count:
		var line := OS.read_string_from_stdin()
		if line == "away":
			mailbox.mail_arrived.disconnect(_on_mail_arrived)
		elif line == "home":
			mailbox.mail_arrived.connect(_on_mail_arrived)
		else:
			print("Delivering: ", line)
			mailbox.deliver(line)
	print("Letters: ", mailbox.letters)

func _on_mail_arrived() -> void:
	print("You've got mail!")