Patrón Composite

El patrón Composite construye árboles en los que un objeto individual y un grupo de objetos tienen los mismos métodos, para que el código pueda tratar a todo un grupo como un solo elemento. Una bolsa contiene elementos, una bolsa puede contener otras bolsas y puedes preguntarles a todas por su peso de la misma manera.

Ambos tipos comparten un padre abstracto:

# entry.gd
@abstract
class_name Entry
extends RefCounted

var entry_name: String

@abstract func get_weight() -> int
@abstract func display(indent: String) -> void

La hoja es un elemento individual:

# item.gd
class_name Item
extends Entry

var weight: int

func _init(n: String, w: int) -> void:
	entry_name = n
	weight = w

func get_weight() -> int:
	return weight

func display(indent: String) -> void:
	print(indent, entry_name, " (", weight, ")")

El compuesto contiene otras entradas y responde preguntándole a cada una de ellas. Una bolsa pesa 1 por sí sola:

# bag.gd
class_name Bag
extends Entry

var contents: Array[Entry] = []

func _init(n: String) -> void:
	entry_name = n

func add(entry: Entry) -> void:
	contents.append(entry)

func get_weight() -> int:
	var total := 1
	for entry in contents:
		total += entry.get_weight()
	return total

func display(indent: String) -> void:
	print(indent, entry_name, " [", get_weight(), "]")
	for entry in contents:
		entry.display(indent + "  ")

# main.gd
var pouch := Bag.new("Pouch")
pouch.add(Item.new("Gem", 2))
var backpack := Bag.new("Backpack")
backpack.add(Item.new("Sword", 8))
backpack.add(pouch)
backpack.display("")

Backpack [12]
  Sword (8)
  Pouch [3]
    Gem (2)

Bag.get_weight() nunca comprueba si una entrada es un elemento o una bolsa: llama al mismo método en cada una, y una bolsa que está dentro responde preguntando a su propio contenido. Esa recursión recorre todo el árbol, por muy profundo que sea.

Los enlaces van en una sola dirección, de una carpeta a su contenido. Si cada elemento también almacenara la carpeta en la que está, cada carpeta y sus elementos se apuntarían mutuamente, formando un ciclo de referencias que nunca se libera. Cuando un elemento necesite saber dónde está, pásale esa información como argumento, de la misma manera que display() pasa la sangría.