Destrua a parede

Parte da seção Projetos do Journey de Godot da Coddy. Lição 9 de 33.

A última etapa é uma forma de vencer: quebre todos os tijolos.

Conte quantos tijolos restam. Comece em 40 e subtraia um cada vez que brick_broken chegar. Quando chegar a zero, a parede estará limpa:

bricks_left -= 1
if bricks_left == 0:
	$HUD/Message.text = "You Win!"
	get_tree().paused = true

Subtraia um antes de testar se chegou a zero. Se testar primeiro, o teste verá 1 no último tijolo e nunca verá 0.

A tecla Enter na tela Game Over também inicia um novo jogo aqui. Seu Breakout está completo.

Desafio

Médio

Em main.gd:

Adicione var bricks_left = 40.
Cada tijolo quebrado diminui esse número em um.
Quando não restar nenhum, mostre You Win! em $HUD/Message e pause o jogo.

Experimente você mesmo

extends Node2D

const BRICK = preload("res://brick.tscn")
const COLORS = [Color(1, 0.42, 0.42), Color(1, 0.78, 0.34), Color(0.49, 0.95, 0.75), Color(0.369, 0.635, 1), Color(0.75, 0.82, 0.95)]

var score = 0
var lives = 3

func _ready():
	for row in 5:
		for column in 8:
			var brick = BRICK.instantiate()
			brick.position = Vector2(68 + column * 72, 60 + row * 26)
			brick.color = COLORS[row]
			add_child(brick)
	$Ball.brick_broken.connect(_on_brick_broken)
	$HUD/Score.text = "Score: 0"
	$Ball.missed.connect(_on_missed)
	$HUD/Lives.text = "Lives: 3"

func _process(delta):
	if get_tree().paused and Input.is_action_just_pressed("action"):
		get_tree().paused = false
		get_tree().reload_current_scene()

func _on_brick_broken():
	score += 10
	$HUD/Score.text = "Score: %d" % score

func _on_missed():
	lives -= 1
	$HUD/Lives.text = "Lives: %d" % lives
	if lives == 0:
		$HUD/Message.text = "Game Over"
		get_tree().paused = true