Contar caracteres
Parte de la sección Funciones, pila y cadenas del Journey de Assembly de Coddy. Lección 22 de 33.
Para encontrar un carácter, compáralo con cada byte: cmp cl, 'e', después je o jne. Mantén el contador en un registro y súmale 1 cada vez que haya una coincidencia. Este bucle cuenta la letra e:
xor eax, eax ; el contador
.next:
movzx ecx, byte [rdi]
test ecx, ecx
jz .done
cmp cl, 'e'
jne .skip
inc rax
.skip:
inc rdi
jmp .next
.done:Para contar varios caracteres, compara con cada uno y envía cada coincidencia a la misma línea de conteo:
cmp cl, 'a'
je .count
cmp cl, 'b'
je .count
jmp .skip
.count:
inc rax
.skip:Algunos caracteres tienen códigos consecutivos: los dígitos '0' a '9' corresponden a los valores del 48 al 57, y 'a' a 'z', del 97 al 122. Dos comparaciones comprueban un rango completo:
cmp cl, '0'
jb .skip ; menor que '0'
cmp cl, '9'
ja .skip ; mayor que '9'
inc rax ; un dígitoUn byte leído con movzx va de 0 a 255, nunca es negativo, así que los rangos usan los saltos sin signo jb y ja de la sección 2.
Las letras mayúsculas y minúsculas son bytes diferentes: 'A' es 65 y 'a' es 97. Una comparación con 'a' no coincide con 'A'.
Desafío
Fácilsolve recibe la dirección de un texto en rdi, terminado en un byte cero. Devuelve en rax cuántos de sus bytes son las vocales minúsculas a, e, i, o o u. Las letras mayúsculas no cuentan.
Ejemplo: para la entrada hello world, el programa imprime 3.
Escribe tu código en solution.asm. El archivo bloqueado main.asm lee una línea de texto, llama a solve e imprime el número en rax.
Pruébalo tú mismo
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 257
text_buffer resb 256
output_buffer resb 32
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jg .trim
xor eax, eax
.trim:
test rax, rax
jz .ended
movzx edx, byte [input_buffer + rax - 1]
cmp dl, 10
je .drop
cmp dl, 13
jne .ended
.drop:
dec rax
jmp .trim
.ended:
mov byte [input_buffer + rax], 0
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
lea rdi, [input_buffer]
lea rsi, [text_buffer]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitEsta lección incluye un breve cuestionario. Empieza la lección para responderlo y registrar tu progreso.
Todas las lecciones de Funciones, pila y cadenas
1La pila
PUSH y POPÚltimo en entrar, primero en salirGuardar un registroLeer con [rsp]Repaso: historial de deshacer4Marcos de pila y recursión
Variables localesMarcos con RBPRecursiónDos llamadas recursivasRepaso: suma de dígitosPractica por tu cuenta: Playground de Assembly