Разрушаем стену

Часть раздела Проекты путешествия по Godot на Coddy. Урок 9 из 33.

Последний шаг — способ победить: разбейте все кирпичи.

Считайте оставшиеся кирпичи. Начните с 40 и вычитайте по одному каждый раз, когда приходит brick_broken. Когда останется ноль, стена будет очищена:

bricks_left -= 1
if bricks_left == 0:
	$HUD/Message.text = "You Win!"
	get_tree().paused = true

Вычитайте единицу до проверки на ноль. Если сначала выполнить проверку, на последнем кирпиче она увидит 1 и никогда не увидит 0.

Клавиша Enter на экране окончания игры здесь тоже запускает новую игру. Ваша игра Breakout готова.

Задание

Средне

В main.gd:

Добавь var bricks_left = 40.
За каждый разбитый кирпич вычитай единицу.
Когда не останется ни одного, покажи You Win! в $HUD/Message и приостанови игру.

Попробуйте сами

extends Node2D

const BRICK = preload("res://brick.tscn")
const COLORS = [Color(1, 0.42, 0.42), Color(1, 0.78, 0.34), Color(0.49, 0.95, 0.75), Color(0.369, 0.635, 1), Color(0.75, 0.82, 0.95)]

var score = 0
var lives = 3

func _ready():
	for row in 5:
		for column in 8:
			var brick = BRICK.instantiate()
			brick.position = Vector2(68 + column * 72, 60 + row * 26)
			brick.color = COLORS[row]
			add_child(brick)
	$Ball.brick_broken.connect(_on_brick_broken)
	$HUD/Score.text = "Score: 0"
	$Ball.missed.connect(_on_missed)
	$HUD/Lives.text = "Lives: 3"

func _process(delta):
	if get_tree().paused and Input.is_action_just_pressed("action"):
		get_tree().paused = false
		get_tree().reload_current_scene()

func _on_brick_broken():
	score += 10
	$HUD/Score.text = "Score: %d" % score

func _on_missed():
	lives -= 1
	$HUD/Lives.text = "Lives: %d" % lives
	if lives == 0:
		$HUD/Message.text = "Game Over"
		get_tree().paused = true