Basic Inheritance

Inheritance lets one class take over the variables and methods of another. The class that passes them on is the parent, and the class that receives them is the child.

Here is a parent class in its own file:

# animal.gd
class_name Animal
extends RefCounted

var animal_name: String

func _init(n: String) -> void:
	animal_name = n

func info() -> void:
	print("I am ", animal_name, ", an animal")

A child class names its parent after extends. The parent's class_name is global, so dog.gd needs no import line:

# dog.gd
class_name Dog
extends Animal

This Dog has no code of its own, yet it has animal_name, info() and the constructor of Animal:

var creature := Animal.new("Creature")
var buddy := Dog.new("Buddy")
creature.info()
buddy.info()

I am Creature, an animal
I am Buddy, an animal

A child can add methods of its own next to the inherited ones. Inside them, the inherited variables work as if the child had declared them:

# dog.gd
class_name Dog
extends Animal

func bark() -> void:
	print(animal_name, " says Woof!")

var buddy := Dog.new("Buddy")
buddy.info()
buddy.bark()

I am Buddy, an animal
Buddy says Woof!

Inheritance goes one way. An Animal does not get what Dog adds, so calling bark() on an Animal object is an error.

The classes you wrote so far said extends RefCounted: they were children of RefCounted, a class built into Godot.