Plataformas de impulso

Lección 6 de 20 del curso Juego de Godot: Circuito Neón de Coddy.

Las flechas luminosas de la pista son plataformas de aceleración. Pasa por encima de una y el coche recibe un impulso de velocidad que supera max_speed.

Guarda cuánto dura el impulso en boost_time. Las plataformas están en el grupo boost_pads, así que el coche puede encontrarlas todas:

for pad in get_tree().get_nodes_in_group("boost_pads"):
	if position.distance_to(pad.position) < 22.0:
		boost_time = maxf(boost_time, 0.4)

Mientras dure el impulso, haz la cuenta regresiva, aumenta la velocidad máxima en un 30 por ciento e impulsa el coche hacia delante:

if boost_time > 0.0:
	boost_time -= delta
	top = max_speed * 1.3
	velocity += forward * accel * delta

Muéstralo: el escape brilla y una llama arde detrás del coche.

Desafío

Fácil

Añade var boost_time := 0.0 debajo de velocity.
Después de var top := max_speed, añade el impulso y después el bucle de plataformas.
Establece $Exhaust.emitting = throttle > 0.0 or boost_time > 0.0 y $Flame.visible = boost_time > 0.0.

Pruébalo tú mismo

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6
@export var grip := 7.0

var velocity := Vector2.ZERO

@onready var track: Node2D = $"../Track"


func _physics_process(delta: float) -> void:
	var throttle := Input.get_axis("move_down", "move_up")
	var steer := Input.get_axis("move_left", "move_right")

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)
	var top := max_speed
	if not track.is_on_road(position):
		top = max_speed * 0.45
		velocity *= 1.0 - 2.5 * delta

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)

	var side := forward.orthogonal()
	velocity -= side * velocity.dot(side) * minf(1.0, grip * delta)
	velocity *= 1.0 - drag * delta
	if velocity.length() > top:
		velocity = velocity.move_toward(velocity.limit_length(top), accel * 2.0 * delta)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0