Nota Média

Parte da seção Lógica e fluxo do Journey de GDScript da Coddy. Lição 46 de 78.

Desafio

Fácil

Calcule a nota média de um aluno. Mantenha tudo o que você escreveu nas etapas anteriores.

1. A função. Abaixo das outras funções, escreva calculate_average_grade(student_name: String) -> float:

Se student_records não tiver o nome, imprima Student '<name>' not found. e retorne -1.0. Nenhuma média real é negativa, então quem chamou a função consegue saber que o aluno não foi encontrado.
Se o aluno ainda não tiver notas, retorne 0.0.
Caso contrário, retorne a soma das notas dividida pela quantidade de notas, como float.

2. O comando. Adicione este ramo para average <name> acima de ["show"]. Ele exibe a média com duas casas decimais, a menos que o aluno não tenha sido encontrado:

["average", var student]:
	var average := calculate_average_grade(student)
	if average >= 0:
		print("Average grade of '%s': %.2f" % [student, average])

Para os comandos

add Alice 20 Math Physics
add Bob 22 Biology Chemistry
grade Alice 90
grade Alice 85
grade Bob 75
average Alice
average Bob
average Charlie
exit

a saída é:

Student 'Alice' added successfully.
Student 'Bob' added successfully.
Grade 90 added for student 'Alice'.
Grade 85 added for student 'Alice'.
Grade 75 added for student 'Bob'.
Average grade of 'Alice': 87.50
Average grade of 'Bob': 75.00
Student 'Charlie' not found.
Goodbye!

Experimente você mesmo

extends Node

# Cada estudante: nome -> {"age": int, "grades": Array, "courses": um conjunto de nomes de cursos}
var student_records := {}

func _ready():
	while true:
		var parts := Array(OS.read_string_from_stdin().split(" ", false))
		match parts:
			["add", var student, var age, ..]:
				add_student(student, int(age), parts.slice(3))
			["grade", var student, var grade]:
				add_grade(student, int(grade))
			["enrolled", var student, var course]:
				print(is_enrolled(student, course))
			["show"]:
				print(student_records)
			["exit"]:
				print("Goodbye!")
				break

func add_student(student_name: String, age: int, courses: Array) -> void:
	if student_records.has(student_name):
		print("Student '%s' already exists." % student_name)
		return
	var course_set := {}
	for course in courses:
		course_set[course] = true
	student_records[student_name] = {"age": age, "grades": [], "courses": course_set}
	print("Student '%s' added successfully." % student_name)

func add_grade(student_name: String, grade: int) -> void:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return
	student_records[student_name]["grades"].append(grade)
	print("Grade %d added for student '%s'." % [grade, student_name])

func is_enrolled(student_name: String, course: String) -> bool:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return false
	return student_records[student_name]["courses"].has(course)