Esquivar: volver a jugar

Parte de la sección Reglas del juego del Journey de Godot de Coddy. Lección 29 de 29.

El último paso permite que el jugador presione E después de Game Over para volver a jugar.

Hiciste esto en la sala de pinchos. Configura Main's process_mode como Node.PROCESS_MODE_ALWAYS, para que su _process se ejecute mientras el juego está en pausa. El jugador, ambos temporizadores y cada bloque están configurados como Pausable en sus escenas, así que siguen deteniéndose. Al presionar la tecla, reanuda el juego y vuelve a cargar la escena:

func _process(delta):
	if lives == 0 and Input.is_action_just_pressed("action"):
		get_tree().paused = false
		get_tree().reload_current_scene()

La recarga borra todos los bloques, la puntuación y las vidas. Muestra también la etiqueta Hint al terminar la partida, para que el jugador sepa qué tecla presionar.

Desafío

Difícil

En _ready(), establece process_mode de este nodo en Node.PROCESS_MODE_ALWAYS.
Al terminar la partida, muestra también $HUD/Hint.
Añade _process(). Cuando lives sea 0 y se acabe de pulsar action, reanuda el juego y vuelve a cargar la escena.

Pruébalo tú mismo

extends Node2D

var block_scene = preload("res://block.tscn")
var score = 0
var lives = 3

func _ready():
	$HUD/Score.text = "Score: %d" % score
	$HUD/Lives.text = "Lives: %d" % lives
	$SpawnTimer.timeout.connect(_on_spawn_timer_timeout)
	$ScoreTimer.timeout.connect(_on_score_timer_timeout)
	$Player.hurt.connect(_on_player_hurt)

func _on_spawn_timer_timeout():
	var block = block_scene.instantiate()
	block.position = Vector2(randf_range(40, 600), -30)
	add_child(block)

func _on_score_timer_timeout():
	score += 1
	$HUD/Score.text = "Score: %d" % score

func _on_player_hurt():
	lives -= 1
	$HUD/Lives.text = "Lives: %d" % lives
	if lives == 0:
		$HUD/GameOver.visible = true
		get_tree().paused = true