반환 값
Coddy Assembly 여정의 함수, 스택, 문자열 섹션에 포함된 레슨. 33개 중 12번째.
함수는 결과를 rax에 돌려줍니다. 호출자는 call 직후, 다른 어떤 것도 rax를 변경하기 전에 rax의 값을 읽습니다.
직접 함수를 작성할 때도 같은 규칙을 따릅니다. 레이블을 지정하고, rdi, rsi, rdx에서 인수를 읽어 결과를 rax에 남기는 코드를 작성한 다음 ret을 작성합니다.
; sum3(rdi, rsi, rdx): rdi + rsi + rdx를 반환합니다
sum3:
mov rax, rdi
add rax, rsi
add rax, rdx
retsolve에 전달하려는 인수와 같은 인수를 받으면, 해당 인수는 이미 올바른 레지스터에 있으므로 바로 호출하고 결과를 사용할 수 있습니다.
solve:
call sum3 ; rax = 세 입력값의 합
imul rax, rax, 2
ret.done처럼 점으로 시작하는 레이블은 점이 없는 바로 앞 레이블에 속합니다. 따라서 두 함수가 각각 자체 .done을 가질 수 있습니다. 각 함수의 이름은 sum3처럼 점이 없는 레이블로 지정하세요.
rax는 결과 레지스터이므로, 유용한 값을 반환하지 않는 함수 호출이라도 호출할 때마다 값이 바뀝니다. call을 실행한 뒤에도 rax의 값이 유지될 거라고 기대하지 마세요. 먼저 push로 저장하세요.
챌린지
쉬움clamp 함수를 작성하세요. 값은 rdi에, 하한은 rsi에, 상한은 rdx에 전달됩니다(모두 -1000에서 1000 사이이며, 하한이 상한보다 큰 경우는 없습니다). 값이 범위를 벗어나면 하한까지 올리거나 상한까지 낮춘 뒤, 그 값을 rax에 반환합니다. solve는 rdi, rsi, rdx에 동일한 세 숫자를 받습니다. clamp를 호출하고 그 결과에 2를 곱한 값을 rax에 반환하세요.
예: 입력이 5 1 10이면 프로그램은 10을 출력합니다.
solution.asm에 코드를 작성하세요. 잠겨 있는 main.asm은 입력을 읽고 solve를 호출한 다음 rax에 있는 숫자 또는 solve가 변경한 호출자 저장 레지스터의 이름을 출력합니다.
직접 해보기
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exit함수, 스택, 문자열의 모든 레슨
직접 연습해 보세요: Assembly 플레이그라운드