The percentage increase formula in Excel is =(new-old)/old. With last year's value in B2 and this year's in C2, type =(C2-B2)/B2 and format the cell as a percentage. A positive result is an increase, a negative result a decrease.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Product | Last year | This year | Change |
| 2 | Coffee | $12,400 | $14,880 | 20.0% |
| 3 | Tea | $8,600 | $7,740 | -10.0% |
| 4 | Juice | $5,200 | $5,460 | 5.0% |
| 5 | Water | $3,100 | $4,650 | 50.0% |
Coffee grew 20.0% and Tea fell 10.0%, shown as -10.0%. Water grew 50.0%. Change a number in column C and the percentage updates. The brackets matter: without them, =C2-B2/B2 divides first and subtracts 1 from this year's sales.
Two ways to write the same formula
=(C2-B2)/B2 the change divided by the old value
=C2/B2-1 the new value as a share of the old, minus 100%
Both give the same result. The first reads like the definition, so it is easier to check later. Either way, the old value is always the one you divide by. Dividing by the new value is the most common mistake, and it gives a different number: from 80 to 100 is +25%, but 20 divided by 100 is 20%.
When neither number is the old one, such as two stores compared side by side, divide the gap by the average of the two instead. This is the percent difference, and for 80 and 100 it gives 22.2% whichever comes first:
=ABS(B2-C2)/AVERAGE(B2,C2)
Month over month percentage change
For a list over time, compare each row with the row above. The first month has nothing to compare with, so the formula starts in the second row.
| A | B | C | |
|---|---|---|---|
| 1 | Month | Visitors | Change |
| 2 | Jan | 4200 | |
| 3 | Feb | 4620 | 10.0% |
| 4 | Mar | 4389 | -5.0% |
| 5 | Apr | 5047 | 15.0% |
| 6 | May | 4795 | -5.0% |
| 7 | Jun | 5754 | 20.0% |
February is up 10.0% on January and March is down 5.0%. To compare every month with January instead, lock the base with dollar signs: =(B3-$B$2)/$B$2. Absolute references explain the $.
Percent change from zero
When the old value is 0, the formula divides by zero and returns #DIV/0!. A rise from nothing has no percentage, so decide what the cell should show instead and test for it:
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Product | Last year | This year | Plain | Checked |
| 2 | Coffee | 12400 | 14880 | 20.0% | 20.0% |
| 3 | Cocoa | 0 | 2100 | #DIV/0! | new |
| 4 | Soda | 0 | 640 | #DIV/0! | new |
D3 and D4 show #DIV/0!; the checked column shows "new". =IFERROR((C2-B2)/B2,"new") gives the same result here, but it also hides real mistakes, such as text in the sales column. The page on the divide by zero error covers it in general.
Practice: write the percent change
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Item | Old price | New price | Change |
| 2 | Bread | $2.40 | $2.76 |
Your turn: In D2, calculate the percent change from the old price in B2 to the new price in C2. The cell is already formatted as a percentage.
Percent change vs percentage points
When the values are themselves percentages, two different answers are both called "the change". A conversion rate going from 4% to 5% rose by 1 percentage point, and it rose by 25%.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Page | Before | After | Points | Percent change |
| 2 | Signup | 4.0% | 5.0% | 1.0% | 25.0% |
D2 subtracts the rates and shows 1.0%, which you would report as "1 percentage point". E2 shows 25.0%. Say which one you mean, because "the rate went up 1%" could mean either.
Negative old values
When the old value is negative, such as a loss turning into a profit, the plain formula gives the wrong sign: from -200 to 100, =(C2-B2)/B2 returns -150%. Divide by the absolute value of the old number instead:
=(C2-B2)/ABS(B2)
From -200 to 100 this returns 150%, an increase. For growth over several years, a yearly average rate is more useful than one big percentage: =(C2/B2)^(1/5)-1 turns a five-year change into a compound annual growth rate (CAGR).
Frequently Asked Questions
What is the formula for percentage increase in Excel?
=(C2-B2)/B2, where B2 is the old value and C2 the new one, with the cell formatted as a percentage. =C2/B2-1 gives the same result. From 80 to 100 the result is 25%.
How do I calculate a percentage decrease in Excel?
Use the same formula, =(C2-B2)/B2. When the new value is smaller, the result is negative: from 100 to 80 it is -20%. Excel has no separate decrease formula.
How do I calculate percent change when the old value is 0?
A change from 0 has no percentage, and =(C2-B2)/B2 returns #DIV/0!. Show something else in that case: =IF(B2=0,"n/a",(C2-B2)/B2).
How do I calculate percent change with negative numbers?
Divide by the absolute value of the old number: =(C2-B2)/ABS(B2). A loss of -200 that becomes a profit of 100 then shows +150%, an increase, instead of the misleading -150% the plain formula gives.
