Surveillance de la plante : Rapport

// Le bouton remplace un capteur d’humidité du sol
const int sensorPin = A0;
// Le voyant d’état : une LED RGB
const int redPin = 9;
const int greenPin = 10;
const int bluePin = 6;
// L’alarme
const int buzzerPin = 8;

bool wasDry = false;         // le sol était-il sec lors de la dernière mesure ?
unsigned long dryStart = 0;  // quand le sol est devenu sec

// L’humidité en pourcentage : 0 correspond à un sol complètement sec, 100 à un sol détrempé.
int readMoisture() {
  int reading = analogRead(sensorPin);
  return map(reading, 0, 1023, 0, 100);
}

// Rouge quand le sol est sec, vert quand tout va bien, bleu quand le sol est humide.
void showStatus(int moisture) {
  digitalWrite(redPin, LOW);
  digitalWrite(greenPin, LOW);
  digitalWrite(bluePin, LOW);
  if (moisture < 30) {
    digitalWrite(redPin, HIGH);
  } else if (moisture <= 70) {
    digitalWrite(greenPin, HIGH);
  } else {
    digitalWrite(bluePin, HIGH);
  }
}

// Émet un bip une fois par seconde lorsque le sol est sec depuis plus de 5 secondes.
void checkAlarm(int moisture) {
  if (moisture < 30) {
    if (wasDry == false) {
      wasDry = true;
      dryStart = millis();
    }
    if (millis() - dryStart > 5000) {
      tone(buzzerPin, 880, 200);
    }
  } else {
    wasDry = false;
  }
}

void setup() {
  pinMode(redPin, OUTPUT);
  pinMode(greenPin, OUTPUT);
  pinMode(bluePin, OUTPUT);
  Serial.begin(9600);
}

void loop() {
  int moisture = readMoisture();
  Serial.print("Moisture: ");
  Serial.print(moisture);
  Serial.println("%");
  showStatus(moisture);
  checkAlarm(moisture);
  delay(1000);
}