=B2-A2는 A2의 날짜와 B2의 더 늦은 날짜 사이의 일수를 반환합니다. 엑셀은 모든 날짜를 정수 일수로 저장하므로(2026-03-15는 46096), 한 날짜에서 다른 날짜를 빼면 그 사이의 일수가 나옵니다.
| A | B | C | |
|---|---|---|---|
| 1 | Ordered | Delivered | Days |
| 2 | 2026-03-02 | 2026-03-09 | 7 |
| 3 | 2026-03-05 | 2026-03-07 | 2 |
| 4 | 2026-03-10 | 2026-04-02 | 23 |
| 5 | 2026-03-28 | 2026-04-03 | 6 |
| 6 | 2026-12-29 | 2027-01-04 | 6 |
주문에는 7, 2, 23, 6, 6일이 걸렸습니다. 빼기는 월과 연도의 경계를 알아서 처리합니다. 마지막 주문은 새해를 넘기지만 여전히 6일로 셉니다. 배송일을 바꾸면 일수가 따라 바뀝니다. 이른 날짜가 B열에 있으면 결과는 7이 아니라 -7처럼 음수가 됩니다.
DAYS 함수
=DAYS(end_date, start_date)는 같은 빼기를 하며 종료일을 먼저 받습니다. =B2-A2와 같은 숫자를 내므로, 이 함수를 쓰는 주된 이유는 이름만 봐도 수식이 하는 일을 알 수 있다는 점입니다.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Start | End | B2-A2 | DAYS |
| 2 | 2026-01-15 | 2026-03-10 | 54 | 54 |
| 3 | 2026-02-01 | 2026-03-01 | 28 | 28 |
| 4 | 2024-02-01 | 2024-03-01 | 29 | 29 |
2026년 2월은 28일, 2024년 2월은 29일입니다. 엑셀은 윤년을 포함한 달력을 알고 있습니다. 인수 순서에 주의하세요. =DAYS(A2,B2)는 첫 행에서 -54를 반환합니다. DAYS는 Excel 2013 이후가 필요하고, 빼기는 어디서나 동작합니다.
시작일과 종료일을 포함한 일수
빼기는 두 날짜 사이의 일수, 즉 박 수를 셉니다. 7월 6일부터 7월 10일까지의 예약은 4박이지만, 7월 6일부터 7월 10일까지 빌린 차는 5일치를 냅니다. 첫날과 마지막 날을 모두 셀 때는 1을 더하세요.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | From | To | Nights | Days (both counted) |
| 2 | 2026-07-06 | 2026-07-10 | 4 | 5 |
| 3 | 2026-07-31 | 2026-08-01 | 1 | 2 |
2026-07-06부터 2026-07-06까지의 하루는 빼기로 0, +1을 하면 1입니다. 날짜 시트에서 생기는 1 차이 오류는 대부분 여기서 나오므로, 열을 채우기 전에 어느 쪽이 필요한지 정하세요.
두 날짜 사이의 주, 개월, 년
주는 일수를 7로 나눕니다. 개월과 년은 일수가 일정하지 않으므로 꽉 찬 달력 기준 개월과 년을 세는 DATEDIF를 쓰세요.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Start | End | Weeks | Full weeks | Months | Years |
| 2 | 2025-06-15 | 2026-09-30 | 67.4 | 67 | 15 | 1 |
| 3 | 2024-01-01 | 2026-01-01 | 104.4 | 104 | 24 | 2 |
2025-06-15부터 2026-09-30까지는 67.4주, 꽉 찬 67주, 꽉 찬 15개월, 꽉 찬 1년입니다. DATEDIF에는 이른 날짜를 먼저 넣어야 하며, 반대로 넣으면 #NUM!을 반환합니다.
두 날짜 사이의 근무일
월요일부터 금요일까지만 세려면 NETWORKDAYS(start, end)를 씁니다. 시작일과 종료일이 평일이면 둘 다 세며, 세 번째 인수로 공휴일 목록을 주면 그날을 건너뜁니다. 공휴일과 다른 주말은 NETWORKDAYS와 WORKDAY에서 다룹니다.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Start | End | Calendar days | Working days |
| 2 | 2026-03-02 | 2026-03-13 | 12 | 10 |
| 3 | 2026-03-06 | 2026-03-09 | 4 | 2 |
2026년 3월 2일부터 3월 13일까지는 양 끝을 세어 12일이고, 그중 10일이 평일입니다. 금요일부터 다음 월요일까지는 4일이고 근무일은 2일입니다.
연습: 배송 기간
| A | B | C | |
|---|---|---|---|
| 1 | Ordered | Delivered | Days |
| 2 | 2026-05-18 | 2026-05-27 |
직접 해 보세요: C2에서 A2의 주문일부터 B2의 배송일까지 주문에 며칠이 걸렸는지 구하세요.
결과가 날짜나 ####으로 보이는 이유
날짜 빼기에서는 표시 문제 두 가지가 자주 생깁니다:
- 결과가 날짜처럼 보입니다(
1900-01-07, 미국 설정에서는1/7/1900). 셀에 날짜 형식이 남아 있어 7일이 엑셀 달력의 7번째 날로 표시된 것입니다. 셀을 선택하고 홈 > 표시 형식 > 일반을 고르세요. - 셀이
#####로 채워집니다. 결과가 음수(날짜 순서가 반대)인데 셀이 음수가 될 수 없는 날짜 형식이기 때문입니다. 날짜를 바꾸거나,=ABS(B2-A2)를 쓰거나, 셀을 일반 형식으로 바꿔 음수를 확인하세요.
결과가 #VALUE!이면 셀 하나에 날짜처럼 보이기만 하는 텍스트가 들어 있는 것입니다. 예를 들어 미국식 날짜로 설정된 엑셀의 15.03.2026입니다. =ISNUMBER(A2)로 확인하세요. 진짜 날짜면 TRUE를 반환합니다.
자주 묻는 질문
엑셀에서 두 날짜 사이의 일수는 어떻게 계산하나요?
늦은 날짜에서 이른 날짜를 뺍니다: =B2-A2. 엑셀은 날짜를 일수로 저장하므로 결과가 두 날짜 사이의 일수입니다. =DAYS(B2,A2)도 같은 결과를 냅니다.
시작일과 종료일을 모두 포함해 일수를 세려면 어떻게 하나요?
1을 더합니다: =B2-A2+1. 7월 6일부터 7월 10일까지는 빼기로 4일(호텔 숙박의 박 수), 양 끝을 모두 세면 5일(대여 일수)입니다.
엑셀에서 두 날짜 사이의 개월 수는 어떻게 구하나요?
=DATEDIF(A2,B2,"M")이 꽉 찬 개월 수를 셉니다. 년은 "Y"를 씁니다. DATEDIF에는 이른 날짜를 먼저 넣어야 합니다.
DAYS와 날짜 빼기는 어떻게 다른가요?
결과는 같습니다. =DAYS(B2,A2)와 =B2-A2는 같은 일수를 반환합니다. DAYS는 종료일을 먼저 받고 Excel 2013 이후가 필요하며, 빼기는 모든 버전에서 동작합니다.
엑셀에서 두 날짜 사이의 주 수는 어떻게 구하나요?
일수를 7로 나눕니다. =(B2-A2)/7은 소수가 있는 주 수를, =INT((B2-A2)/7)은 꽉 찬 주 수를 냅니다.
