פינוי הקיר

חלק מהיחידה פרויקטים במסלול ה-Godot של Coddy. שיעור 9 מתוך 33.

השלב האחרון הוא דרך לנצח: לשבור את כל הלבנים.

ספרו את הלבנים שנותרו. התחילו ב־40 והפחיתו אחת בכל פעם שמתקבל brick_broken. כשהמספר מגיע לאפס, הקיר פונה:

bricks_left -= 1
if bricks_left == 0:
	$HUD/Message.text = "You Win!"
	get_tree().paused = true

הפחיתו אחת לפני שבודקים אם המספר הוא אפס. אם תבדקו קודם, הבדיקה תראה 1 בלבנה האחרונה ולעולם לא תראה 0.

גם כאן, מקש Enter במסך Game Over מתחיל משחק חדש. משחק ה־Breakout שלכם הושלם.

אתגר

בינוני

ב־main.gd:

הוסף var bricks_left = 40.
כל לבנה שנשברת מפחיתה אחת מהמספר.
כשלא נשארות לבנים, הצג את You Win! בתוך $HUD/Message והשהה את המשחק.

נסו בעצמכם

extends Node2D

const BRICK = preload("res://brick.tscn")
const COLORS = [Color(1, 0.42, 0.42), Color(1, 0.78, 0.34), Color(0.49, 0.95, 0.75), Color(0.369, 0.635, 1), Color(0.75, 0.82, 0.95)]

var score = 0
var lives = 3

func _ready():
	for row in 5:
		for column in 8:
			var brick = BRICK.instantiate()
			brick.position = Vector2(68 + column * 72, 60 + row * 26)
			brick.color = COLORS[row]
			add_child(brick)
	$Ball.brick_broken.connect(_on_brick_broken)
	$HUD/Score.text = "Score: 0"
	$Ball.missed.connect(_on_missed)
	$HUD/Lives.text = "Lives: 3"

func _process(delta):
	if get_tree().paused and Input.is_action_just_pressed("action"):
		get_tree().paused = false
		get_tree().reload_current_scene()

func _on_brick_broken():
	score += 10
	$HUD/Score.text = "Score: %d" % score

func _on_missed():
	lives -= 1
	$HUD/Lives.text = "Lives: %d" % lives
	if lives == 0:
		$HUD/Message.text = "Game Over"
		get_tree().paused = true