Para sumar una columna en Excel, haz clic en la celda debajo de los números, escribe =SUMA(B2:B6) y pulsa Enter. La función SUMA (SUM en inglés) suma todos los números de B2 a B6, y el total cambia cada vez que cambia uno de esos números.
| A | B | |
|---|---|---|
| 1 | Month | Sales |
| 2 | Jan | 1200 |
| 3 | Feb | 950 |
| 4 | Mar | 1430 |
| 5 | Apr | 1100 |
| 6 | May | 1320 |
| 7 | Total | 6000 |
=SUMA(B2:B6)Haz clic en B7 para ver la fórmula y el rango que suma, marcado en la cuadrícula. Cambia Feb a 2000 y el total se actualiza. B2:B6 es un rango: la primera celda, dos puntos y la última celda.
Autosuma: el atajo de SUMA
Casi nunca necesitas escribir SUMA. Haz clic en la celda vacía debajo de una columna de números y pulsa Alt+= (en Mac, Cmd+Shift+T), o haz clic en Inicio > Autosuma. Excel adivina el rango de arriba, lo muestra con un borde en movimiento y escribe =SUMA(B2:B6). Pulsa Enter para aceptarlo, o arrastra antes sobre otras celdas para corregir la suposición.
Autosuma se detiene en la primera celda vacía o en la primera celda con texto, así que un hueco en la columna da un rango demasiado corto. Revisa el rango marcado antes de pulsar Enter.
Para ver un total sin escribir ninguna fórmula, selecciona las celdas: la barra de estado, abajo en la ventana de Excel, muestra Suma, Promedio y Recuento de la selección.
Sintaxis de la fórmula SUMA
=SUM(number1, [number2], ...)
Cada argumento puede ser un rango (B2:B6), una celda (B2), un número (100) u otra fórmula. Se admiten hasta 255 argumentos, y SUMA los suma todos. En Excel en español los argumentos se separan con punto y coma, =SUMA(A1;A2) (con la configuración regional de México, con comas), y la tabla de esta página acepta las fórmulas escritas de las dos formas.
Cómo sumar una fila en Excel
Una fila funciona igual, con el rango en horizontal: =SUMA(B2:D2). Aquí la fórmula se escribe una vez en E2 y se copia hacia abajo, así que cada fila suma sus propios tres meses.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Region | Jan | Feb | Mar | Q1 total |
| 2 | North | 420 | 380 | 510 | 1310 |
| 3 | South | 310 | 290 | 335 | 935 |
| 4 | East | 505 | 470 | 490 | 1465 |
| 5 | West | 260 | 315 | 300 | 875 |
=SUMA(B2:D2)Haz clic en E3: la fórmula ahí es =SUM(B3:D3). Excel movió el número de fila al copiar la fórmula hacia abajo, que es justo lo que quieres aquí. Para copiar tú una fórmula hacia abajo, arrastra el pequeño cuadrado de la esquina inferior de la celda, o selecciona las celdas y pulsa Ctrl+J (Cmd+D en Mac).
Sumar celdas no adyacentes
Para sumar celdas que no están juntas, sepáralas dentro de SUMA. Mantén pulsada Ctrl (Cmd en Mac) mientras haces clic en las celdas y Excel escribe los separadores por ti.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Product | Q1 | Q2 | Shirts and socks | Q1 and Q2, first two rows | |
| 2 | Shirts | $2,400 | $2,650 | $3,550 | $6,610 | |
| 3 | Hats | $800 | $760 | |||
| 4 | Socks | $1,150 | $1,300 | |||
| 5 | Belts | $640 | $700 | |||
| 6 | Bags | $1,900 | $2,100 |
=SUMA(B2;B4)E2 suma dos celdas sueltas y da 3550. F2 suma dos rangos, B2:B3 y C2:C3, y da 6610. Puedes mezclar rangos, celdas y números en una misma SUMA.
Sumar varias hojas
Escribe el nombre de la hoja antes del rango, con un signo de exclamación: Jan!B2:B4 significa B2:B4 en la hoja llamada Jan. Usa las pestañas debajo de esta hoja para ver las dos hojas mensuales.
| A | B | |
|---|---|---|
| 1 | Store | Jan + Feb |
| 2 | All stores | 25500 |
=SUMA(Jan!B2:B4;Feb!B2:B4)El total es 25500. Si el nombre de la hoja tiene un espacio, ponlo entre comillas simples: ='Jan 2026'!B2.
Cuando las hojas tienen el mismo diseño, una referencia 3D suma el mismo rango en todas las hojas entre dos pestañas:
=SUM(Jan:Mar!B2:B4)
Esto suma B2:B4 en Jan, en Mar y en todas las hojas que hay entre ellas en el orden de las pestañas. Si sacas una hoja de ese tramo, sale también del total.
Por qué SUMA ignora los números guardados como texto
Un número escrito con un apóstrofo delante, o importado de otro programa, puede quedar guardado como texto. Parece un número, pero SUMA lo omite sin avisar. En Excel una celda así suele mostrar un pequeño triángulo verde en la esquina.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Order | Amount | SUM | Plus signs | Converted | |
| 2 | 1001 | 250 | 725 | 1125 | 1125 | |
| 3 | 1002 | 400 | ||||
| 4 | 1003 | 175 | ||||
| 5 | 1004 | 300 |
=SUMA(B2:B5)B3 contiene el texto "400". SUMA da 725 porque deja fuera B3. Cuando todas las celdas del rango son texto, SUMA devuelve 0. Los signos más dan 1125 porque + convierte el texto que parece un número. =SUMAPRODUCTO(B2:B5*1) también da 1125: multiplicar por 1 convierte primero cada celda en número.
La solución definitiva es convertir las celdas: selecciónalas, haz clic en el icono de advertencia y elige Convertir en número. Convertir texto en números explica las otras formas.
Práctica: total de una tabla
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Region | Q1 | Q2 | Q3 | Q4 | Grand total | |
| 2 | North | 420 | 380 | 510 | 450 | ||
| 3 | South | 310 | 290 | 335 | 360 | ||
| 4 | East | 505 | 470 | 490 | 520 | ||
| 5 | West | 260 | 315 | 300 | 280 |
Tu turno: En G2, escribe una sola fórmula que sume las ventas de las cuatro regiones en los cuatro trimestres.
Un rango puede abarcar varias columnas a la vez: su primera celda es la esquina superior del bloque y la última, la esquina opuesta.
SUMA con un error en el rango
Si alguna celda del rango contiene un error como #N/A o #¡DIV/0! (#DIV/0! en inglés, el nombre que muestra la tabla), SUMA devuelve ese error en vez de un total. Busca la celda y corrígela o, cuando los errores son esperables, suma sin ellos:
=AGGREGATE(9,6,B2:B10)
En Excel en español: =AGREGAR(9;6;B2:B10). El 9 significa sumar y el 6, ignorar los valores de error. Para sumar solo las filas que cumplen una condición, como una región o un mes, usa SUMAR.SI.
Preguntas frecuentes
¿Cómo sumo una columna en Excel?
Haz clic en la celda debajo de los números y escribe =SUMA(B2:B6), con tu propia primera y última celda, y pulsa Enter. O haz clic en esa celda y pulsa Alt+= (Cmd+Shift+T en Mac), y Autosuma escribe la misma fórmula por ti.
¿Cómo sumo una fila en Excel?
Dale a SUMA un rango horizontal: =SUMA(B2:D2) suma B2, C2 y D2. Cópiala hacia abajo y cada fila suma sus propias celdas: la copia de la fila 3 es =SUMA(B3:D3).
¿Cómo sumo la misma celda en varias hojas?
Usa una referencia 3D: =SUMA(Jan:Mar!B5) suma B5 en todas las hojas de Jan a Mar, incluidas las que están entre ellas. Para dos hojas concretas, nómbralas: =SUMA(Jan!B2:B4;Feb!B2:B4).
¿Cómo sumo una columna entera en Excel?
=SUMA(B:B) suma todos los números de la columna B, por muchas filas que añadas después. Pon la fórmula en otra columna: una SUMA de la columna B escrita dentro de la columna B se refiere a sí misma y provoca una referencia circular.
¿Qué diferencia hay entre SUMA y el signo +?
=B2+B3+B4 y =SUMA(B2:B4) dan el mismo total con números normales. SUMA omite el texto y las celdas vacías, mientras que + convierte un número guardado como texto y devuelve #¡VALOR! (#VALUE! en inglés) con texto real como "n/a".
