대소문자 바꾸기
Coddy Assembly 여정의 함수, 스택, 문자열 섹션에 포함된 레슨. 33개 중 23번째.
소문자 'a'부터 'z'까지는 97부터 122까지이고, 대문자 'A'부터 'Z'까지는 65부터 90까지입니다. 각 대문자는 해당 소문자보다 32 작습니다. 즉, 'a' 97은 'A' 65가 됩니다.
바이트를 대문자로 바꾸려면 'a'부터 'z'까지의 범위에 있는지 확인한 다음 32를 빼세요. 그 외의 바이트(대문자, 숫자, 공백)는 그대로 유지됩니다.
cmp cl, 'a'
jb .keep
cmp cl, 'z'
ja .keep
sub cl, 32 ; 'h'가 'H'로 바뀜
.keep:mov [rsi], cl은 rcx의 최하위 바이트 하나를 rsi에 있는 주소에 씁니다. 크기는 레지스터에 따라 결정됩니다. cl은 1바이트이므로 1바이트가 기록됩니다.
이 단원부터 일부 과제에서는 새로운 텍스트를 만듭니다. 이때 solve는 rsi에 있는 비어 있는 256바이트 버퍼의 주소도 받습니다. 그곳에 텍스트를 쓰고 길이를 rax로 반환하세요. 잠긴 main.asm은 버퍼에서 그 길이만큼의 바이트를 출력합니다.
하나의 인덱스로 텍스트와 버퍼를 함께 순회할 수 있습니다. 이 루프는 텍스트를 변경 없이 복사하고, 마지막에 rax에는 텍스트의 길이가 저장됩니다.
xor eax, eax
.next:
movzx ecx, byte [rdi + rax]
test ecx, ecx
jz .done
mov [rsi + rax], cl
inc rax
jmp .next
.done:챌린지
쉬움solve는 rdi에 0 바이트로 끝나는 텍스트의 주소를, rsi에 비어 있는 버퍼의 주소를 전달받습니다. 텍스트를 버퍼에 복사하면서 a부터 z까지의 모든 소문자는 대문자로 바꾸고, 나머지 바이트는 모두 그대로 유지하세요. 텍스트의 길이를 rax에 반환하세요.
예: 입력이 hello이면 프로그램은 HELLO를 출력합니다.
코드는 solution.asm에 작성하세요. 잠긴 main.asm은 텍스트 한 줄을 읽고, solve를 호출한 다음 버퍼의 첫 rax바이트를 출력합니다.
직접 해보기
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 257
text_buffer resb 257
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jg .trim
xor eax, eax
.trim:
test rax, rax
jz .ended
movzx edx, byte [input_buffer + rax - 1]
cmp dl, 10
je .drop
cmp dl, 13
jne .ended
.drop:
dec rax
jmp .trim
.ended:
mov byte [input_buffer + rax], 0
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
lea rdi, [input_buffer]
lea rsi, [text_buffer]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
cmp rax, 256
jbe .length_ok
mov eax, 256
.length_ok:
mov byte [text_buffer + rax], 10
lea rdx, [rax + 1]
lea rsi, [text_buffer]
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exit함수, 스택, 문자열의 모든 레슨
직접 연습해 보세요: Assembly 플레이그라운드