Octets et ASCII
Fait partie de la section Fonctions, pile et chaînes de caractères du Journey Assembly de Coddy. Leçon 21 sur 33.
Un caractère est stocké sur un octet : son code ASCII. 'A' vaut 65, 'a' vaut 97, le chiffre '0' vaut 48 et une espace vaut 32. Un texte en mémoire est une suite de ces octets, un par caractère.
Dans ce chapitre, le fichier verrouillé main.asm lit une ligne de texte et transmet son adresse à solve dans rdi. Le texte se termine par un octet nul, le nombre 0, qu'aucun caractère n'utilise. Le code qui parcourt le texte s'arrête lorsqu'il lit cet octet nul. C stocke ses chaînes de la même manière.
movzx eax, byte [rdi] lit un octet et remplit de zéros le reste de rax. Un simple mov al, [rdi] ne modifie que l’octet de poids faible et conserve les anciens octets de poids fort de rax, donc comparer ensuite l’ensemble de rax peut produire un résultat incorrect.
movzx eax, byte [rdi] ; rax = le premier octet, pour 'Hi' 72
movzx ecx, byte [rdi + 1] ; rcx = le deuxième octet, 105Chaque caractère occupe un octet, donc le caractère suivant se trouve à l’adresse suivante : inc rdi, ou à un registre d’index dans [rdi + rcx]. Cette boucle s’arrête à l’octet nul :
xor ecx, ecx
.next:
movzx eax, byte [rdi + rcx]
test eax, eax
jz .end
inc rcx
jmp .next
.end:En NASM, un caractère entre guillemets correspond à son code : cmp al, 'a' est la même instruction que cmp al, 97. Les guillemets rendent le code plus facile à lire que le nombre.
Défi
Facilesolve reçoit l’adresse d’un texte dans rdi ; le texte se termine par un octet nul. Renvoie dans rax le nombre d’octets avant l’octet nul. Un texte vide renvoie 0.
Exemple : pour l’entrée hello, le programme affiche 5.
Écris ton code dans solution.asm. Le fichier verrouillé main.asm lit une ligne de texte, appelle solve et affiche le nombre dans rax.
Essayez vous-même
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 257
text_buffer resb 256
output_buffer resb 32
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jg .trim
xor eax, eax
.trim:
test rax, rax
jz .ended
movzx edx, byte [input_buffer + rax - 1]
cmp dl, 10
je .drop
cmp dl, 13
jne .ended
.drop:
dec rax
jmp .trim
.ended:
mov byte [input_buffer + rax], 0
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
lea rdi, [input_buffer]
lea rsi, [text_buffer]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitToutes les leçons de Fonctions, pile et chaînes de caractères
1La pile
PUSH et POPDernier entré, premier sortiSauvegarder un registreLire avec [rsp]Récapitulatif : historique des annulations4Cadres de pile et récursivité
Variables localesCadres avec RBPRécursivitéDeux appels récursifsRécapitulatif : somme des chiffres2CALL et RET
CALL et RETÉcrire une fonction auxiliaireAppels imbriquésUne pile qui doit rester équilibréeRécapitulatif : prix de la commande5Chaînes de caractères et octets
Octets et ASCIICompter les caractèresChanger la casseTexte en nombreInverser le texteRécapitulatif : palindromeEntraînez-vous par vous-même : Playground Assembly