Virtual Methods Introduction

Python has magic methods such as __init__ and __str__, which the language calls for you. Godot's version is the virtual method: a method with a fixed name, starting with an underscore, that you define in your class and Godot calls at the right moment. You have used two already:

• _init() runs when new() creates the object, with the arguments given to new().
• _ready() runs when a node enters the scene tree, which is where main.gd starts.

Others are _to_string(), called when an object is printed, the iterator methods that let a for loop walk through an object (both in the next lessons), and _notification(), which receives events from the engine. One of them, NOTIFICATION_PREDELETE, arrives right before the object is deleted:

# torch.gd
class_name Torch
extends RefCounted

var label: String

func _init(new_label: String = "Torch") -> void:
	label = new_label
	print(label, " lit")

func _notification(what: int) -> void:
	if what == NOTIFICATION_PREDELETE:
		print(label, " burned out")

# main.gd
var torch := Torch.new("Hall torch") # Hall torch lit
torch = null # Hall torch burned out

A RefCounted object is deleted as soon as no variable refers to it any more, so torch = null sends the notification at once. The default value in _init() makes the argument of new() optional: Torch.new() creates a torch called Torch.

Python also uses magic methods for operators, such as __add__ for + and __eq__ for ==. GDScript has no operator overloading: potion_a + potion_b is an error. Write a method instead:

# potion.gd
class_name Potion
extends RefCounted

var power: int

func _init(start_power: int) -> void:
	power = start_power

func combined(other: Potion) -> Potion:
	return Potion.new(power + other.power)

potion_a.combined(potion_b) returns a new potion and leaves both originals unchanged. == between two objects checks whether both sides are the same object, not whether their values match: Potion.new(5) == Potion.new(5) is false. Write a method such as equals(other) when you need to compare values.