סוף המשחק בבריקאאוט

חלק מהיחידה פרויקטים במסלול ה-Godot של Coddy. שיעור 9 מתוך 36.

שלוש החטאות אמורות לסיים את המשחק. כשמספר החיים מגיע לאפס, הצג את Game Over והשהה באמצעות get_tree().paused = true. המחבט והכדור הם Pausable, ולכן הם קופאים. Main הוא Always, ולכן הוא ממשיך לפעול ויכול לקרוא את Enter:

func _process(delta):
	if get_tree().paused and Input.is_action_just_pressed("action"):
		get_tree().paused = false
		get_tree().reload_current_scene()

בטל את ההשהיה לפני הטעינה מחדש. ההשהיה שייכת לעץ, לא לסצנה, ולכן סצנה שנטענה מחדש תתחיל קפואה.

אתגר

קשה

סיימו את המשחק כשנשארים בלי החיים האחרונים.

ב־_on_missed, כש־lives הוא 0, הציגו את Game Over ב־$HUD/Message והשהו את המשחק.
הוסיפו את _process: כשהמשחק מושהה ו־action נלחץ זה עתה, בטלו את ההשהיה ואז טענו מחדש את הסצנה.

לחצו על "שחק" והחטיאו שלושה כדורים: ההודעה Game Over תופיע והכדור ייעצר. לחצו על Enter כדי להתחיל שוב. לאחר מכן לחצו על "בדיקה".

נסו בעצמכם

extends Node2D

const BRICK = preload("res://brick.tscn")
const COLORS = [Color(1, 0.42, 0.42), Color(1, 0.78, 0.34), Color(0.49, 0.95, 0.75), Color(0.369, 0.635, 1), Color(0.75, 0.82, 0.95)]

var score = 0
var lives = 3

func _ready():
	for row in 5:
		for column in 8:
			var brick = BRICK.instantiate()
			brick.position = Vector2(68 + column * 72, 60 + row * 26)
			brick.color = COLORS[row]
			add_child(brick)
	$Ball.brick_broken.connect(_on_brick_broken)
	$HUD/Score.text = "Score: 0"
	$Ball.missed.connect(_on_missed)
	$HUD/Lives.text = "Lives: 3"

func _on_brick_broken():
	score += 10
	$HUD/Score.text = "Score: %d" % score

func _on_missed():
	lives -= 1
	$HUD/Lives.text = "Lives: %d" % lives