Generowanie raportu

Część sekcji Logika i przepływ programu ścieżki GDScript w Coddy. Lekcja 75 z 78.

Wyzwanie

Trudny

Na koniec dodaj polecenie sell, które sprzedaje kilka produktów naraz i podaje przychód. Zachowaj wszystko, co zostało napisane w poprzednich krokach.

Linijka taka jak sell Apple:30 Banana:20 sprzedaje 30 jabłek i 20 bananów. Każda część po sell zawiera nazwę produktu, dwukropek i ilość, a dany produkt może pojawić się w linijce najwyżej raz.

Napisz funkcję sales_report(inventory, sales) powyżej _ready(). sales to słownik, który przypisuje każdej nazwie produktu sprzedaną ilość. Dla każdego produktu, w podanej kolejności:

Jeśli produktu nie ma w inventory, wypisz Error: Item 'Orange' not found. i przejdź do następnego produktu
Jeśli jego stan magazynowy jest mniejszy niż ilość, wypisz Error: Insufficient stock for 'Apple'. i przejdź do następnego produktu
W przeciwnym razie odejmij ilość od stanu magazynowego i dodaj iloczyn ilości i ceny do przychodu

Funkcja zwraca tekst Total revenue: $, po którym następuje przychód z dwoma miejscami po przecinku.

W pętli gałąź sell tworzy słownik sales z części znajdujących się po poleceniu. Jeśli część nie składa się dokładnie z nazwy i liczby całkowitej oddzielonych znakiem :, wypisz Error: Invalid sale 'Apple-3'. (wraz z tą częścią) i pomiń ją. Następnie wypisz to, co zwraca sales_report().

Dla poleceń add Apple 0.5 50, add Banana 0.2 60, sell Apple:30 Banana:20 Orange:10, show i exit wynik jest następujący:

Inventory Management System
Item 'Apple' added successfully.
Item 'Banana' added successfully.
Error: Item 'Orange' not found.
Total revenue: $19.00
{ "Apple": { "price": 0.5, "stock": 20 }, "Banana": { "price": 0.2, "stock": 40 } }
Goodbye!

Spróbuj swoich sił

extends Node

func add_item(inventory: Dictionary, item: String, price: float, stock: int) -> void:
	if inventory.has(item):
		print("Error: Item '%s' already exists." % item)
		return
	inventory[item] = {"price": price, "stock": stock}
	print("Item '%s' added successfully." % item)

func update_stock(inventory: Dictionary, item: String, quantity: int) -> void:
	if not inventory.has(item):
		print("Error: Item '%s' not found." % item)
		return
	var new_stock: int = inventory[item]["stock"] + quantity
	if new_stock < 0:
		print("Error: Insufficient stock for '%s'." % item)
		return
	inventory[item]["stock"] = new_stock
	print("Stock for '%s' updated successfully." % item)

func check_availability(inventory: Dictionary, item: String) -> int:
	if not inventory.has(item):
		return -1
	return inventory[item]["stock"]

func _ready():
	# Magazyn: nazwa przedmiotu -> {"price": float, "stock": int}
	var inventory := {}
	print("Inventory Management System")

	while true:
		var line := OS.read_string_from_stdin()
		var parts := line.split(" ")
		var command := parts[0]

		if command == "exit":
			print("Goodbye!")
			break
		elif command == "show":
			print(inventory)
		elif command == "add":
			if parts.size() != 4:
				print("Error: Use add ITEM PRICE STOCK")
			elif not parts[2].is_valid_float() or not parts[3].is_valid_int():
				print("Error: Price and stock must be numeric.")
			else:
				add_item(inventory, parts[1], float(parts[2]), int(parts[3]))
		elif command == "update":
			if parts.size() != 3:
				print("Error: Use update ITEM QUANTITY")
			elif not parts[2].is_valid_int():
				print("Error: Quantity must be an integer.")
			else:
				update_stock(inventory, parts[1], int(parts[2]))
		elif command == "check":
			if parts.size() != 2:
				print("Error: Use check ITEM")
			else:
				var stock := check_availability(inventory, parts[1])
				if stock == -1:
					print("Item not found")
				else:
					print(parts[1], ": ", stock, " in stock")
		else:
			print("Unknown command")