Lire avec [rsp]
Fait partie de la section Fonctions, pile et chaînes de caractères du Journey Assembly de Coddy. Leçon 4 sur 33.
rsp contient une adresse, donc tu peux lire la pile comme n’importe quelle autre zone mémoire. mov rax, [rsp] copie la valeur au sommet dans rax sans la dépiler : rsp reste à sa place.
Chaque emplacement fait 8 octets, et les valeurs plus anciennes se trouvent aux adresses les plus élevées. Après avoir empilé 10, 20 et 30 :
push 10
push 20
push 30
mov rax, [rsp] ; rax = 30, le sommet de la pile
mov rbx, [rsp + 8] ; rbx = 20
mov rcx, [rsp + 16] ; rcx = 10, empilé en premierLa lecture ne supprime rien. Quand tu as terminé, libère l’espace : dépile chaque valeur, ou libère-les toutes d’un coup avec add rsp, 24 pour trois valeurs (3 fois 8 octets).
La pile doit être équilibrée avant ret. solve se termine par ret, qui lit à l’adresse de retour dans [rsp]. Si une valeur que tu as empilée se trouve encore au sommet, ret l’utilise comme adresse et le programme plante avant d’afficher quoi que ce soit.
Défi
Facilesolve reçoit quatre nombres dans rdi, rsi, rdx et rcx. Empile-les dans cet ordre. Sans les dépiler, lis la valeur qui se trouve en deuxième position à partir du sommet et celle qui se trouve en bas (la première empilée) avec [rsp + ...], puis retourne leur somme dans rax. Retire les quatre valeurs avant ret.
Exemple : pour l’entrée 1 2 3 4, le programme affiche 4.
Écris ton code dans solution.asm. Le fichier verrouillé main.asm lit l’entrée, appelle solve et affiche le nombre dans rax.
Essayez vous-même
bits 64
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscallCette leçon comprend un petit quiz. Commencez la leçon pour y répondre et suivre votre progression.
Toutes les leçons de Fonctions, pile et chaînes de caractères
1La pile
PUSH et POPDernier entré, premier sortiSauvegarder un registreLire avec [rsp]Récapitulatif : historique des annulations4Cadres de pile et récursivité
Variables localesCadres avec RBPRécursivitéDeux appels récursifsRécapitulatif : somme des chiffresEntraînez-vous par vous-même : Playground Assembly