Per andare a capo dentro una cella, premi Alt+Invio mentre scrivi. Su Mac, premi Ctrl+Opzione+A capo; Microsoft 365 per Mac accetta anche Opzione+A capo. In una formula, l'a capo è CODICE.CARATT(10) (in inglese CHAR(10)): =A2&CODICE.CARATT(10)&B2 mette il testo di B2 su una seconda riga sotto il testo di A2. La tabella mostra le formule in inglese, =A2&CHAR(10)&B2, ma puoi scriverle anche in italiano, con il punto e virgola.
| A | B | C | |
|---|---|---|---|
| 1 | Street | City | Address label |
| 2 | 12 Oak Road | Leeds | 12 Oak Road Leeds |
| 3 | 4 Mill Lane | York | 4 Mill Lane York |
=A2&CODICE.CARATT(10)&B2Fai clic su C2: la formula unisce la via, un a capo e la città. La piccola tabella mostra il risultato su una riga. Anche in Excel la cella mostra una riga sola finché non attivi Home > Testo a capo; allora la riga si allarga e la città compare sotto la via. Un a capo scritto con Alt+Invio attiva Testo a capo da solo. Un a capo prodotto da una formula no, ed è il motivo abituale per cui "CODICE.CARATT(10) non funziona".
Premere solo Invio chiude la cella e scende. In Google Sheets, si va a capo in una cella con Ctrl+Invio o Alt+Invio (Cmd+Invio su Mac), e CHAR(10) funziona allo stesso modo.
L'a capo è un carattere
CODICE.CARATT(10) è il carattere di avanzamento riga, codice 10. Conta come un carattere, e TROVA e SOSTITUISCI lo cercano come qualsiasi altro:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Text | Length | Break at | First line |
| 2 | Ana Silva | 9 | 4 | Ana |
=LUNGHEZZA(A2)Ana, l'a capo e Silva fanno 9 caratteri, e l'a capo è il 4°. D2 prende tutto ciò che c'è prima. Qui A2 è costruita con una formula solo per farti vedere dov'è l'a capo; una cella in cui qualcuno ha premuto Alt+Invio si comporta allo stesso modo.
| A | B | C | |
|---|---|---|---|
| 1 | Name | Title | Badge |
| 2 | Ana Silva | Manager |
Tocca a te: In C2, metti in una sola cella il nome di A2 e la qualifica di B2, con la qualifica su una seconda riga.
Unire un intervallo con gli a capo
Per impilare un intero elenco in una cella, usa CODICE.CARATT(10) come delimitatore di TESTO.UNISCI:
| A | B | C | |
|---|---|---|---|
| 1 | Item | List | |
| 2 | Milk | Milk Bread Eggs | |
| 3 | Bread | ||
| 4 | Eggs |
=TESTO.UNISCI(CODICE.CARATT(10);VERO;A2:A4)In Excel 2016 e precedenti, che non hanno TESTO.UNISCI, concatena le celle con &: =A2&CODICE.CARATT(10)&A3&CODICE.CARATT(10)&A4.
Eliminare gli a capo
I dati copiati da email, moduli web o altri programmi si portano dietro spesso degli a capo. Sostituisci ogni a capo con uno spazio o una virgola usando SOSTITUISCI:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Imported | Spaces | Commas | CLEAN |
| 2 | Milk Bread Eggs | Milk Bread Eggs | Milk, Bread, Eggs | MilkBreadEggs |
=SOSTITUISCI(A2;CODICE.CARATT(10);" ")Anche LIBERA, in D2, cancella gli a capo, ma non mette nulla al loro posto, quindi le parole restano attaccate come MilkBreadEggs. Il testo dei file di Windows può avere un ritorno a capo, CODICE.CARATT(13), prima di ogni avanzamento riga; elimina entrambi con =SOSTITUISCI(SOSTITUISCI(A2;CODICE.CARATT(13);"");CODICE.CARATT(10);" ").
| A | B | |
|---|---|---|
| 1 | Imported | One line |
| 2 | Ana Ben Chen |
Tocca a te: I nomi in A2 sono su righe separate. In B2, restituiscili su una riga sola con una virgola e uno spazio al posto di ogni a capo.
Dividere una cella ai suoi a capo
=DIVIDI.TESTO(A2;CODICE.CARATT(10)) mette ogni riga nella propria colonna (Microsoft 365 ed Excel 2024):
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Address | |||
| 2 | 12 Oak Road Leeds LS1 4AB | 12 Oak Road | Leeds | LS1 4AB |
=DIVIDI.TESTO(A2;CODICE.CARATT(10))Nelle versioni precedenti di Excel per Windows lo fa Dati > Testo in colonne: scegli Delimitato, spunta Altro, fai clic nella sua casella e premi Ctrl+J. La casella sembra vuota, ma ora contiene l'a capo.
Eliminare gli a capo con Trova e sostituisci
Per ripulire molte celle in una volta senza formula, in Excel per Windows:
- Seleziona le celle e premi Ctrl+H.
- Fai clic in Trova e premi Ctrl+J. Non compare nulla di visibile; la casella ora contiene l'a capo.
- In Sostituisci con, scrivi uno spazio o una virgola.
- Fai clic su Sostituisci tutto.
Su Mac, usa la formula con SOSTITUISCI vista sopra, poi incolla i risultati sopra l'originale con Incolla speciale > Valori.
Se poi le celle sembrano ancora alte, seleziona le righe e fai doppio clic sul bordo di una riga per adattare di nuovo l'altezza, e disattiva Testo a capo se non ti serve.
Domande frequenti
Come si va a capo in una cella di Excel?
Mentre scrivi nella cella, premi Alt+Invio su Windows o Ctrl+Opzione+A capo su Mac (Microsoft 365 per Mac accetta anche Opzione+A capo). Invio da solo passa alla cella successiva.
Come aggiungo un a capo in una formula di Excel?
Unisci CODICE.CARATT(10) dove deve andare l'interruzione: =A2&CODICE.CARATT(10)&B2, oppure =TESTO.UNISCI(CODICE.CARATT(10);VERO;A2:A4) per un intervallo. Attiva Home > Testo a capo per la cella, altrimenti le righe appaiono attaccate.
Perché CODICE.CARATT(10) non va a capo?
La cella non ha Testo a capo attivo. Selezionala e fai clic su Home > Testo a capo; l'altezza della riga cresce per mostrare tutte le righe.
Come elimino gli a capo in Excel?
=SOSTITUISCI(A2;CODICE.CARATT(10);" ") sostituisce ogni a capo con uno spazio. Senza formula, in Excel per Windows: apri Trova e sostituisci (Ctrl+H), premi Ctrl+J in Trova, scrivi uno spazio in Sostituisci con e fai clic su Sostituisci tutto.
