Construtor (_init)

Definir cada propriedade após new() exige várias linhas, e é fácil esquecer uma. Um construtor configura um objeto no momento em que ele é criado. Em GDScript, o construtor é o método _init():

# book.gd
class_name Book
extends RefCounted

var title: String
var author: String
var pages: int

func _init(book_title: String, book_author: String, page_count: int) -> void:
	title = book_title
	author = book_author
	pages = page_count

Os argumentos que você passa para new() são enviados para _init(), que é executado automaticamente antes de new() retornar o objeto:

var dune := Book.new("Dune", "Frank Herbert", 412)
print(dune.title) # Dune
print(dune.pages) # 412

Quando _init() tem parâmetros, new() deve passá-los: Book.new() sem argumentos é um erro informado antes de o programa ser executado. Um parâmetro com um valor padrão é opcional:

func _init(book_title: String, book_author: String = "Unknown") -> void:

Com este construtor, Book.new("Notes") cria um livro cujo autor é "Unknown".

Os nomes dos parâmetros acima diferem dos nomes das propriedades. Se fossem iguais, você escreveria self.title = title, como na lição sobre self.