=WEEKNUM(A2) returns the week number of the date in A2. By default weeks start on Sunday and week 1 is the week that contains January 1. Most of Europe uses ISO week numbers instead, where weeks start on Monday: for those, use =ISOWEEKNUM(A2).
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Date | WEEKNUM | ISOWEEKNUM | Day |
| 2 | 2026-03-02 | 10 | 10 | Mon |
| 3 | 2026-12-27 | 53 | 52 | Sun |
| 4 | 2026-12-31 | 53 | 53 | Thu |
| 5 | 2027-01-01 | 1 | 53 | Fri |
| 6 | 2027-01-03 | 2 | 53 | Sun |
The two systems agree on most dates and part ways around New Year. Friday 2027-01-01 is in week 1 by WEEKNUM, because week 1 always contains January 1. By ISOWEEKNUM it is in week 53 of 2026: ISO week 1 is the week with the year's first Thursday, and that week starts on Monday, January 4. Sunday 2026-12-27 shows the other difference: WEEKNUM has already started week 53, because its weeks start on Sunday.
WEEKNUM return types
WEEKNUM takes a second argument that sets the day a week starts on. Type 21 switches it to the ISO system, the same as ISOWEEKNUM, which helps in older Excel: ISOWEEKNUM needs Excel 2013 or later.
| return_type | Week starts on | Week 1 |
|---|---|---|
| 1 or omitted | Sunday | contains January 1 |
| 2 | Monday | contains January 1 |
| 11 to 17 | Monday to Sunday | contains January 1 |
| 21 | Monday | contains the first Thursday (ISO 8601) |
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Date | Type 1 | Type 2 | Type 21 | ISOWEEKNUM |
| 2 | 2026-01-04 | 2 | 1 | 1 | 1 |
| 3 | 2026-01-05 | 2 | 2 | 2 | 2 |
| 4 | 2027-01-01 | 1 | 1 | 53 | 53 |
Sunday 2026-01-04 starts week 2 under type 1 but is still in week 1 under type 2, where the week runs to Sunday. Types 21 and ISOWEEKNUM always agree.
Start date of a week
Reports grouped by week usually show the week's first day rather than its number. Subtract the weekday from the date: WEEKDAY(A2,3) counts Monday as 0, so =A2-WEEKDAY(A2,3) is the Monday on or before A2. For weeks starting on Sunday, =A2-WEEKDAY(A2)+1.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Date | Week starts (Monday) | Week starts (Sunday) | Week ends (Sunday) |
| 2 | 2026-03-04 | 2026-03-02 | 2026-03-01 | 2026-03-08 |
| 3 | 2026-03-08 | 2026-03-02 | 2026-03-08 | 2026-03-08 |
| 4 | 2026-03-09 | 2026-03-09 | 2026-03-08 | 2026-03-15 |
| 5 | 2027-01-01 | 2026-12-28 | 2026-12-27 | 2027-01-03 |
Wednesday 2026-03-04 is in the week of Monday 2026-03-02, which ends on Sunday 2026-03-08. A Monday maps to itself. The formula is a date, so the result needs a date format; without one it shows a number such as 46083. WEEKDAY explains the return types.
Convert a week number to a date
Going the other way, from "week 12 of 2026" to a date, uses the rule that January 4 is always in ISO week 1. Find the Monday of that week, then add 7 days for each week after the first.
| A | B | C | |
|---|---|---|---|
| 1 | Year | Week | Monday |
| 2 | 2026 | 12 | 2026-03-16 |
| 3 | 2026 | 1 | 2025-12-29 |
| 4 | 2027 | 1 | 2027-01-04 |
Week 12 of 2026 starts on 2026-03-16, week 1 of 2026 on 2025-12-29, and week 1 of 2027 on 2027-01-04. The first ISO week of a year can start in December, which is why the year in the label and the year of the date do not always match.
Practice: week numbers
| A | B | |
|---|---|---|
| 1 | Date | ISO week |
| 2 | 2026-05-24 | |
| 3 | 2023-03-15 | |
| 4 | 2026-11-08 |
Your turn: In B2, return the ISO week number of the date in A2, then fill it down to B4.
| A | B | |
|---|---|---|
| 1 | Date | Monday |
| 2 | 2026-05-22 | |
| 3 | 2026-05-24 | |
| 4 | 2026-05-25 |
Your turn: In B2, return the Monday of the week that contains the date in A2, then fill it down to B4. Weeks run Monday to Sunday.
Common mistake: week 53 in January
Grouping by YEAR(A2) and ISOWEEKNUM(A2) puts January 1, 2027 into "2027, week 53", a week that does not exist. The ISO week belongs to the year of its Thursday, so take the year from the Thursday of the same week: YEAR(A2-WEEKDAY(A2,2)+4).
| A | B | C | |
|---|---|---|---|
| 1 | Date | Wrong label | Right label |
| 2 | 2026-12-31 | 2026-W53 | 2026-W53 |
| 3 | 2027-01-01 | 2027-W53 | 2026-W53 |
| 4 | 2027-01-03 | 2027-W53 | 2026-W53 |
For January 1, 2027 the wrong label reads 2027-W53 and the right one 2026-W53, the same week as December 31. The opposite happens at the other end of a year: Monday 2025-12-29 is in ISO week 1 of 2026, and the right label reads 2026-W01. The TEXT(...,"00") keeps week numbers two digits wide, so the labels sort in order.
Frequently Asked Questions
How do I get the week number from a date in Excel?
=WEEKNUM(A2) returns the week number with weeks starting on Sunday and week 1 being the week of January 1. For the ISO week number used in most of Europe, use =ISOWEEKNUM(A2) or =WEEKNUM(A2,21).
What is the difference between WEEKNUM and ISOWEEKNUM?
WEEKNUM starts week 1 on January 1, so the first and last weeks of a year can be short. ISOWEEKNUM follows ISO 8601: weeks run Monday to Sunday and week 1 is the week with the year's first Thursday, so January 1 can belong to week 52 or 53 of the year before.
How do I get the Monday of the week in Excel?
=A2-WEEKDAY(A2,3) returns the Monday on or before the date in A2. WEEKDAY with type 3 counts Monday as 0, so a Monday stays where it is. Format the result as a date.
How do I convert a week number to a date in Excel?
For ISO weeks, the Monday of week N of year Y is =DATE(Y,1,4)-WEEKDAY(DATE(Y,1,4),3)+(N-1)*7. January 4 is always in ISO week 1, so the formula steps back to that week's Monday and then forward N-1 weeks.
Why does Excel show week 53?
With WEEKNUM, December 31 is always in week 53, because week 1 is the partial week of January 1 (week 54 in a leap year that starts on a Saturday, such as 2028). With ISOWEEKNUM, a year has 53 weeks when it starts or ends on a Thursday, as 2026 does.
