Sprawdzanie dostępności

Część sekcji Logika i przepływ programu ścieżki GDScript w Coddy. Lekcja 74 z 78.

Wyzwanie

Łatwy

Dodaj polecenie check. Zachowaj wszystko, co napisałeś w poprzednich krokach.

Napisz funkcję check_availability(inventory, item) nad _ready(). Niczego nie wypisuje i zwraca wartość typu int:

stan magazynowy elementu, jeśli element znajduje się w inventory
-1, jeśli brakuje elementu. Stan magazynowy nigdy nie jest ujemny, więc -1 może oznaczać tylko "not found".

W pętli wiersz taki jak check Apple:

wypisuje Error: Use check ITEM, jeśli nie ma dokładnie 2 części
w przeciwnym razie wywołuje check_availability() i wypisuje Item not found dla wartości -1, albo nazwę elementu, : , stan magazynowy i in stock

Dla poleceń add Apple 0.5 100, add Banana 0.2 50, update Apple -20, update Banana 30, check Apple, check Banana, check Orange i exit wynik jest następujący:

Inventory Management System
Item 'Apple' added successfully.
Item 'Banana' added successfully.
Stock for 'Apple' updated successfully.
Stock for 'Banana' updated successfully.
Apple: 80 in stock
Banana: 80 in stock
Item not found
Goodbye!

Spróbuj swoich sił

extends Node

func add_item(inventory: Dictionary, item: String, price: float, stock: int) -> void:
	if inventory.has(item):
		print("Error: Item '%s' already exists." % item)
		return
	inventory[item] = {"price": price, "stock": stock}
	print("Item '%s' added successfully." % item)

func update_stock(inventory: Dictionary, item: String, quantity: int) -> void:
	if not inventory.has(item):
		print("Error: Item '%s' not found." % item)
		return
	var new_stock: int = inventory[item]["stock"] + quantity
	if new_stock < 0:
		print("Error: Insufficient stock for '%s'." % item)
		return
	inventory[item]["stock"] = new_stock
	print("Stock for '%s' updated successfully." % item)

func _ready():
	# Magazyn: nazwa przedmiotu -> {"price": float, "stock": int}
	var inventory := {}
	print("Inventory Management System")

	while true:
		var line := OS.read_string_from_stdin()
		var parts := line.split(" ")
		var command := parts[0]

		if command == "exit":
			print("Goodbye!")
			break
		elif command == "show":
			print(inventory)
		elif command == "add":
			if parts.size() != 4:
				print("Error: Use add ITEM PRICE STOCK")
			elif not parts[2].is_valid_float() or not parts[3].is_valid_int():
				print("Error: Price and stock must be numeric.")
			else:
				add_item(inventory, parts[1], float(parts[2]), int(parts[3]))
		elif command == "update":
			if parts.size() != 3:
				print("Error: Use update ITEM QUANTITY")
			elif not parts[2].is_valid_int():
				print("Error: Quantity must be an integer.")
			else:
				update_stock(inventory, parts[1], int(parts[2]))
		else:
			print("Unknown command")