RefCounted vs. Node

Cada objeto ocupa memória até ser liberado. RefCounted e Node são liberados de maneiras diferentes.

Um objeto RefCounted conta as variáveis, os arrays e os objetos que fazem referência a ele. Quando a contagem chega a zero, o Godot o libera por conta própria. NOTIFICATION_PREDELETE, do capítulo Métodos especiais, mostra o momento:

# note.gd
class_name Note
extends RefCounted

func _notification(what: int) -> void:
	if what == NOTIFICATION_PREDELETE:
		print("Note freed")

# main.gd
func write() -> void:
	var note := Note.new()
	print("Note written")

func _ready():
	write()          # Note escrita, depois Note liberada
	print("Back in _ready")

note era a única referência, então a nota é liberada assim que write() termina.

Um Node não é contado. Um nó na árvore de cena é liberado junto com seu pai, e a árvore inteira é liberada quando o jogo termina. Um nó que você remove da árvore, ou nunca adiciona a ela, deve ser liberado por você:

crate.free()         # liberado agora, junto com todos os seus filhos
crate.queue_free()   # liberado ao final do quadro atual

Após free(), o nó desaparece: is_instance_valid(crate) retorna false, e chamar um método nele é um erro. queue_free() é a opção segura enquanto outro código ainda puder usar o nó neste quadro, mas, até o fim desse quadro, o nó permanece na árvore e ainda é contado em get_child_count().

Um nó que nunca é liberado é um vazamento de memória: Godot informa "ObjectDB instances were leaked at exit" quando o programa termina. Objetos RefCounted também causam vazamentos quando dois deles fazem referência um ao outro, porque nenhuma das contagens pode chegar a zero. Armazene o link em apenas uma direção ou armazene um nome em vez do objeto.

Use RefCounted para dados: itens, pontuações, registros. Use Node para coisas que vivem na árvore de cena.