Recursión
Parte de la sección Funciones, pila y cadenas del Journey de Assembly de Coddy. Lección 18 de 33.
Una función recursiva se llama a sí misma con una versión más pequeña de su problema. El factorial de n es n multiplicado por el factorial de n - 1: 4! = 4 * 3!. La cadena se detiene en 1! = 1, y 0! = 1 también.
Toda función recursiva necesita un caso base: una entrada a la que responde sin llamarse a sí misma. Sin uno, las llamadas nunca terminan. Cada llamada añade una dirección de retorno y la pila se queda sin espacio hasta que el programa falla.
factorial recibe n en rdi y devuelve n! en rax:
factorial:
cmp rdi, 1
jg .recurse
mov eax, 1
ret
.recurse:
push rdi
dec rdi
call factorial
pop rdi
imul rax, rdi
retLa llamada interna cambia rdi, así que cada llamada apila su propio n antes de llamar y lo desapila después. Cada llamada tiene su propia dirección de retorno y su propio n guardado en la pila.
Para factorial(3): guarda 3 y llama a factorial(2), que guarda 2 y llama a factorial(1), que devuelve 1. Después, los valores devueltos se procesan en orden inverso: 2 * 1 = 2 y, después, 3 * 2 = 6.
Desafío
FácilEscribe una función recursiva factorial: n en rdi (de 0 a 20), n! en rax, con 0! y 1! iguales a 1. solve recibe n en rdi, llama a factorial y devuelve su resultado en rax.
Por ejemplo: para la entrada 5, el programa imprime 120.
Escribe tu código en solution.asm. El main.asm bloqueado lee la entrada, llama a solve e imprime el número en rax, o el nombre de un registro preservado por el llamador que solve haya cambiado.
Pruébalo tú mismo
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitTodas las lecciones de Funciones, pila y cadenas
1La pila
PUSH y POPÚltimo en entrar, primero en salirGuardar un registroLeer con [rsp]Repaso: historial de deshacer4Marcos de pila y recursión
Variables localesMarcos con RBPRecursiónDos llamadas recursivasRepaso: suma de dígitosPractica por tu cuenta: Playground de Assembly