Padrão Composite

O padrão Composite cria árvores nas quais um único objeto e um grupo de objetos têm os mesmos métodos, para que o código possa tratar um grupo inteiro como um único item. Uma sacola contém itens, uma sacola pode conter outras sacolas, e você pode perguntar o peso de qualquer uma delas da mesma maneira.

Ambos os tipos compartilham um pai abstrato:

# entry.gd
@abstract
class_name Entry
extends RefCounted

var entry_name: String

@abstract func get_weight() -> int
@abstract func display(indent: String) -> void

A folha é um único item:

# item.gd
class_name Item
extends Entry

var weight: int

func _init(n: String, w: int) -> void:
	entry_name = n
	weight = w

func get_weight() -> int:
	return weight

func display(indent: String) -> void:
	print(indent, entry_name, " (", weight, ")")

O composto contém outras entradas e responde consultando cada uma delas. Uma bolsa pesa 1 por si só:

# bag.gd
class_name Bag
extends Entry

var contents: Array[Entry] = []

func _init(n: String) -> void:
	entry_name = n

func add(entry: Entry) -> void:
	contents.append(entry)

func get_weight() -> int:
	var total := 1
	for entry in contents:
		total += entry.get_weight()
	return total

func display(indent: String) -> void:
	print(indent, entry_name, " [", get_weight(), "]")
	for entry in contents:
		entry.display(indent + "  ")

# main.gd
var pouch := Bag.new("Pouch")
pouch.add(Item.new("Gem", 2))
var backpack := Bag.new("Backpack")
backpack.add(Item.new("Sword", 8))
backpack.add(pouch)
backpack.display("")

Backpack [12]
  Sword (8)
  Pouch [3]
    Gem (2)

Bag.get_weight() nunca verifica se uma entrada é um item ou uma bolsa: ele chama o mesmo método em cada uma, e uma bolsa dentro de outra responde perguntando aos próprios conteúdos. Essa recursão percorre toda a árvore, por mais profunda que seja.

Os links seguem em uma só direção, de uma pasta para seu conteúdo. Se cada entrada também armazenasse a pasta em que está, cada pasta e suas entradas apontariam umas para as outras, formando um ciclo de referências que nunca é liberado. Quando uma entrada precisa saber onde está, passe essa informação como argumento, da mesma forma que display() passa a indentação.