=CONTAR.SI(A2:A8;"*") cuenta las celdas de A2:A8 que contienen texto. El asterisco es un comodín para "cualquier carácter", y solo coincide con texto, así que los números, las fechas, VERDADERO/FALSO y las celdas vacías no se cuentan. CONTAR.SI se llama COUNTIF en inglés, y la tabla muestra la fórmula así: =COUNTIF(A2:A8,"*"). La tabla también acepta las fórmulas escritas en español, con punto y coma (o con comas, como en México).
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Entry | What | Count | |
| 2 | Apple | Text | 3 | |
| 3 | 12 | Not empty | 6 | |
| 4 | Numbers and dates | 2 | ||
| 5 | Pear | Empty | 1 | |
| 6 | 2026-01-05 | |||
| 7 | TRUE | |||
| 8 | n/a |
=CONTAR.SI(A2:A8;"*")D2 cuenta Apple, Pear y n/a: 3. CONTARA (COUNTA en inglés) cuenta todas las celdas llenas, 6, y CONTAR (COUNT en inglés) los dos números (una fecha es un número). Escribe 25 en A4 y D3 y D4 suben mientras D2 se queda en 3; escribe Plum en su lugar y suben D2 y D3 mientras D4 se queda en 2. CONTAR y CONTARA se comparan en su propia página.
Un número escrito con un apóstrofo delante, como '007, es texto, así que "*" lo cuenta. Para contar solo las celdas con al menos un carácter, usa "?*": el ? tiene que coincidir con un carácter, así que una fórmula que devuelve una cadena vacía ("") nunca se cuenta.
Contar las celdas que contienen un texto concreto
Para contar las celdas que contienen una palabra en cualquier lugar, pon un asterisco a cada lado. Sin los asteriscos, la celda entera tiene que coincidir.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Product | Condition | Count | |
| 2 | Apple | contains apple | 5 | |
| 3 | Pineapple | exactly apple | 1 | |
| 4 | Pear | starts with apple | 3 | |
| 5 | apple juice | word in C6 | 1 | |
| 6 | Plum | juice | ||
| 7 | Green apple | apple, case-sensitive | 3 | |
| 8 | Apple cider |
=CONTAR.SI(A2:A8;"*apple*")"*apple*" coincide con cinco productos. "apple" solo coincide con la celda que es exactamente Apple (CONTAR.SI no distingue mayúsculas), y "apple*" con las tres que empiezan por esa palabra. D5 toma la palabra de C6, así que puedes escribir ahí cualquier palabra. D7 distingue mayúsculas: ENCONTRAR (FIND en inglés), a diferencia de CONTAR.SI, distingue apple de Apple, así que solo cuentan Pineapple, apple juice y Green apple. El -- convierte los resultados VERDADERO/FALSO en 1 y 0 para que SUMAPRODUCTO los sume.
Si una celda contiene un texto, devolver un valor
Para marcar cada fila, comprueba una celda cada vez. HALLAR("apple";A2) devuelve la posición en la que empieza apple, o #¡VALOR! (#VALUE! en inglés; la tabla muestra los nombres de error en inglés) cuando no está. ESNUMERO convierte eso en VERDADERO o FALSO, y SI elige el resultado.
| A | B | C | |
|---|---|---|---|
| 1 | Product | Contains apple? | Any text? |
| 2 | Apple | Yes | Text |
| 3 | Pear | No | Text |
| 4 | Pineapple | Yes | Text |
| 5 | 42 | No | Not text |
| 6 | Green apple | Yes | Text |
| 7 | 2026-02-01 | No | Not text |
=SI(ESNUMERO(HALLAR("apple";A2));"Yes";"No")Las dos columnas están copiadas hacia abajo. B muestra Yes para Apple, Pineapple y Green apple. C usa ESTEXTO (ISTEXT en inglés), que responde a otra pregunta: si en la celda hay algún texto. 42 y la fecha son números, así que son "Not text". Usa ENCONTRAR en lugar de HALLAR cuando importen las mayúsculas. Hay más sobre las dos funciones, y por qué HALLAR es la que no distingue mayúsculas, en ENCONTRAR y HALLAR.
=SI(CONTAR.SI(A2;"*apple*");"Yes";"No") hace la misma prueba con CONTAR.SI: un conteo de 1 cuenta como VERDADERO y 0 como FALSO.
Contar las celdas que contienen una de varias palabras
Sumar dos CONTAR.SI cuenta dos veces una celda que contiene las dos palabras. En su lugar, comprueba cada celda una sola vez: HALLAR cada palabra, sumar los resultados VERDADERO y contar las filas en las que la suma es mayor que 0.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Product | Formula | Count | |
| 2 | Apple | Two COUNTIFs | 5 | |
| 3 | Orange juice | Each cell once | 4 | |
| 4 | Pear | |||
| 5 | apple juice | |||
| 6 | Plum | |||
| 7 | Green apple |
=CONTAR.SI(A2:A7;"*apple*")+CONTAR.SI(A2:A7;"*juice*")Cuatro productos mencionan apple o juice, pero los dos CONTAR.SI dan 5, porque apple juice se cuenta en los dos. La versión con SUMAPRODUCTO da 4.
Práctica: contar las celdas de texto
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Delivery | Weight | What | Count | |
| 2 | D-1 | 12 | Notes | ||
| 3 | D-2 | 9 | |||
| 4 | D-3 | damaged | |||
| 5 | D-4 | 15 | |||
| 6 | D-5 | missing | |||
| 7 | D-6 | ||||
| 8 | D-7 | late |
Tu turno: Algunas entregas tienen un peso y otras una nota. Cuenta las celdas de B2:B8 que contienen texto. Escribe la fórmula en E2.
Por qué el conteo de celdas de texto no cuadra
- Los números guardados como texto se cuentan. Una columna importada de otro sistema puede contener
'125como texto."*"lo cuenta y CONTAR no. Si CONTAR sobre una columna de números da menos que CONTARA, algunos son texto; consulta números guardados como texto. - Celdas que solo parecen vacías. Una celda con un espacio es texto y se cuenta. Usa
=SUMAPRODUCTO(--(LARGO(ESPACIOS(A2:A8))>0))para contar las celdas con caracteres visibles. - VERDADERO y FALSO no son texto.
"*"los salta, igual que salta los valores de error como #N/A. - CONTAR.SI no distingue mayúsculas. Para un conteo que las distinga, usa ENCONTRAR dentro de SUMAPRODUCTO, como en la segunda tabla.
Preguntas frecuentes
¿Cómo cuento las celdas que contienen cualquier texto en Excel?
Usa =CONTAR.SI(A2:A8;"*"). El asterisco coincide con cualquier texto, así que la fórmula cuenta cada celda de texto y deja fuera los números, las fechas, VERDADERO/FALSO y las celdas vacías.
¿Cómo cuento las celdas que contienen un texto concreto?
Pon asteriscos alrededor de la palabra: =CONTAR.SI(A2:A8;"*apple*") cuenta las celdas que tienen apple en cualquier lugar, sin importar mayúsculas. Sin los asteriscos, "apple" cuenta solo las celdas que son exactamente apple.
¿Cómo escribo "si la celda contiene un texto, entonces" en Excel?
Combina SI, ESNUMERO y HALLAR: =SI(ESNUMERO(HALLAR("apple";A2));"Yes";"No"). HALLAR devuelve una posición cuando encuentra el texto y un error cuando no, y ESNUMERO lo convierte en VERDADERO o FALSO.
¿Cómo compruebo si una celda contiene algún texto?
Usa =ESTEXTO(A2), que es VERDADERO para el texto y FALSO para números, fechas y celdas vacías. Dentro de SI: =SI(ESTEXTO(A2);"Text";"Not text").
