Mantenha-se na pista

Lição 5 de 20 do curso Jogo na Godot: Circuito Neon da Coddy.

A pista é desenhada por track.gd, que também responde a perguntas sobre ela. track.is_on_road(position) é verdadeiro enquanto um ponto está na pista. Fora dela, o carro deve avançar lentamente pela grama.

Obtenha o nó da pista uma vez, quando o carro estiver pronto:

@onready var track: Node2D = $"../Track"

Em seguida, mantenha uma velocidade máxima para este quadro. Fora da pista, ela é 45 por cento de max_speed, e a grama também desacelera o carro:

var top := max_speed
if not track.is_on_road(position):
	top = max_speed * 0.45
	velocity *= 1.0 - 2.5 * delta

Por fim, substitua limit_length. Reduzir a velocidade de uma vez faria o carro parar bruscamente na borda da pista, então reduza-a gradualmente até a velocidade máxima:

if velocity.length() > top:
	velocity = velocity.move_toward(velocity.limit_length(top), accel * 2.0 * delta)

Desafio

Fácil

Adicione a linha @onready para a pista.
Depois de speed, calcule top e a desaceleração fora da pista.
Substitua a linha limit_length pelas duas linhas acima.
Pressione “Jogar” e dirija sobre a grama.

Experimente você mesmo

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6
@export var grip := 7.0

var velocity := Vector2.ZERO


func _physics_process(delta: float) -> void:
	var throttle := Input.get_axis("move_down", "move_up")
	var steer := Input.get_axis("move_left", "move_right")

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)

	var side := forward.orthogonal()
	velocity -= side * velocity.dot(side) * minf(1.0, grip * delta)
	velocity *= 1.0 - drag * delta
	velocity = velocity.limit_length(max_speed)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0