Calificación promedio

Parte de la sección Lógica y flujo del Journey de GDScript de Coddy. Lección 46 de 78.

Desafío

Fácil

Calcula la nota media de un estudiante. Conserva todo lo que escribiste en los pasos anteriores.

1. La función. Debajo de las otras funciones, escribe calculate_average_grade(student_name: String) -> float:

Si student_records no contiene el nombre, imprime Student '<name>' not found. y devuelve -1.0. Ninguna media real es negativa, así que quien llama a la función puede saber que no se encontró al estudiante.
Si el estudiante todavía no tiene notas, devuelve 0.0.
De lo contrario, devuelve la suma de las notas dividida por la cantidad de notas, como un float.

2. El comando. Añade esta rama para average <name> antes de ["show"]. Imprime la media con dos decimales, a menos que no se haya encontrado al estudiante:

["average", var student]:
	var average := calculate_average_grade(student)
	if average >= 0:
		print("Average grade of '%s': %.2f" % [student, average])

Para los comandos

add Alice 20 Math Physics
add Bob 22 Biology Chemistry
grade Alice 90
grade Alice 85
grade Bob 75
average Alice
average Bob
average Charlie
exit

la salida es:

Student 'Alice' added successfully.
Student 'Bob' added successfully.
Grade 90 added for student 'Alice'.
Grade 85 added for student 'Alice'.
Grade 75 added for student 'Bob'.
Average grade of 'Alice': 87.50
Average grade of 'Bob': 75.00
Student 'Charlie' not found.
Goodbye!

Pruébalo tú mismo

extends Node

# Cada estudiante: nombre -> {"age": int, "grades": Array, "courses": un conjunto de nombres de cursos}
var student_records := {}

func _ready():
	while true:
		var parts := Array(OS.read_string_from_stdin().split(" ", false))
		match parts:
			["add", var student, var age, ..]:
				add_student(student, int(age), parts.slice(3))
			["grade", var student, var grade]:
				add_grade(student, int(grade))
			["enrolled", var student, var course]:
				print(is_enrolled(student, course))
			["show"]:
				print(student_records)
			["exit"]:
				print("Goodbye!")
				break

func add_student(student_name: String, age: int, courses: Array) -> void:
	if student_records.has(student_name):
		print("Student '%s' already exists." % student_name)
		return
	var course_set := {}
	for course in courses:
		course_set[course] = true
	student_records[student_name] = {"age": age, "grades": [], "courses": course_set}
	print("Student '%s' added successfully." % student_name)

func add_grade(student_name: String, grade: int) -> void:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return
	student_records[student_name]["grades"].append(grade)
	print("Grade %d added for student '%s'." % [grade, student_name])

func is_enrolled(student_name: String, course: String) -> bool:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return false
	return student_records[student_name]["courses"].has(course)