PUSH y POP
Parte de la sección Funciones, pila y cadenas del Journey de Assembly de Coddy. Lección 1 de 33.
La pila es una región de memoria que tu programa usa para guardar valores durante un breve período. El registro rsp (el puntero de pila) contiene la dirección del valor que está en la cima de la pila. Cuando tu programa se inicia, rsp ya apunta a la pila.
push coloca un valor de 8 bytes en la parte superior. push rdi primero resta 8 a rsp y después almacena rdi en la nueva dirección de rsp. La pila crece hacia abajo: cada inserción mueve rsp a una dirección más baja. Las direcciones reales son números largos, así que los ejemplos usan números pequeños.
; rsp = 1000
push rdi ; rsp = 992, rdi se almacena en 992
push rsi ; rsp = 984, rsi se almacena en 984pop quita el valor superior. pop rax copia los 8 bytes de la dirección indicada en rsp a rax y después suma 8 a rsp.
; rsp = 984
pop rax ; rax = el valor de 984, rsp = 992
pop rbx ; rbx = el valor de 992, rsp = 1000Push y pop pueden intercambiar dos registros sin usar un tercero. El primer pop devuelve el último valor insertado:
push rdi ; guarda rdi
push rsi ; guarda rsi encima
pop rdi ; rdi = el valor anterior de rsi
pop rsi ; rsi = el valor anterior de rdiEn esta sección, los desafíos llaman a tu código de la misma manera que un programa en C llama a una función. El archivo bloqueado main.asm coloca las entradas en rdi, rsi, rdx y rcx, en ese orden, llama a tu solve e imprime el número que dejas en rax. Cada tarea indica qué entradas utiliza. El capítulo 3 explica por qué se usan estos registros.
Desafío
Fácilsolve recibe dos números: el primero en rdi y el segundo en rsi. Intercambia los dos registros con dos instrucciones push y dos instrucciones pop, luego devuelve rdi - rsi en rax.
Por ejemplo: para la entrada 3 10, el programa imprime 7.
Escribe tu código en solution.asm. El archivo bloqueado main.asm lee la entrada, llama a solve e imprime el número en rax.
Pruébalo tú mismo
bits 64
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscallTodas las lecciones de Funciones, pila y cadenas
1La pila
PUSH y POPÚltimo en entrar, primero en salirGuardar un registroLeer con [rsp]Repaso: historial de deshacer4Marcos de pila y recursión
Variables localesMarcos con RBPRecursiónDos llamadas recursivasRepaso: suma de dígitosPractica por tu cuenta: Playground de Assembly