=SEQUENCE(5) devuelve los números del 1 al 5 en una columna, desde la única celda en la que la escribes. En Excel en español la función se llama SECUENCIA (SEQUENCE en inglés), y la tabla también acepta las fórmulas escritas en español, con punto y coma (o con comas, como en México): =SECUENCIA(5). Con un segundo argumento llena una cuadrícula: =SECUENCIA(3;4) da 3 filas y 4 columnas, contando del 1 al 12 a lo largo de cada fila. Cambia el 5 de A2 por 8 y la columna crece.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Rows | Rows and columns | ||||
| 2 | 1 | 1 | 2 | 3 | 4 | |
| 3 | 2 | 5 | 6 | 7 | 8 | |
| 4 | 3 | 9 | 10 | 11 | 12 | |
| 5 | 4 | |||||
| 6 | 5 |
=SECUENCIA(5)Sintaxis de SECUENCIA
=SEQUENCE(rows, [columns], [start], [step])
rows(filas) es cuántas filas se devuelven.columns(columnas) es cuántas columnas. Por defecto, 1.start(inicio) es el primer número. Por defecto, 1.step(incremento) es cuánto suma cada número al anterior. Por defecto, 1, y puede ser negativo o decimal.
Una cuadrícula se llena primero a lo ancho: en =SECUENCIA(3;4) la primera fila es 1, 2, 3, 4 y la segunda empieza en 5. Para contar bajando por las columnas, envuélvela en TRANSPONER (TRANSPOSE en inglés): =TRANSPONER(SECUENCIA(4;3)).
SECUENCIA necesita Excel 2021, Excel 2024 o Microsoft 365, y muestra #¿NOMBRE? (#NAME? en inglés; la tabla muestra los nombres de error en inglés) en versiones anteriores. Google Sheets tiene la misma función.
Inicio e incremento
Los dos últimos argumentos fijan el primer número y la distancia entre números:
| A | B | C | D | E | F | G | H | I | |
|---|---|---|---|---|---|---|---|---|---|
| 1 | 10 to 50 | 5 down to 1 | Across a row | ||||||
| 2 | 10 | 5 | 1 | 2 | 3 | 4 | 5 | ||
| 3 | 20 | 4 | |||||||
| 4 | 30 | 3 | |||||||
| 5 | 40 | 2 | |||||||
| 6 | 50 | 1 |
=SECUENCIA(5;1;10;10)=SECUENCIA(5;1;10;10) empieza en 10 y suma 10 cada vez. =SECUENCIA(5;1;5;-1) cuenta hacia atrás desde 5. =SECUENCIA(1;5) es una fila de cinco columnas. Para un número sí y otro no, usa un incremento de 2: =SECUENCIA(10;1;1;2) da los impares del 1 al 19.
Numerar filas automáticamente
Los números de fila escritos a mano se quedan desfasados en cuanto se añade una fila. Cuenta los nombres y deja que SECUENCIA dé un número por nombre:
| A | B | |
|---|---|---|
| 1 | No. | Name |
| 2 | 1 | Ann |
| 3 | 2 | Ben |
| 4 | 3 | Cara |
| 5 | 4 | Dan |
| 6 | 5 | Eve |
=SECUENCIA(CONTARA(B2:B8))CONTARA (COUNTA en inglés) cuenta las 5 celdas llenas de B2:B8, así que A2 devuelve del 1 al 5. Escribe Finn en B7 y los números llegan a 6. CONTARA cuenta cualquier celda llena, así que la lista no debe tener huecos; en una hoja real usa un rango amplio, como B2:B1000. Si la lista está vacía, CONTARA devuelve 0 y SECUENCIA(0) muestra #CALC!.
Una secuencia de fechas
En Excel una fecha es un número (uno por día), así que una fecha sirve como inicio. Cada fila de abajo suma un día; la fórmula necesita formato de fecha, o muestra números de serie como 46083:
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Start | 2026-03-02 | Weekly | ||
| 2 | 2026-03-02 | Monday | 2026-03-02 | ||
| 3 | 2026-03-03 | Tuesday | 2026-03-09 | ||
| 4 | 2026-03-04 | Wednesday | 2026-03-16 | ||
| 5 | 2026-03-05 | Thursday | 2026-03-23 | ||
| 6 | 2026-03-06 | Friday | |||
| 7 | 2026-03-07 | Saturday | |||
| 8 | 2026-03-08 | Sunday |
=SECUENCIA(7;1;B1)B2 lista del 2026-03-02 al 2026-03-08 y C2 nombra cada día, de lunes a domingo. E2 usa un incremento de 7 para cuatro fechas separadas por una semana. Cambia B1 y las tres lo siguen.
Para meses, un incremento de 30 se va desviando, porque los meses tienen distinta duración. Pasa SECUENCIA a FECHA.MES (EDATE en inglés), que suma meses completos: =FECHA.MES(B1;SECUENCIA(6;1;0)) devuelve del 2 de marzo al 2 de agosto (da formato de fecha a las celdas). (Consulta sumar días y meses para FECHA.MES y FIN.MES.)
Un calendario con SECUENCIA
Seis filas de siete días bastan para cualquier mes. La cuadrícula empieza en el domingo que cae el día 1 o antes: FECHA(2026;4;1)-DIASEM(FECHA(2026;4;1))+1 retrocede del 1 de abril a ese domingo. Las celdas tienen el formato d, así que cada una muestra su número de día, y un formato condicional resalta los días de abril:
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Sun | Mon | Tue | Wed | Thu | Fri | Sat |
| 2 | 29 | 30 | 31 | 1 | 2 | 3 | 4 |
| 3 | 5 | 6 | 7 | 8 | 9 | 10 | 11 |
| 4 | 12 | 13 | 14 | 15 | 16 | 17 | 18 |
| 5 | 19 | 20 | 21 | 22 | 23 | 24 | 25 |
| 6 | 26 | 27 | 28 | 29 | 30 | 1 | 2 |
| 7 | 3 | 4 | 5 | 6 | 7 | 8 | 9 |
=SECUENCIA(6;7;FECHA(2026;4;1)-DIASEM(FECHA(2026;4;1))+1)El 1 de abril de 2026 es miércoles, así que la cuadrícula empieza con 29, 30 y 31 de marzo. Cambia los dos 4 de A2 (y el 4 de la regla) por otro mes y el calendario se redibuja. Para mostrar celdas en blanco en lugar de los días del otro mes, comprueba cada fecha dentro de la fórmula; LET mantiene corta esa fórmula.
Práctica: fechas separadas por una semana
| A | B | |
|---|---|---|
| 1 | Start | 2026-05-04 |
| 2 | Dates |
Tu turno: En B2, lista 5 fechas hacia abajo, empezando por la fecha de B1 y separadas por una semana.
SECUENCIA dentro de otras fórmulas
SECUENCIA suele ser una ayuda más que el resultado. Tres usos frecuentes:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | List | Top 3 | Sum 1 to 10 | 1, 2, 3 repeated |
| 2 | Cara | Cara | 55 | 1 |
| 3 | Dan | Dan | 2 | |
| 4 | Ann | Ann | 3 | |
| 5 | Eve | 1 | ||
| 6 | Ben | 2 | ||
| 7 | 3 |
=INDICE(A2:A6;SECUENCIA(3))=INDICE(A2:A6;SECUENCIA(3))devuelve los tres primeros elementos de una lista: Cara, Dan y Ann.TOMAR(A2:A6;3)hace lo mismo en Microsoft 365 y Excel 2024.=SUMA(SECUENCIA(10))suma del 1 al 10 sin escribirlos: 55.=RESIDUO(SECUENCIA(6)-1;3)+1repite 1, 2, 3, 1, 2, 3, útil para repartir filas entre tres grupos por turnos.
Un error frecuente es poner SECUENCIA donde su resultado no puede derramarse. =SECUENCIA(5) muestra #SPILL! cuando alguna de las cuatro celdas de debajo contiene datos; vacíalas o mueve la fórmula (consulta error #SPILL!).
Preguntas frecuentes
¿Qué hace la función SECUENCIA en Excel?
Devuelve una lista de números que se derrama desde una celda: =SECUENCIA(5) da del 1 al 5 en una columna, =SECUENCIA(1;5) da del 1 al 5 en una fila y =SECUENCIA(5;1;10;10) da 10, 20, 30, 40, 50.
¿Cómo creo una secuencia de fechas en Excel?
Usa una fecha como inicio: =SECUENCIA(7;1;B1) devuelve siete días seguidos desde la fecha de B1, y =SECUENCIA(4;1;B1;7) devuelve cuatro fechas separadas por una semana. Da formato de fecha al resultado, o mostrará números de serie.
¿Cómo numero filas automáticamente en Excel?
Pon =SECUENCIA(CONTARA(B2:B100)) en la primera fila de la columna de números. Cuenta las celdas llenas de B y devuelve del 1 hasta ese número, así que un nombre nuevo recibe su número sin copiar nada.
¿Cómo hago una secuencia descendente?
Usa un incremento negativo: =SECUENCIA(5;1;5;-1) devuelve 5, 4, 3, 2, 1. El incremento también puede ser decimal, como en =SECUENCIA(5;1;0;0,25).
¿Qué versiones de Excel tienen SECUENCIA?
Excel 2021, Excel 2024 y Microsoft 365. Las versiones anteriores muestran #¿NOMBRE?; ahí escribes los dos primeros valores y arrastras el controlador de relleno, o usas =FILA()-1 copiada hacia abajo.
