Linia mety

Lekcja 12 z 20 w kursie Gra w Godot: Neonowy tor w Coddy.

Trzy okrążenia i wyścig się kończy. state określa, w jakim stanie jest wyścig:

const LAPS := 3
var state := "racing"

Gdy liczba okrążeń osiągnie LAPS, wyścig się kończy: stan zmienia się na „done”, samochód przestaje reagować na klawisze i wyświetla się czas. Po zakończeniu wyścig nie robi już nic więcej:

func finish_race() -> void:
	state = "done"
	car.active = false
	$HUD/Message.text = "Finished!\nTime %s" % clock(race_time)

W pliku car.gd zmienna active decyduje o tym, czy odczytywane są klawisze. Ustaw początkowo wartości przepustnicy i skrętu na 0 i odczytuj klawisze tylko wtedy, gdy active ma wartość true:

var throttle := 0.0
var steer := 0.0
if active:
	throttle = Input.get_axis("move_down", "move_up")
	steer = Input.get_axis("move_left", "move_right")

Wyzwanie

Średni

W race.gd dodaj LAPS, state i var race_time := 0.0, zwiększając wartość co klatkę, tak jak czas okrążenia.
Rozpocznij _physics_process od sprawdzenia: jeśli stan to „done”, zakończ działanie.
W finish_lap wywołaj finish_race(), gdy laps >= LAPS.
Wyświetlaj w HUD "Lap %d/%d" % [mini(laps + 1, LAPS), LAPS].
W car.gd dodaj var active := true i odczytuj klawisze tylko wtedy, gdy aktywność jest włączona (dotyczy to również przycisku dopalacza).

Spróbuj swoich sił

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6
@export var grip := 7.0

var velocity := Vector2.ZERO
var boost_time := 0.0
var boost_charge := 0.0

@onready var track: Node2D = $"../Track"


func _physics_process(delta: float) -> void:
	var throttle := Input.get_axis("move_down", "move_up")
	var steer := Input.get_axis("move_left", "move_right")
	if Input.is_action_just_pressed("action") and boost_charge >= 1.0:
		boost_charge = 0.0
		boost_time = 1.0
	boost_charge = minf(1.0, boost_charge + delta / 10.0)
	$"../HUD/Boost".scale.x = boost_charge

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)
	var top := max_speed
	var grip_now := grip
	if boost_time > 0.0:
		boost_time -= delta
		top = max_speed * 1.3
		velocity += forward * accel * delta
	for pad in get_tree().get_nodes_in_group("boost_pads"):
		if position.distance_to(pad.position) < 22.0:
			boost_time = maxf(boost_time, 0.4)
	for oil in get_tree().get_nodes_in_group("oil"):
		if position.distance_to(oil.position) < 20.0:
			grip_now = grip * 0.12
	if not track.is_on_road(position):
		top = max_speed * 0.45
		velocity *= 1.0 - 2.5 * delta

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)

	var side := forward.orthogonal()
	velocity -= side * velocity.dot(side) * minf(1.0, grip_now * delta)
	velocity *= 1.0 - drag * delta
	if velocity.length() > top:
		velocity = velocity.move_toward(velocity.limit_length(top), accel * 2.0 * delta)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0 or boost_time > 0.0
	$Flame.visible = boost_time > 0.0