Arguments dans les registres
Fait partie de la section Fonctions, pile et chaînes de caractères du Journey Assembly de Coddy. Leçon 11 sur 33.
Une convention d’appel est l’ensemble des règles sur lesquelles toutes les fonctions s’accordent : où placer les arguments, où récupérer le résultat et quels registres une fonction peut modifier. Du code écrit par différentes personnes, ou généré par un compilateur C, peut s’appeler mutuellement parce qu’il suit les mêmes règles. Sous Linux x86-64, ces règles sont appelées System V AMD64.
Les six premiers arguments entiers sont placés dans rdi, rsi, rdx, rcx, r8 et r9, dans cet ordre. La fonction renvoie son résultat dans rax. Pour appeler area(3, 4) :
mov rdi, 3 ; premier argument : la largeur
mov rsi, 4 ; deuxième argument : la hauteur
call area ; rax = 12Le fichier verrouillé main.asm suit les mêmes règles : chaque défi de cette section t’a fourni ses entrées dans rdi, rsi, rdx et rcx, car il appelle solve comme un programme C appelle une fonction, et lit ta réponse dans rax.
Une fonction peut se trouver dans un autre fichier. extern area en haut de votre fichier indique à nasm que l’étiquette area est définie ailleurs ; le fichier qui la définit la marque global area, et l’éditeur de liens réunit les deux.
extern area
...
call areaChaque argument doit se trouver dans son registre lorsque call s’exécute. Tu peux calculer un argument directement : lea rdi, [rdi + rdx * 2] définit rdi à rdi + 2 * rdx en une seule instruction, sans toucher à rdx.
Défi
Facilesolve reçoit la largeur d’une image dans rdi, sa hauteur dans rsi et la taille d’une bordure dans rdx (toutes comprises entre 0 et 100). Appelez area avec la largeur encadrée (largeur + 2 fois la bordure) dans rdi et la hauteur encadrée (hauteur + 2 fois la bordure) dans rsi, puis renvoyez son résultat dans rax.
Exemple : pour l’entrée 3 4 1, le programme affiche 30.
Écrivez votre code dans solution.asm. Le fichier verrouillé main.asm lit l’entrée, appelle solve et affiche le nombre dans rax, ou le nom d’un registre préservé par l’appelé que solve a modifié.
lib.asm contient max2, area, score et points, avec un commentaire pour chacun ; ce fichier est verrouillé.
Essayez vous-même
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitCette leçon comprend un petit quiz. Commencez la leçon pour y répondre et suivre votre progression.
Toutes les leçons de Fonctions, pile et chaînes de caractères
1La pile
PUSH et POPDernier entré, premier sortiSauvegarder un registreLire avec [rsp]Récapitulatif : historique des annulations4Cadres de pile et récursivité
Variables localesCadres avec RBPRécursivitéDeux appels récursifsRécapitulatif : somme des chiffres2CALL et RET
CALL et RETÉcrire une fonction auxiliaireAppels imbriquésUne pile qui doit rester équilibréeRécapitulatif : prix de la commande5Chaînes de caractères et octets
Octets et ASCIICompter les caractèresChanger la casseTexte en nombreInverser le texteRécapitulatif : palindrome3La convention d’appel
Arguments dans les registresValeurs de retourRegistres sauvegardés par l’appelantRegistres sauvegardés par l’appeléRécapitulatif : tableau des scores6Projet : compteur de mots
L’appel système readCompter les caractèresEntraînez-vous par vous-même : Playground Assembly