Menu
CoddyTech

PUSH와 POP

Coddy Assembly 여정의 함수, 스택, 문자열 섹션에 포함된 레슨. 33개 중 1번째.

스택은 프로그램이 값을 잠시 보관하는 데 사용하는 메모리 영역입니다. 레지스터 rsp(스택 포인터)는 스택 맨 위에 있는 값의 주소를 저장합니다. 프로그램이 시작되면 rsp는 이미 스택을 가리킵니다.

push는 8바이트 값을 맨 위에 넣습니다. push rdi는 먼저 rsp에서 8을 뺀 다음, 새로운 rsp 주소에 rdi를 저장합니다. 스택은 아래쪽으로 자랍니다. 즉, 푸시할 때마다 rsp가 더 낮은 주소로 이동합니다. 실제 주소는 긴 숫자이므로 예시에서는 작은 숫자를 사용합니다.

; rsp = 1000
push rdi        ; rsp = 992, rdi는 992에 저장됨
push rsi        ; rsp = 984, rsi는 984에 저장됨

pop은 맨 위의 값을 꺼냅니다. pop rax는 rsp에 있는 주소의 8바이트를 rax로 복사한 다음, rsp에 8을 더합니다.

; rsp = 984
pop rax         ; rax = 984에서 가져온 값, rsp = 992
pop rbx         ; rbx = 992에서 가져온 값, rsp = 1000

Push와 pop을 사용하면 세 번째 레지스터 없이 두 레지스터의 값을 바꿀 수 있습니다. 첫 번째 pop은 마지막에 push한 값을 반환합니다.

push rdi        ; rdi 저장
push rsi        ; rsi를 맨 위에 저장
pop rdi         ; rdi = 이전 rsi
pop rsi         ; rsi = 이전 rdi

이 섹션에서는 챌린지에서 C 프로그램이 함수를 호출하는 방식으로 여러분의 코드를 호출합니다. 잠겨 있는 main.asm은 입력값을 순서대로 rdi, rsi, rdx, rcx에 넣고, 여러분의 solve를 호출한 다음 rax에 남겨 둔 숫자를 출력합니다. 각 과제에는 사용하는 입력값이 나와 있습니다. 3장에서 왜 이 레지스터들을 사용하는지 설명합니다.

challenge icon

챌린지

쉬움

solve는 두 개의 숫자를 받습니다. 첫 번째 숫자는 rdi에, 두 번째 숫자는 rsi에 있습니다. push 명령어 두 개와 pop 명령어 두 개를 사용해 두 레지스터의 값을 바꾼 다음, rdi - rsi를 rax에 반환하세요.

예를 들어 입력이 3 10이면 프로그램은 7을 출력합니다.

solution.asm에 코드를 작성하세요. 잠긴 main.asm은 입력을 읽고, solve를 호출한 다음 rax의 숫자를 출력합니다.

직접 해보기

bits 64
section .bss
    input_buffer resb 256
    output_buffer resb 32
    values resq 4
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jle .loaded
    mov rsi, input_buffer
    lea rdi, [input_buffer + rax]
    xor ecx, ecx
.scan:
    cmp rsi, rdi
    jae .loaded
    cmp ecx, 4
    jae .loaded
    movzx eax, byte [rsi]
    cmp al, 32
    jbe .space
    mov r10, 1
    cmp al, '-'
    jne .number
    mov r10, -1
    inc rsi
.number:
    xor eax, eax
.digit:
    cmp rsi, rdi
    jae .store
    movzx edx, byte [rsi]
    cmp dl, '0'
    jb .store
    cmp dl, '9'
    ja .store
    imul rax, rax, 10
    sub edx, '0'
    add rax, rdx
    inc rsi
    jmp .digit
.store:
    imul rax, r10
    mov [values + rcx * 8], rax
    inc ecx
.space:
    inc rsi
    jmp .scan
.loaded:
    mov rdi, [values]
    mov rsi, [values + 8]
    mov rdx, [values + 16]
    mov rcx, [values + 24]
    xor eax, eax
    call solve
    lea rsi, [output_buffer + 31]
    mov byte [rsi], 10
    mov ecx, 1
    xor r8d, r8d
    test rax, rax
    jns .positive
    mov r8d, 1
    neg rax
.positive:
    mov r9d, 10
.convert:
    xor edx, edx
    div r9
    add dl, '0'
    dec rsi
    mov [rsi], dl
    inc ecx
    test rax, rax
    jnz .convert
    test r8d, r8d
    jz .write
    dec rsi
    mov byte [rsi], '-'
    inc ecx
.write:
    mov edx, ecx
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall

함수, 스택, 문자열의 모든 레슨

직접 연습해 보세요: Assembly 플레이그라운드