Gerar Relatório

Parte da seção Lógica e fluxo do Journey de GDScript da Coddy. Lição 75 de 78.

Desafio

Difícil

Por fim, adicione o comando sell, que vende vários itens de uma vez e informa a receita. Mantenha tudo o que você escreveu nas etapas anteriores.

Uma linha como sell Apple:30 Banana:20 vende 30 maçãs e 20 bananas. Cada parte após sell é um nome de item, dois-pontos e uma quantidade, e um item aparece no máximo uma vez por linha.

Escreva a função sales_report(inventory, sales) acima de _ready(). sales é um dicionário que associa cada nome de item à quantidade vendida. Para cada item, na ordem:

Se o item não estiver em inventory, imprima Error: Item 'Orange' not found. e passe para o próximo item
Se o estoque for menor que a quantidade, imprima Error: Insufficient stock for 'Apple'. e passe para o próximo item
Caso contrário, subtraia a quantidade do estoque e some à receita o resultado da multiplicação da quantidade pelo preço

A função retorna o texto Total revenue: $ seguido pela receita com duas casas decimais.

No loop, o ramo sell cria o dicionário sales a partir das partes após o comando. Uma parte que não seja exatamente um nome e um número inteiro separados por : imprime Error: Invalid sale 'Apple-3'. (com aquela parte) e é ignorada. Em seguida, imprima o que sales_report() retorna.

Para os comandos add Apple 0.5 50, add Banana 0.2 60, sell Apple:30 Banana:20 Orange:10, show e exit, a saída é:

Inventory Management System
Item 'Apple' added successfully.
Item 'Banana' added successfully.
Error: Item 'Orange' not found.
Total revenue: $19.00
{ "Apple": { "price": 0.5, "stock": 20 }, "Banana": { "price": 0.2, "stock": 40 } }
Goodbye!

Experimente você mesmo

extends Node

func add_item(inventory: Dictionary, item: String, price: float, stock: int) -> void:
	if inventory.has(item):
		print("Error: Item '%s' already exists." % item)
		return
	inventory[item] = {"price": price, "stock": stock}
	print("Item '%s' added successfully." % item)

func update_stock(inventory: Dictionary, item: String, quantity: int) -> void:
	if not inventory.has(item):
		print("Error: Item '%s' not found." % item)
		return
	var new_stock: int = inventory[item]["stock"] + quantity
	if new_stock < 0:
		print("Error: Insufficient stock for '%s'." % item)
		return
	inventory[item]["stock"] = new_stock
	print("Stock for '%s' updated successfully." % item)

func check_availability(inventory: Dictionary, item: String) -> int:
	if not inventory.has(item):
		return -1
	return inventory[item]["stock"]

func _ready():
	# O inventário: nome do item -> {"price": float, "stock": int}
	var inventory := {}
	print("Inventory Management System")

	while true:
		var line := OS.read_string_from_stdin()
		var parts := line.split(" ")
		var command := parts[0]

		if command == "exit":
			print("Goodbye!")
			break
		elif command == "show":
			print(inventory)
		elif command == "add":
			if parts.size() != 4:
				print("Error: Use add ITEM PRICE STOCK")
			elif not parts[2].is_valid_float() or not parts[3].is_valid_int():
				print("Error: Price and stock must be numeric.")
			else:
				add_item(inventory, parts[1], float(parts[2]), int(parts[3]))
		elif command == "update":
			if parts.size() != 3:
				print("Error: Use update ITEM QUANTITY")
			elif not parts[2].is_valid_int():
				print("Error: Quantity must be an integer.")
			else:
				update_stock(inventory, parts[1], int(parts[2]))
		elif command == "check":
			if parts.size() != 2:
				print("Error: Use check ITEM")
			else:
				var stock := check_availability(inventory, parts[1])
				if stock == -1:
					print("Item not found")
				else:
					print(parts[1], ": ", stock, " in stock")
		else:
			print("Unknown command")